Elementos visuais específicos do painel de controlo

Todas as visualizações criadas no contexto do operador de renderização estão disponíveis em visualizações de painel. No entanto, as visualizações a seguir só estão disponíveis em painéis do Azure Data Explorer, Real-Time Dashboards ou na interface do usuário da Web do Azure Data Explorer, e não com o operador de renderização.

Para saber como personalizar qualquer elemento visual do painel, consulte Personalizar visuais do painel do Azure Data Explorer

Para obter informações gerais sobre painéis no Azure Data Explorer, consulte Visualizar dados com painéis do Azure Data Explorer.

Gráfico de funil

Um gráfico de funil visualiza um processo linear que tem estágios sequenciais e conectados. Cada etapa do funil representa uma porcentagem do total. Assim, na maioria dos casos, um gráfico de funil tem a forma de um funil, com o primeiro estágio sendo o maior, e cada estágio subsequente menor do que seu antecessor.

O exemplo a seguir visualiza a progressão das solicitações do Server, mostrando o número total de sessões, solicitações e seu status de conclusão. Ele realça a redução de número de sessões em relação aos pedidos e a proporção de pedidos concluídos versus incompletos.

Exemplo de consulta

let stageOrder = datatable(Stage:string, Order:int)
[
    "session_id", 1,
    "request_id", 2,
    "Completed", 3,
    "Incomplete", 4
];

let base = TransformedServerMetrics
| where MetricType == "sqlserver_requests";

// Build the funnel table dynamically
let funnelData = 
    union 
    (base | where SQLMetrics == "session_id" | summarize Count = count() | extend Stage = "session_id"),
    (base | where SQLMetrics == "request_id" | summarize Count = count() | extend Stage = "request_id"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value == 100) | extend Stage = "Completed"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value < 100) | extend Stage = "Incomplete");

// Join with stage order and order properly
funnelData
| join kind=inner stageOrder on Stage
| order by Order asc
| project Stage, Count

Mapa de Calor

Um mapa de calor mostra valores para uma variável principal de interesse em relação a duas variáveis de eixo, como uma grelha de quadrados coloridos.

Para renderizar um heatmap, a consulta deve gerar uma tabela com três colunas. Os dados utilizados para o campo de valor devem ser numéricos. As colunas que serão usadas para valores x e y usam as seguintes regras:

• Se os valores na coluna x estiverem no string formato, os valores na coluna y também deverão estar no string formato.
• Se os valores na coluna x estiverem no datetime formato, os valores na coluna y devem ser numéricos.

O exemplo a seguir mostra a distribuição das cinco métricas SQL mais frequentes em diferentes tipos de métricas. Ele destaca quais tipos de métricas são mais comuns para cada métrica SQL, facilitando a identificação de padrões de atividade nas métricas principais.

Exemplo de consulta

let topMetrics = TransformedServerMetrics
| summarize TotalCount = count() by SQLMetrics
| top 5 by TotalCount;  // pick only the 5 most common metrics

TransformedServerMetrics
| where SQLMetrics in (topMetrics | project SQLMetrics)
| summarize Count = count() by SQLMetrics, MetricType
| project X = MetricType, Y = SQLMetrics, Value = Count