Compartilhar via

Characters.AddFieldEx method (Visio) (Método Characters.AddFieldEx [Visio])

Substitui o texto representado por um objeto Carateres por um novo campo da categoria, código, formato, ID de idioma e ID de calendário que especificar.

Sintaxe

expressão. AddFieldEx (Category, Code, Format, LangID, CalendarID)

expressão Uma variável que representa um objeto Carateres .

Parâmetros

Nome Obrigatório/Opcional Tipo de dados Descrição
Categoria Obrigatório VisFieldCategories A categoria do novo campo.
Código Obrigatório VisFieldCodes O código do novo campo.
Format Obrigatório VisFieldFormats O formato do novo campo.
LangID Opcional Long O idioma a utilizar para o novo campo.
CalendarID Opcional Long O calendário a ser usado para o novo campo.

Valor de retorno

Nada

Comentários

Os valores constantes para Categoria, Código e Formato são declarados pela biblioteca de tipos do Visio em VisFieldCategories, VisFieldCodes e VisFieldFormats , respetivamente.

O argumento LangID deve ser um dos IDs padrão utilizados pelo Windows para codificar versões de idioma diferentes. Por exemplo, a ID do idioma é &H0409 para a versão americana do Microsoft Visio. Para exibir uma lista de possíveis IDs de idioma, pesquise por "VERSIONINFO" no Microsoft Platform SDK no MSDN.

O argumento CalendarID deve ser um dos seguintes valores, declarados em VisCellVals na biblioteca de tipos do Visio. O valor padrão é visCalWestern, que define o calendário como ocidental.

Constant Valor Descrição
visCalWestern 0 Oeste
visCalArabicHijri 1 Islâmico árabe
visCalHebrewLunar 2 Lunar hebraico
visCalChineseTaiwan 3 Calendário de Taiwan
visCalJapaneseEmperor 4 Reinado do imperador japonês
visCalThaiBuddhism 5 Budista tailandês
visCalKoreanDanki 6 Danki coreano
visCalSakaEra 7 Era Saka
visCalTranslitEnglish 8 Transliteração inglesa
visCalTranslitFrench 9 Transliteração francesa

Usar o método AddFieldEx é semelhante a clicar em Campo na guia Inserir e inserir quaisquer das seguintes categorias dos campos no texto:

  • Data/Hora

  • Informações do documento

  • Geometria

  • Informações do objeto

  • Informações da página

Para adicionar um campo de fórmula personalizado, utilize o método AddCustomField ou AddCustomFieldU . Quando não transmite valores (ou transmite valores predefinidos) para os argumentos LangID e CalendarID opcionais, AddFieldEx age exatamente como AddField.

Exemplo

A seguinte macro do Microsoft Visual Basic for Applications (VBA) mostra como usar a propriedade AddFieldEx para formatar um campo de data em uma forma. Desenha um retângulo na página de desenho e, em seguida, insere um campo que apresenta a data atual em grego, utilizando o calendário ocidental.

Public Sub AddFieldEx_Example() 
 
 Dim vsoCharacters As Visio.Characters 
 Dim vsoShape As Visio.Shape 
 
 ActiveWindow.DeselectAll 
 
 Set vsoShape = Application.ActivePage.DrawRectangle(3, 5, 5, 3) 
 vsoShape.Text = "Date: " 
 
 Set vsoCharacters = vsoShape.Characters 
 
 'Set Begin property equal to End property to 
 'append new text to existing text. 
 vsoCharacters.Begin = vsoCharacters.End 
 
 'Add a field for the current date, in Greek, 
 'using the Western calendar and the long date format. 
 vsoCharacters.AddFieldEx visFCatDateTime, visFCodeCurrentDate, visFmtMsoDateLong, 1032, visCalWestern 
 
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.

  • Last updated on