Consultas para a tabela AEWExperimentAssignmentSummary

Para obter informações sobre como usar essas consultas no portal do Azure, consulte o tutorial do Log Analytics. Para a API REST, consulte Consulta.

Contagem de atribuição de variantes por características

Liste o número total de atribuições de cada variante em alocações de funcionalidades.

// Variant assignment counts by features
AEWExperimentAssignmentSummary
| summarize
    IsControlVariant = take_any(IsControlVariant),
    AllocationPercentage = take_any(AllocationPercentage),
    AssignmentEventCount = sum(AssignmentEventCount),
    EarliestAssignment = min(MinTimeGenerated),
    LatestAssignment = max(MaxTimeGenerated)
    by FeatureName, AllocationId, Variant
| order by FeatureName asc, LatestAssignment desc, Variant asc

Metadados do quadro de pontuação mais recentes para uma determinada característica

Consulte os metadados mais recentes do experimentscorecard para um determinado recurso.

// Latest scorecard metadata for a given feature
// set the feature flag name to query
let QueryFeature = "MyFeatureFlag";
AEWExperimentAssignmentSummary
| where FeatureName == QueryFeature
| summarize MaxTimeGenerated=max(MaxTimeGenerated), Variants=make_set(Variant, 1000) by AllocationId
| summarize arg_max(MaxTimeGenerated, *)
| join kind=inner AEWExperimentScorecards on AllocationId
| summarize arg_max(TimeGenerated, ScorecardId)
| project
    FeatureName, AllocationId, Variants,
    ScorecardId, AnalysisStartTime, AnalysisEndTime, Insights

Resultados mais recentes do painel de pontuação para uma determinada funcionalidade

Consulte o resultado mais recente do cartão de pontuação do experimento para uma determinada característica.

// Latest scorecard results for a given feature
// set the feature flag name to query
let QueryFeature = "MyFeatureFlag";
AEWExperimentAssignmentSummary
| where FeatureName == QueryFeature
| summarize arg_max(MaxTimeGenerated, AllocationId)
| join kind=inner AEWExperimentScorecards on AllocationId
| summarize arg_max(TimeGenerated, ScorecardId)
| join kind=inner AEWExperimentScorecardMetricPairs on ScorecardId
| project
    ScorecardId, MetricId, MetricDisplayName, MetricKind, MetricTags,
    TreatmentVariant, TreatmentCount, TreatmentMetricValue,
    ControlVariant, ControlCount, ControlMetricValue,
    TreatmentEffect, RelativeDifference, PValue, Insights