List.Distinct

Sintaxe

List.Distinct(list as list, optional equationCriteria as any) as list

Sobre

Retorna uma lista que contém todos os valores na lista especificada com duplicatas removidas. Se a lista especificada estiver vazia, o resultado será uma lista vazia.

• list: a lista da qual valores distintos são extraídos.
• equationCriteria: (Opcional) Especifica como a igualdade é determinada ao comparar valores. Esse parâmetro pode ser uma função de seletor de chave, uma função de comparador ou uma lista que contém um seletor de chave e um comparador.

Exemplo 1

Remova as duplicatas da lista {1, 1, 2, 3, 3, 3}.

Usage

List.Distinct({1, 1, 2, 3, 3, 3})

Saída

{1, 2, 3}

Exemplo 2

A partir do final da lista, selecione as frutas que têm um comprimento de texto exclusivo.

Usage

let
    Source = {"Apple", "Banana", "Cherry", "Date", "Fig"},
    Result = List.Distinct(List.Reverse(Source), each Text.Length(_))
in
    Result

Saída

{"Fig", "Date", "Cherry", "Apple"}

Exemplo 3

A partir do início da lista, selecione as frutas exclusivas, ignorando maiúsculas e minúsculas.

Usage

let
    Source = {"apple", "Pear", "aPPle", "banana", "ORANGE", "pear", "Banana", "Cherry"},
    Result = List.Distinct(Source, Comparer.OrdinalIgnoreCase)
in
    Result

Saída

{"apple", "Pear", "banana", "ORANGE", "Cherry"}

Exemplo 4

Extraia de uma lista de listas as primeiras listas com nomes de país exclusivos, ignorando maiúsculas e minúsculas. Coloque as listas extraídas nas linhas de uma nova tabela.

Usage

let
    Source = {
        {"USA", #date(2023, 8, 1), 567},
        {"canada", #date(2023, 8, 1), 254},
        {"Usa", #date(2023, 7, 1), 450},
        {"CANADA", #date(2023, 6, 1), 357},
        {"Panama", #date(2023, 6, 2), 20},
        {"panama", #date(2023, 7, 1), 40}
    },
    DistinctByCountry = List.Distinct(
        Source,
        {each _{0}, Comparer.OrdinalIgnoreCase}
    ),
    ToTable = Table.FromRows(DistinctByCountry, {"Country", "Date", "Value"}),
    ChangeTypes = Table.TransformColumnTypes(
        ToTable, {{"Country", type text}, {"Date", type date}, {"Value", Int64.Type}}
    )
in
    ChangeTypes

Saída

#table(type table[Country = text, Date = date, Value = Int64.Type],
    {
        {"USA", #date(2023, 8, 1), 567},
        {"canada", #date(2023, 8, 1), 254},
        {"Panama", #date(2023, 6, 2), 20}
    }
)

Conteúdo relacionado

Critérios de equação