Compartilhar via

Propriedade Worksheet.Range (Excel)

Retorna um objeto Range que representa uma célula ou um intervalo de células.

Sintaxe

expressão. Intervalo (Célula1, Célula2)

expressão Uma variável que representa um objeto de Folha de Cálculo .

Parâmetros

Nome Obrigatório/Opcional Tipo de dados Descrição
Cell1 Obrigatório Variant Uma String que é uma referência de intervalo quando um argumento é usado. Uma String que é uma referência de intervalos ou um objeto Range quando são usados dois argumentos.
Cell2 Opcional Variant Uma String que é uma referência de intervalos ou um objeto Range. Cell2 define outra extremidade do intervalo retornado pela propriedade.

Comentários

Cell1 e Cell2 podem ser referências de estilo A1 na linguagem da macro. As referências de intervalo podem incluir o operador de intervalo (dois pontos), o operador de intersecção (um espaço) ou o operador de união (uma vírgula). Pode também incluir sinais de cifrão, mas eles são ignorados. Um nome definido local pode ser uma referência de intervalo. Se você usar um nome, o nome será considerado como estando na linguagem da macro.

Cell1 e Cell2 podem ser objetos Range que contêm uma única célula, coluna, linha ou qualquer outro intervalo de células.

Muitas vezes, a Célula1 e a Célula2 são células individuais nos cantos superior esquerdo e inferior direito do intervalo devolvido.

Quando usado sem um qualificador de objeto, essa propriedade é um atalho para ActiveSheet.Range (retorna um intervalo da planilha ativa; se a folha ativa não for uma planilha, a propriedade falhará).

Quando aplicado a um objeto Range, a propriedade será relativa ao objeto Range. Por exemplo, se a seleção for a célula C3, Selection.Range("B1") devolve a célula D3 porque é relativa ao objeto Intervalo devolvido pela propriedade Seleção . Por outro lado, o código ActiveSheet.Range("B1") sempre retorna a célula B1.

Exemplos

Este exemplo define o valor da célula A1 de Sheet1 como 3,14159.

Worksheets("Sheet1").Range("A1").Value = 3.14159

Este exemplo cria uma fórmula na célula A1 na Planilha1.

Worksheets("Sheet1").Range("A1").Formula = "=10*RAND()"

Este exemplo dá um ciclo nas células A1:D10 na Folha1 do livro ativo. Se uma das células tiver um valor menor do que 0,001, o código substituirá esse valor por 0 (zero).

For Each c in Worksheets("Sheet1").Range("A1:D10") 
 If c.Value < .001 Then 
 c.Value = 0 
 End If 
Next c

Este exemplo percorre o intervalo com o nome TestRange e apresenta o número de células vazias no intervalo.

numBlanks = 0 
For Each c In Range("TestRange") 
 If c.Value = "" Then 
 numBlanks = numBlanks + 1 
 End If 
Next c 
MsgBox "There are " & numBlanks & " empty cells in this range"

Este exemplo define o estilo do tipo de letra nas células A1:C5 na Folha1 do livro ativo como itálico. O exemplo usa a Sintaxe 2 da propriedade Range.

With Worksheets("Sheet1")
	.Range(.Cells(1, 1), .Cells(5, 3)).Font.Italic = True
End With

Este exemplo compara a propriedade Folha de Cálculo.Intervalo , o método Application.Union e o método Application.Intersect .

Range("A1:A10").Select                            'Selects cells A1 to A10.
Range(Range("A1"), Range("A10")).Select           'Selects cells A1 to A10.
 Range("A1, A10").Select                          'Selects cells A1 and A10.
Union(Range("A1"), Range("A10")).Select           'Selects cells A1 and A10.
 Range("A1:A5 A5:A10").Select                     'Selects cell A5.
Intersect(Range("A1:A5"), Range("A5:A10")).Select 'Selects cell A5.

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.

  • Last updated on