Implantar uma conta do Azure Batch e dois pools - Terraform

Neste início rápido, você cria uma conta de Lote do Azure, uma conta de Armazenamento do Azure e dois pools de Lotes usando o Terraform. O Batch é um serviço de agendamento de tarefas baseado em nuvem que paraleliza e distribui o processamento de grandes volumes de dados em muitos computadores. É normalmente usado para varreduras paramétricas, simulações de Monte Carlo, modelagem de risco financeiro e outras aplicações de computação de alto desempenho. Uma conta de lote é o recurso de nível superior no serviço de lote que fornece acesso a pools, trabalhos e tarefas. A conta de armazenamento é usada para armazenar e gerenciar todos os arquivos usados e gerados pelo serviço de lote, enquanto os dois pools de lotes são coleções de nós de computação que executam as tarefas.

Terraform permite a definição, visualização e implantação de infraestrutura em nuvem. Usando Terraform, você cria arquivos de configuração usando a sintaxe HCL. A sintaxe HCL permite especificar o provedor de nuvem - como o Azure - e os elementos que compõem sua infraestrutura de nuvem. Depois de criar os arquivos de configuração, você cria um plano de execução que permite visualizar as alterações na infraestrutura antes que elas sejam implantadas. Depois de verificar as alterações, você aplica o plano de execução para implantar a infraestrutura.

Pré-requisitos

• Crie uma conta do Azure com uma assinatura ativa. Você pode criar uma conta gratuitamente.
• Instale e configure o Terraform.

Implementar o código Terraform

1. Crie um diretório no qual testar e executar o código Terraform de exemplo e torne-o o diretório atual.

2. Crie um arquivo chamado main.tfe insira o seguinte código:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   resource "random_string" "storage_account_name" {
     length  = 8
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_storage_account" "example" {
     name                     = random_string.storage_account_name.result
     resource_group_name      = azurerm_resource_group.rg.name
     location                 = azurerm_resource_group.rg.location
     account_tier             = "Standard"
     account_replication_type = "LRS"
   }
   
   resource "random_string" "batch_account_name" {
     length  = 8
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_batch_account" "example" {
     name                                = random_string.batch_account_name.result
     resource_group_name                 = azurerm_resource_group.rg.name
     location                            = azurerm_resource_group.rg.location
     storage_account_id                  = azurerm_storage_account.example.id
     storage_account_authentication_mode = "StorageKeys"
   }
   
   resource "random_pet" "azurerm_batch_pool_name" {
     prefix = "pool"
   }
   
   resource "azurerm_batch_pool" "fixed" {
     name                = "${random_pet.azurerm_batch_pool_name.id}-fixed-pool"
     resource_group_name = azurerm_resource_group.rg.name
     account_name        = azurerm_batch_account.example.name
     display_name        = "Fixed Scale Pool"
     vm_size             = "Standard_A1"
     node_agent_sku_id   = "batch.node.ubuntu 22.04"
   
     fixed_scale {
       target_dedicated_nodes = 2
       resize_timeout         = "PT15M"
     }
   
     storage_image_reference {
       publisher = "Canonical"
       offer     = "0001-com-ubuntu-server-jammy"
       sku       = "22_04-lts"
       version   = "latest"
     }
   
     start_task {
       command_line       = "echo 'Hello World from $env'"
       task_retry_maximum = 1
       wait_for_success   = true
   
       common_environment_properties = {
         env = "TEST"
       }
   
       user_identity {
         auto_user {
           elevation_level = "NonAdmin"
           scope           = "Task"
         }
       }
     }
   
     metadata = {
       "tagName" = "Example tag"
     }
   }
   
   resource "azurerm_batch_pool" "autopool" {
     name                = "${random_pet.azurerm_batch_pool_name.id}-autoscale-pool"
     resource_group_name = azurerm_resource_group.rg.name
     account_name        = azurerm_batch_account.example.name
     display_name        = "Auto Scale Pool"
     vm_size             = "Standard_A1"
     node_agent_sku_id   = "batch.node.ubuntu 22.04"
   
     auto_scale {
       evaluation_interval = "PT15M"
   
       formula = <<EOF
         startingNumberOfVMs = 1;
         maxNumberofVMs = 25;
         pendingTaskSamplePercent = $PendingTasks.GetSamplePercent(180 * TimeInterval_Second);
         pendingTaskSamples = pendingTaskSamplePercent < 70 ? startingNumberOfVMs : avg($PendingTasks.GetSample(180 * TimeInterval_Second));
         $TargetDedicatedNodes=min(maxNumberofVMs, pendingTaskSamples);
   EOF
     }
   
     storage_image_reference {
       publisher = "Canonical"
       offer     = "0001-com-ubuntu-server-jammy"
       sku       = "22_04-lts"
       version   = "latest"
     }
   }
   

3. Crie um arquivo chamado outputs.tfe insira o seguinte código:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "storage_account_name" {
     value = azurerm_storage_account.example.name
   }
   
   output "batch_account_name" {
     value = azurerm_batch_account.example.name
   }
   
   output "batch_pool_fixed_name" {
     value = azurerm_batch_pool.fixed.name
   }
   
   output "batch_pool_autopool_name" {
     value = azurerm_batch_pool.autopool.name
   }
   

4. Crie um arquivo chamado providers.tfe insira o seguinte código:

   terraform {
     required_version = ">=1.0"
   
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

5. Crie um arquivo chamado variables.tfe insira o seguinte código:

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location of the resource group."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   

Inicializar Terraform

Execute terraform init para inicializar a implantação do Terraform. Este comando baixa o provedor do Azure necessário para gerenciar seus recursos do Azure.

terraform init -upgrade

Pontos principais:

• O parâmetro -upgrade atualiza os plug-ins de provedor necessários para a versão mais recente que está em conformidade com as restrições de versão da configuração.

Criar um plano de execução do Terraform

Execute o comando terraform plan para criar um plano de execução.

terraform plan -out main.tfplan

Pontos principais:

• O comando terraform plan cria um plano de execução, mas não o executa. Em vez disso, ele determina quais ações são necessárias para criar a configuração especificada em seus arquivos de configuração. Esse padrão permite que você verifique se o plano de execução corresponde às suas expectativas antes de fazer quaisquer alterações nos recursos reais.
• O parâmetro opcional -out permite especificar um arquivo de saída para o plano. O uso do -out parâmetro garante que o plano revisado seja exatamente o que é aplicado.

Aplicar um plano de execução do Terraform

Execute terraform apply para aplicar o plano de execução à sua infraestrutura de nuvem.

terraform apply main.tfplan

Pontos principais:

• O comando de exemplo terraform apply pressupõe que já executaste terraform plan -out main.tfplan anteriormente.
• Se você especificou um nome de arquivo diferente para o parâmetro -out, use esse mesmo nome de arquivo na chamada para terraform apply.
• Se você não usou o parâmetro -out, chame terraform apply sem nenhum parâmetro.

Verificar os resultados

az batch account show --name <batch_account_name> --resource-group <resource_group_name>

Limpeza de recursos

Quando você não precisar mais dos recursos criados via Terraform, execute as seguintes etapas:

1. Execute terraform plan e especifique o parâmetro destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Pontos principais:

   • O comando terraform plan cria um plano de execução, mas não o executa. Em vez disso, ele determina quais ações são necessárias para criar a configuração especificada em seus arquivos de configuração. Esse padrão permite que você verifique se o plano de execução corresponde às suas expectativas antes de fazer quaisquer alterações nos recursos reais.
   • O parâmetro opcional -out permite especificar um arquivo de saída para o plano. O uso do -out parâmetro garante que o plano revisado seja exatamente o que é aplicado.

2. Execute terraform apply para aplicar o plano de execução.

   terraform apply main.destroy.tfplan
   

Solucionar problemas do Terraform no Azure

Solucione problemas comuns ao usar o Terraform no Azure.

Próximos passos