Compartilhar via

Propriedade Application.StencilPaths (Visio)

Obtém ou define os caminhos nos quais o Microsoft Visio procura por estênceis. Leitura/gravação.

Sintaxe

expressão. StencilPaths

expressão Uma variável que representa um Aplicativo objeto.

Valor de retorno

Cadeia de caracteres

Comentários

Por padrão, a propriedade StencilPaths é definida como uma sequência vazia ("").

A cadeia de caracteres passada e recebida da propriedade StencilPaths é a mesma mostrada na caixa de diálogo Localizações de Arquivo. (Clique no separador Ficheiro , clique em Opções, clique em Avançadas e, em seguida, em Geral, clique em Localizações de Ficheiros.) Esta cadeia é armazenada na subchaveHKEY_CURRENT_USER\Software\Microsoft\Office\14.0\Visio\Application\StencilPath .

Quando o Visio procura por estênceis, examina todos os caminhos especificados na propriedade StencilPaths e em todas as subpastas desses caminhos. Se você passar a propriedade StencilPaths para o método EnumDirectories, ele retornará uma lista completa de caminhos totalmente qualificados nas pastas que lhe foram passadas.

Definir a propriedade StencilPaths substitui os valores existentes para Stencils na caixa de diálogo Localizações de Ficheiros . Para reter valores existentes, obtenha a sequência de caracteres existentes e anexe o novo caminho de arquivo para a sequência de caracteres, como exibido no seguinte código:

Application.StencilPaths = Application.StencilPaths & ";" & "newpath ".

Aviso

Modificar o registo do Windows de qualquer forma, seja no Editor de Registo ou através de programação, tem sempre algum grau de risco. Uma modificação incorreta pode causar problemas sérios que talvez exijam a reinstalação do sistema operacional. É recomendável que você sempre faça um backup do registro do computador antes de modificá-lo.

Exemplo

Esta macro do VBA (Microsoft Visual Basic for Applications) mostra como usar a propriedade StencilPaths para adicionar um caminho para os estênceis.

 
Public Sub ShowStencilPaths_Example() 
  
    Dim strMessage As String 
    Dim strNewPath As String 
    Dim strStencilPath As String 
    Dim strTitle As String 
 
    'Get the path we want to add.  
    strStencilPath = Application.StencilPaths  
    strTitle = "StencilPaths"  
    strMessage = "The current content of the Visio Stencils box is:"  
    strMessage = strMessage & vbCrLf & strStencilPath  
    MsgBox strMessage, vbInformation + vbOKOnly, strTitle  
    strMessage = "Type in an additional path for Visio to look for stencils. "  
    strNewPath = InputBox$(strMessage, strTitle)  
 
    'Make sure the folder exists and that it's not 
    'already in the stencil paths.  
    strMessage = ""  
    If strNewPath = ""  Then 
        strMessage = "You did not enter a path." 
        ElseIf InStr(strStencilPath, strNewPath)  Then 
            strMessage = "The path you specified is already in the stencil paths."  
        ElseIf Len(Dir$(strNewPath, vbDirectory)) = 0 And _  
                Len(Dir$(Application.Path & strNewPath, _  
                vbDirectory)) = 0 Then 
            strMessage = "The folder you typed does not exist (or is blank)."  
        Else 
            Application.StencilPaths = strStencilPath & ";" & strNewPath  
            strMessage = "We just added " & strNewPath & _  
                " to the stencil paths."  
        End If 
   
    If strMessage <> ""  Then 
        MsgBox strMessage, vbExclamation + vbOKOnly, strTitle  
    End If 
   
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.

  • Last updated on