Propriedade ShapeRange.LockAspectRatio (Project)

Obtém ou define um valor que indica se o intervalo de formas mantém as proporções originais quando o redimensiona; ou seja, a proporção do intervalo de formas está bloqueada. MsoTriState de leitura/escrita.

Sintaxe

expressão. LockAspectRatio

expressão Uma variável que representa um objeto "ShapeRange".

Comentários

O valor LockAspectRatio é msoTrue se o intervalo de formas mantiver as proporções originais quando é redimensionado. Se conseguir alterar a altura e a largura do intervalo de formas de forma independente, o valor é msoFalse.

Exemplo

O exemplo seguinte cria dois intervalos de formas, com um triângulo e uma engrenagem do mesmo tamanho em cada intervalo de formas. O intervalo da forma esquerda tem a proporção desbloqueada e o intervalo da forma direita tem a proporção bloqueada. A Figura 1 mostra o resultado quando cada intervalo de formas é redimensionado pela mesma quantidade.

As alterações a um intervalo de formas são aplicadas a cada forma no intervalo.

Sub ResizeShapeRanges()
    Dim shapeReport As Report
    Dim reportName As String
    Dim triangle1 As shape
    Dim triangle2 As shape
    Dim gear1 As shape
    Dim gear2 As shape
    Dim sRange1 As ShapeRange
    Dim sRange2 As ShapeRange
    
    reportName = "ShapeRange resize report"
    Set shapeReport = ActiveProject.Reports.Add(reportName)
    
    With shapeReport.Shapes
        Set triangle1 = .AddShape(msoShapeIsoscelesTriangle, 10, 10, 100, 100)
        Set gear1 = .AddShape(msoShapeGear6, 10, 120, 100, 100)
        Set triangle2 = .AddShape(msoShapeIsoscelesTriangle, 150, 10, 100, 100)
        Set gear2 = .AddShape(msoShapeGear6, 150, 120, 100, 100)
        
        gear2.BackgroundStyle = msoBackgroundStylePreset3
        
        Set sRange1 = .Range(Array(1, 2))
        Set sRange2 = .Range(Array(3, 4))
    End With
       
    sRange1.LockAspectRatio = msoFalse
    sRange1.height = 200
    
    ' Set a yellow shape style for gear1.
    sRange1(2).ShapeStyle = msoShapeStylePreset26
    
    sRange2.LockAspectRatio = msoTrue
    sRange2.height = 200
    
    sRange2.Select
End Sub

Na Figura 1, é selecionado o intervalo de formas correto com a proporção bloqueada.

Figura 1. Redimensionar um intervalo de formas quando a proporção é desbloqueada ou bloqueada

Valor de propriedade

MSOTRISTATE

Confira também

ShapeRange ObjectShape.LockAspectRatio PropertyMsoTriState

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.