Table.FromRecords

Sintaxe

Table.FromRecords(
    records as list,
    optional columns as any,
    optional missingField as nullable number
) as table

Sobre

Converte uma lista especificada de registros em uma tabela.

• records: a lista de registros a serem convertidos em uma tabela.

• columns: (Opcional) Uma lista dos nomes de coluna da tabela ou do tipo da tabela.

• missingField: (Opcional) Especifica como lidar com campos ausentes em uma linha. Use um dos valores a seguir:

  • MissingField.Error: todos os campos ausentes produzem um erro (padrão).
  • MissingField.UseNull: todos os campos ausentes são incluídos como null valores.

  O uso MissingField.Ignore nesse parâmetro produz um erro.

Exemplo 1

Cria uma tabela com base nos registros usando os nomes de campo dos registros como nomes de coluna.

Usage

Table.FromRecords({
    [CustomerID = 1, Name = "Bob", Phone = "123-4567"],
    [CustomerID = 2, Name = "Jim", Phone = "987-6543"],
    [CustomerID = 3, Name = "Paul", Phone = "543-7890"]
})

Saída

#table(type table[CustomerID = any, Name = any, Phone = any],
{
    {1, "Bob", "123-4567"},
    {2, "Jim", "987-6543"},
    {3, "Paul", "543-7890"}
})

Exemplo 2

Cria uma tabela com base nos registros com colunas de tipo e seleciona as colunas de número.

Usage

Table.ColumnsOfType(
    Table.FromRecords(
        {[CustomerID = 1, Name = "Bob"]},
        type table[CustomerID = Number.Type, Name = Text.Type]
    ),
    {type number}
)

Saída

{"CustomerID"}

Exemplo 3

Crie uma tabela que contenha o nome, a inicial do meio e o sobrenome dos clientes dos registros especificados. Se algum dos valores estiver ausente, substitua o valor por null.

Usage

Table.FromRecords({
        [CustomerID = 1, FirstName = "Bob", MiddleInitial = "C", LastName = "Smith"],
        [CustomerID = 2, FirstName = "Sarah", LastName = "Jones"],
        [CustomerID = 3, FirstName = "Harry", MiddleInitial = "H"]
    },
    type table [FirstName = nullable text, MiddleInitial = nullable text, LastName = nullable text],
    MissingField.UseNull)

Saída

#table(type table[FirstName = text, MiddleInitial = text, LastName = text],
{
    {"Bob", "C", "Smith"},
    {"Sarah", null, "Jones"},
    {"Harry", "H", null}
})

Conteúdo relacionado

Campo ausente