Método DataRecordset.GetDataRowIDs (Visio)

Obtém uma matriz das identificações de todas as linhas no conjunto de registros de dados.

Sintaxe

expressão. GetDataRowIDs (CriteriaString)

expressão Uma expressão que devolve um objeto DataRecordset .

Parâmetros

Valor de retorno

Longo()

Comentários

Utilize o método GetDataRowIDs para obter uma matriz dos IDs de todas as linhas num conjunto de registos de dados, em que cada linha representa um único registo de dados. O método GetDataRowIDs usa como parâmetro uma cadeia de caracteres de critérios, que está em conformidade com as diretrizes especificadas na API do ADO para definição da propriedade ADO.Filter. A especificação de critérios apropriados e o uso dos operadores AND e OR para separar cláusulas permite filtrar as informações no conjunto de registros de dados para retornar apenas algumas linhas do conjunto de registros de dados de forma seletiva. Para não aplicar nenhum filtro (ou seja, para obter todas as linhas), passe uma cadeia de caracteres vazia ("").

Para obter mais informações sobre cadeias de critérios, veja Propriedade do Filtro na Referência da API do ADO 2.8.

Exemplo

Esta macro do Microsoft Visual Basic for Applications (VBA) mostra como pode utilizar os métodos GetDataRowIDs e GetRowData para devolver o ID de linha de cada linha e, em seguida, obter os dados armazenados em cada coluna em cada linha do conjunto de registos de dados especificado. A macro obtém a contagem de todos os conjuntos de registos de dados associados ao documento atual e obtém dados de linha para o mais recente adicionado. Ela itera em todas as linhas do conjunto de registros de dados e, em seguida, para cada linha, itera em todas as colunas dessa linha. O código exibe as informações retornadas na janela Imediato.

Antes de executar essa macro, crie pelo menos um conjunto de registros de dados no documento atual.

Observe que a macro passa uma cadeia de caracteres vazia para o método GetDataRowIDs para ignorar a filtragem e obter todas as linhas do conjunto de registros. Após executar a macro, observe que o primeiro conjunto de dados mostrado (correspondendo à primeira linha de dados) contém os títulos de todas as colunas de dados no conjunto de registros de dados.

Public Sub GetDataRowIDs_Example() 
 
     
    Dim vsoDataRecordset As Visio.DataRecordset 
    Dim intCount As Integer 
    Dim lngRowIDs() As Long 
    Dim lngRow As Long 
    Dim lngColumn As Long 
    Dim varRowData As Variant 
 
    'Get the count of all data recordsets in the current document. 
    intCount = ThisDocument.DataRecordsets.Count 
 
    Set vsoDataRecordset = ThisDocument.DataRecordsets(intCount) 
 
    'Get the row IDs of all the rows in the data recordset 
    lngRowIDs = vsoDataRecordset.GetDataRowIDs("") 
 
    'Iterate through all the records in the data recordset. 
    For lngRow = LBound(lngRowIDs) To UBound(lngRowIDs) + 1 
        varRowData = vsoDataRecordset.GetRowData(lngRow) 
 
        'Print a separator between rows 
        Debug.Print "------------------------------" 
 
       'Print the data stored in each column of a particular data row. 
        For lngColumn = LBound(varRowData) To UBound(varRowData) 
            Debug.Print varRowData(lngColumn) 
        Next lngColumn 
    Next lngRow 
 
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.