List.Accumulate

Sintaxe

List.Accumulate(
    list as list,
    seed as any,
    accumulator as function
) as any

Sobre

Acumula um valor de resumo dos itens na lista especificada usando o acumulador.

• list: a lista a ser iterada.
• seed: um valor acumulado inicial.
• accumulator: uma função que usa o estado atual e o item atual e retorna o novo estado.

Exemplo 1

Acumula o valor de resumo dos itens na lista.

Usage

let
    Source = List.Accumulate(
        {1, 2, 3, 4, 5},
        0,
        (runningSum, nextNumber) => runningSum + nextNumber
    )
in
    Source

Saída

15

Exemplo 2

Concatena cada palavra na lista com um espaço entre elas, mas não inclua um espaço no início.

Usage

let
    Source = List.Accumulate(
        {"The", "quick", "brown", "fox", "jumps", "over", "the", "lazy", "dog."},
        null,
        (fullTextSoFar, nextPart) =>
            Text.Combine({fullTextSoFar, nextPart}, " ")
    )
in
    Source

Saída"The quick brown fox jumps over the lazy dog."

Exemplo 3

Crie uma lista de tempos de conclusão do processo a partir de uma data de início e uma lista de tempos de execução do processo.

Usage

let
    #"Process Duration" = 
    {
        #duration(0,1,0,0),
        #duration(0,2,0,0),
        #duration(0,3,0,0)
    },
    #"Start Time" = #datetime(2025, 9, 8, 19, 0, 0),
    #"Process Timeline" = List.Accumulate(
        #"Process Duration",
        {#"Start Time"},
        (accumulatedTimes, nextDuration) => 
            accumulatedTimes & {List.Last(accumulatedTimes) + nextDuration}
    )
in
    #"Process Timeline"

Saída

{
    #datetime(2025, 9, 8, 19, 0, 0),
    #datetime(2025, 9, 8, 20, 0, 0),
    #datetime(2025, 9, 8, 22, 0, 0),
    #datetime(2025, 9, 9, 1, 0, 0)
}