Criar uma máquina virtual no VMware vCenter usando métodos de infraestrutura como código

Este artigo descreve como provisionar uma VM usando recursos do vCenter usando um modelo Bicep.

Criar uma máquina Arc VMware usando o modelo Bicep

O modelo de bíceps a seguir pode ser usado para criar uma máquina Arc VMware. Aqui está a lista de modelos disponíveis do Azure Resource Manager (ARM), Bicep e Terraform para recursos VMware compatíveis com o Arc. Para acionar qualquer outra operação do Arc, converta o modelo ARM correspondente num modelo Bicep.

// Parameters
param vmName string = 'contoso-vm'
param vmAdminPassword string = 'examplepassword!#'
param vCenterId string = '/subscriptions/aaaa0a0a-bb1b-cc2c-dd3d-eeeeee4e4e4e/resourceGroups/contoso-rg/providers/Microsoft.ConnectedVMwarevSphere/vcenters/contoso-vcenter'
param templateId string = '/subscriptions/aaaa0a0a-bb1b-cc2c-dd3d-eeeeee4e4e4e/resourceGroups/contoso-rg/providers/Microsoft.ConnectedVMwarevSphere/VirtualMachineTemplates/contoso-template-win22'
param resourcePoolId string = '/subscriptions/aaaa0a0a-bb1b-cc2c-dd3d-eeeeee4e4e4e/resourceGroups/contoso-rg/providers/Microsoft.ConnectedVMwarevSphere/ResourcePools/contoso-respool'
param datastoreId string = '/subscriptions/aaaa0a0a-bb1b-cc2c-dd3d-eeeeee4e4e4e/resourceGroups/contoso-rg/providers/Microsoft.ConnectedVMwarevSphere/Datastores/contoso-datastore'
param networkId string = '/subscriptions/aaaa0a0a-bb1b-cc2c-dd3d-eeeeee4e4e4e/resourceGroups/contoso-rg/providers/Microsoft.ConnectedVMwarevSphere/VirtualNetworks/contoso-network'
param extendedLocation object = {
  type: 'customLocation'
  name: '/subscriptions/aaaa0a0a-bb1b-cc2c-dd3d-eeeeee4e4e4e/resourceGroups/contoso-rg/providers/Microsoft.ExtendedLocation/customLocations/contoso-customlocation'
}
param ipSettings object = {
  allocationMethod: 'static'
  gateway: ['172.24.XXX.1']
  ipAddress: '172.24.XXX.105'
  subnetMask: '255.255.255.0'
  dnsServers: ['172.24.XXX.9']
}

resource contosoMachine 'Microsoft.HybridCompute/machines@2023-10-03-preview' = {
  name: vmName
  location:'westeurope'
  kind:'VMware'
  properties:{}
  tags: {
    foo: 'bar'
  }
}

resource vm 'Microsoft.ConnectedVMwarevSphere/virtualMachineInstances@2023-12-01' = {
  name: 'default'
  scope: contosoMachine
  extendedLocation: extendedLocation
  properties: {
    hardwareProfile: {
      memorySizeMB: 4096
      numCPUs: 2
    }
    osProfile: {
      computerName: vmName
      adminPassword: vmAdminPassword
    }
    placementProfile: {
      resourcePoolId: resourcePoolId
      datastoreId: datastoreId
    }
    infrastructureProfile: {
      templateId: templateId
      vCenterId: vCenterId
    }
    networkProfile: {
      networkInterfaces: [
        {
          nicType: 'vmxnet3'
          ipSettings: ipSettings
          networkId: networkId
          name: 'VLAN103NIC'
          powerOnBoot: 'enabled'
        }
      ]
    }
  }
}

// Outputs
output vmId string = vm.id

Este artigo descreve como provisionar uma VM usando recursos do vCenter usando um modelo Terraform.

Crie uma máquina Arc VMware com Terraform

Pré-requisitos

Assinatura do Azure: verifique se você tem uma assinatura ativa do Azure.
Terraform: Instale Terraform na sua máquina.
CLI do Azure: instale a CLI do Azure para autenticar e gerenciar recursos.

Siga estas etapas para criar uma máquina Arc VMware usando Terraform. Os dois cenários a seguir são abordados neste artigo:

Para as VMs descobertas no inventário do vCenter, ative a operação no Azure e instale os agentes Arc.
Crie uma nova VM Arc VMware usando modelos, pool de recursos, Datastore e instale agentes Arc.

Cenário 1

Para as VMs descobertas no inventário do vCenter, ative a operação no Azure e instale os agentes Arc.

Etapa 1: Definir variáveis em um arquivo de variables.tf

Crie um arquivo chamado variables.tf e defina todas as variáveis necessárias.

variable "subscription_id" {
  description = "The subscription ID for the Azure account."
  type        = string
}

variable "resource_group_name" {
  description = "The name of the resource group."
  type        = string
}

variable "location" {
  description = "The location/region where the resources will be created."
  type        = string
}

variable "machine_name" {
  description = "The name of the machine."
  type        = string
}

variable "inventory_item_id" {
  description = "The ID of the Inventory Item for the VM."
  type        = string
}

variable "custom_location_id" {
  description = "The ID of the custom location."
  type        = string
}

variable "vm_username" {
  description = "The admin username for the VM."
  type        = string
}

variable "vm_password" {
  description = "The admin password for the VM."
  type        = string
}

variable "resource_group_name" {
  description = "The name of the resource group."
  type        = string
}

variable "location" {
  description = "The location/region where the resources will be created."
  type        = string
}

variable "machine_name" {
  description = "The name of the machine."
  type        = string
}

variable "vm_username" {
  description = "The admin username for the VM."
  type        = string
}

variable "vm_password" {
  description = "The admin password for the VM."
  type        = string
}

variable "inventory_id" {
  description = "The Inventory ID for the VM."
  type        = string
}

variable "vcenter_id" {
  description = "The ID of the vCenter."
  type        = string
}

variable "custom_location_id" {
  description = "The ID of the custom location."
  type        = string
}

Etapa 2: Criar um arquivo tfvars

Crie um ficheiro chamado CreateVMwareVM.tfvars e forneça valores de exemplo para as variáveis.

subscription_id      = "your-subscription-id"
resource_group_name  = "your-resource-group"
location             = "eastus"
machine_name         = "test_machine0001"
inventory_item_id    = "/subscriptions/your-subscription-id/resourceGroups/your-resource-group/providers/Microsoft.ConnectedVMwarevSphere/VCenters/your-vcenter-id/InventoryItems/your-inventory-item-id"
custom_location_id   = "/subscriptions/your-subscription-id/resourceGroups/your-resource-group/providers/Microsoft.ExtendedLocation/customLocations/your-custom-location-id"
vm_username          = "Administrator"
vm_password          = " The admin password for the VM "

Etapa 3: Modificar a configuração para usar variáveis

Crie um arquivo chamado main.tf e insira o código a seguir.

terraform {
  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = ">= 3.0"
    }
    azapi = {
      source  = "azure/azapi"
      version = ">= 1.0.0"
    }
  }
}

# Configure the AzureRM provider with the subscription ID
provider "azurerm" {
  features {}
  subscription_id = var.subscription_id
}

# Configure the AzAPI provider with the subscription ID
provider "azapi" {
  subscription_id = var.subscription_id
}

# Retrieve the resource group details
data "azurerm_resource_group" "example" {
  name = var.resource_group_name
}

# Create a VMware machine resource in Azure
resource "azapi_resource" "test_machine0001" {
  schema_validation_enabled = false
  parent_id = data.azurerm_resource_group.example.id
  type = "Microsoft.HybridCompute/machines@2023-06-20-preview"
  name = var.machine_name
  location = data.azurerm_resource_group.example.location
  body = jsonencode({
      kind = "VMware"
      identity = {
        type = "SystemAssigned"
      }
  })
}

# Create a Virtual Machine instance using the VMware machine and Inventory Item ID
resource "azapi_resource" "test_inventory_vm0001" {
  schema_validation_enabled = false
  type = "Microsoft.ConnectedVMwarevSphere/VirtualMachineInstances@2023-10-01"
  name = "default"
  parent_id = azapi_resource.test_machine0001.id
  body = jsonencode({
      properties = {
          infrastructureProfile = {
            inventoryItemId = var.inventory_item_id
          }
      }
      extendedLocation = {
        type = "CustomLocation"
        name = var.custom_location_id
      }
  })
  depends_on = [azapi_resource.test_machine0001]
}

# Install Arc agent on the VM
resource "azapi_resource" "guestAgent" {
  type      = "Microsoft.ConnectedVMwarevSphere/virtualMachineInstances/guestAgents@2023-10-01"
  parent_id = azapi_resource.test_inventory_vm0001.id
  name      = "default"
  body = jsonencode({
    properties = {
      credentials = {
        username = var.vm_username
        password = var.vm_password
      }
      provisioningAction = "install"
    }
  })
  schema_validation_enabled = false
  ignore_missing_property   = false
  depends_on = [azapi_resource.test_inventory_vm0001]
}

Etapa 4: Executar comandos Terraform

Use o sinalizador -var-file para passar o ficheiro .tfvars durante os comandos Terraform.

Inicializar Terraform (se ainda não tiver sido inicializado): terraform init
Valide a configuração: terraform validate -var-file="CreateVMwareVM.tfvars"
Planeje as alterações: terraform plan -var-file="CreateVMwareVM.tfvars"
Aplique as alterações: terraform apply -var-file="CreateVMwareVM.tfvars"

Confirme o prompt digitando sim para aplicar as alterações.

Melhores práticas

Use o controle de versão: mantenha seus arquivos de configuração do Terraform sob controle de versão (por exemplo, Git) para controlar as alterações ao longo do tempo.
Revise os planos cuidadosamente: sempre revise a saída do plano de terraforma antes de aplicar alterações para garantir que você entenda quais alterações serão feitas.
Gerenciamento de estado: Faça backup regularmente de seus arquivos de estado Terraform para evitar a perda de dados.

Seguindo estas etapas, você pode criar e gerenciar efetivamente VMs HCRP e Arc VMware no Azure usando o Terraform e instalar agentes convidados nas VMs criadas.

Cenário 2

Crie uma nova VM Arc VMware usando modelos, pool de recursos, Datastore e instale agentes Arc.

Etapa 1: Definir variáveis em um arquivo de variables.tf

Crie um arquivo chamado variables.tf e defina todas as variáveis necessárias.

variable "subscription_id" {
  description = "The subscription ID for the Azure account."
  type        = string
}

variable "resource_group_name" {
  description = "The name of the resource group."
  type        = string
}

variable "location" {
  description = "The location/region where the resources will be created."
  type        = string
}

variable "machine_name" {
  description = "The name of the machine."
  type        = string
}

variable "vm_username" {
  description = "The admin username for the VM."
  type        = string
}

variable "vm_password" {
  description = "The admin password for the VM."
  type        = string
}

variable "template_id" {
  description = "The ID of the VM template."
  type        = string
}

variable "vcenter_id" {
  description = "The ID of the vCenter."
  type        = string
}

variable "resource_pool_id" {
  description = "The ID of the resource pool."
  type        = string
}

variable "datastore_id" {
  description = "The ID of the datastore."
  type        = string
}

variable "custom_location_id" {
  description = "The ID of the custom location."
  type        = string
}

Etapa 2: Criar arquivo tfvars

Crie um ficheiro chamado CreateVMwareVM.tfvars e forneça valores de exemplo para as variáveis.

subscription_id      = "your-subscription-id"
resource_group_name  = "your-resource-group"
location             = "eastus"
machine_name         = "test_machine0002"
vm_username          = "Administrator"
vm_password          = "*********"
template_id          = "/subscriptions/your-subscription-id/resourceGroups/your-resource-group/providers/Microsoft.ConnectedVMwarevSphere/virtualmachinetemplates/your-template-id"
vcenter_id           = "/subscriptions/your-subscription-id/resourceGroups/your-resource-group/providers/Microsoft.ConnectedVMwarevSphere/VCenters/your-vcenter-id"
resource_pool_id     = "/subscriptions/your-subscription-id/resourceGroups/your-resource-group/providers/Microsoft.ConnectedVMwarevSphere/resourcepools/your-resource-pool-id"
datastore_id         = "/subscriptions/your-subscription-id/resourceGroups/your-resource-group/providers/Microsoft.ConnectedVMwarevSphere/datastores/your-datastore-id"
custom_location_id   = "/subscriptions/your-subscription-id/resourceGroups/your-resource-group/providers/Microsoft.ExtendedLocation/customLocations/your-custom-location-id"

Etapa 3: Modificar a configuração para usar variáveis

Crie um arquivo chamado main.tf e insira o código a seguir.

terraform {
  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = ">= 3.0"
    }
    azapi = {
      source  = "azure/azapi"
      version = ">= 1.0.0"
    }
  }
}

# Configure the AzureRM provider with the subscription ID
provider "azurerm" {
  features {}
  subscription_id = var.subscription_id
}

# Configure the AzAPI provider with the subscription ID
provider "azapi" {
  subscription_id = var.subscription_id
}

# Retrieve the resource group details
data "azurerm_resource_group" "example" {
  name = var.resource_group_name
}

# Create a VMware machine resource in Azure
resource "azapi_resource" "test_machine0002" {
  schema_validation_enabled = false
  parent_id = data.azurerm_resource_group.example.id
  type = "Microsoft.HybridCompute/machines@2023-06-20-preview"
  name = var.machine_name
  location = data.azurerm_resource_group.example.location
  body = jsonencode({
      kind = "VMware"
      identity = {
        type = "SystemAssigned"
      }
  })
}

# Create a Virtual Machine instance using the VMware machine created above
resource "azapi_resource" "test_vm0002" {
  schema_validation_enabled = false
  type = "Microsoft.ConnectedVMwarevSphere/VirtualMachineInstances@2023-10-01"
  name = "default"
  parent_id = azapi_resource.test_machine0002.id
  body = jsonencode({
      properties = {
          infrastructureProfile = {
            templateId = var.template_id
            vCenterId = var.vcenter_id
          }

          placementProfile = {
            resourcePoolId = var.resource_pool_id
            datastoreId = var.datastore_id
          }

          osProfile = {
            adminPassword = var.vm_password
          }
      }
      extendedLocation = {
        type = "CustomLocation"
        name = var.custom_location_id
      }
  })
  depends_on = [azapi_resource.test_machine0002]
}

# Create a guest agent for the VM instance
resource "azapi_resource" "guestAgent" {
  type      = "Microsoft.ConnectedVMwarevSphere/virtualMachineInstances/guestAgents@2023-10-01"
  parent_id = azapi_resource.test_vm0002.id
  name      = "default"
  body = jsonencode({
    properties = {
      credentials = {
        username = var.vm_username
        password = var.vm_password
      }
      provisioningAction = "install"
    }
  })
  schema_validation_enabled = false
  ignore_missing_property   = false
  depends_on = [azapi_resource.test_vm0002]
}

Etapa 4: Executar comandos Terraform

Use o sinalizador -var-file para passar o ficheiro .tfvars durante os comandos Terraform.

Inicializar Terraform (se ainda não tiver sido inicializado): terraform init
Valide a configuração: terraform validate -var-file="CreateVMwareVM.tfvars"
Planeje as alterações: terraform plan -var-file="CreateVMwareVM.tfvars"
Aplique as alterações: terraform apply -var-file="CreateVMwareVM.tfvars"

Confirme o prompt digitando sim para aplicar as alterações.

Melhores práticas

Use o controle de versão: mantenha seus arquivos de configuração do Terraform sob controle de versão (por exemplo, Git) para controlar as alterações ao longo do tempo.
Revise os planos cuidadosamente: sempre revise a saída do plano de terraforma antes de aplicar alterações para garantir que você entenda quais alterações serão feitas.
Gerenciamento de estado: Faça backup regularmente de seus arquivos de estado Terraform para evitar a perda de dados.

Próximos passos

Execute operações em VMs VMware no Azure.

Feedback

Esta página foi útil?

Last updated on 2025-07-22

Partilhar via

Criar uma máquina virtual no VMware vCenter usando métodos de infraestrutura como código

Criar uma máquina Arc VMware usando o modelo Bicep

Crie uma máquina Arc VMware com Terraform

Pré-requisitos

Cenário 1

Etapa 1: Definir variáveis em um arquivo de variables.tf

Etapa 2: Criar um arquivo tfvars

Etapa 3: Modificar a configuração para usar variáveis

Etapa 4: Executar comandos Terraform

Melhores práticas

Cenário 2

Etapa 1: Definir variáveis em um arquivo de variables.tf

Etapa 2: Criar arquivo tfvars

Etapa 3: Modificar a configuração para usar variáveis

Etapa 4: Executar comandos Terraform

Melhores práticas

Próximos passos

Feedback

Recursos adicionais