List.PositionOf

Sintaxe

List.PositionOf(
    list as list,
    value as any,
    optional occurrence as nullable number,
    optional equationCriteria as any
) as any

Sobre

Retorna o deslocamento no qual o valor especificado aparece em uma lista. Retornará -1 se o valor não for exibido.

• list: a lista a ser pesquisada.
• value: o valor a ser encontrado na lista.
• occurrence: (Opcional) A ocorrência específica a ser reportado. Esse valor pode ser Occurrence.First, Occurrence.Last ou Occurrence.All. Se não occurrence for especificado, Occurrence.First será usado.
• equationCriteria: (Opcional) Especifica como a igualdade é determinada ao comparar valores. Esse parâmetro pode ser uma função de seletor de chave, uma função de comparador ou uma lista que contém um seletor de chave e um comparador.

Exemplo 1

Localize a posição na lista {1, 2, 3} em que o valor 3 aparece.

Usage

List.PositionOf({1, 2, 3}, 3)

Saída

2

Exemplo 2

Localize a posição na lista de todas as instâncias de datas a partir de 2022.

Usage

let
    Source = {
        #date(2021, 5, 10),
        #date(2022, 6, 28),
        #date(2023, 7, 15),
        #date(2022, 12, 31),
        #date(2022, 4, 8),
        #date(2024, 3, 20)
    },
    YearList = List.Transform(Source, each Date.Year(_)),
    TargetYear = 2022,
    FindPositions = List.PositionOf(YearList, TargetYear, Occurrence.All)
in
    FindPositions

Saída

{1, 3, 4}

Exemplo 3

Localize a posição na lista da última ocorrência da palavra cachorro, ignorando maiúsculas e minúsculas.

Usage

let
    Source = List.PositionOf(
        {"dog", "cat", "DOG", "pony", "bat", "rabbit", "dOG"}, 
        "dog", 
        Occurrence.Last, 
        Comparer.OrdinalIgnoreCase
    )
in
    Source

Saída

6

Exemplo 4

Localize a posição na lista que está dentro de duas unidades do número 28.

Usage

let
    Source = { 10, 15, 20, 25, 30 },
    Position = List.PositionOf(
        Source, 
        28,
        Occurrence.First, 
        (x, y) => Number.Abs(x - y) <= 2
    )
in
    Position

Saída

4

Conteúdo relacionado

Critérios de equação