Partilhar via

Quickstart: Implemente um cluster Azure DocumentDB usando o Bicep

Neste quickstart, implementa um novo cluster Azure DocumentDB usando o Bicep. Este guia de início rápido fornece instruções passo a passo para o ajudar a começar rapidamente. Este cluster contém todos os seus recursos do MongoDB: bases de dados, coleções e documentos. Fornece um endpoint único para ferramentas e kits de desenvolvimento de software (SDKs) se ligarem ao Azure DocumentDB e realizarem operações.

Pré-requisitos

  • Uma assinatura do Azure

    • Se você não tiver uma assinatura do Azure, crie uma conta gratuita

Configurar ambiente

Configure o seu ambiente Azure CLI para gerir os recursos Azure DocumentDB na sua subscrição.

  1. Comece em um diretório vazio.

  2. Entre na CLI do Azure.

    az login

  3. Verifica a tua subscrição alvo do Azure.

    az account show

    Observação

    Se não estiver ligado à subscrição que esperava, use este comando para alterar a sua subscrição:

    az account set --subscription "<subscription-name>"

    Para mais informações, consulte gerir subscrições Azure com a CLI do Azure.

Prepare o modelo de bíceps

Crie e configure um ficheiro Bicep para definir os recursos necessários para a implementação de um cluster Azure DocumentDB.

  1. Cria um novo ficheiro main.bicep no diretório do teu projeto.

  2. Adicione este modelo ao conteúdo do ficheiro.

    @description('Cluster name')
@minLength(8)
@maxLength(40)
param clusterName string = 'msdocs-${uniqueString(resourceGroup().id)}'

@description('Location for the cluster.')
param location string = resourceGroup().location

@description('Username for admin user')
param adminUsername string

@secure()
@description('Password for admin user')
@minLength(8)
@maxLength(128)
param adminPassword string

resource cluster 'Microsoft.DocumentDB/mongoClusters@2025-09-01' = {
  name: clusterName
  location: location
  properties: {
    administrator: {
      userName: adminUsername
      password: adminPassword
    }
    serverVersion: '8.0'
    sharding: {
      shardCount: 1
    }
    storage: {
      sizeGb: 32
    }
    highAvailability: {
      targetMode: 'Disabled'
    }
    compute: {
      tier: 'M10'
    }
  }
}

resource firewallRules 'Microsoft.DocumentDB/mongoClusters/firewallRules@2025-09-01' = {
  parent: cluster
  name: 'AllowAllAzureServices'
  properties: {
    startIpAddress: '0.0.0.0'
    endIpAddress: '0.0.0.0'
  }
}

    Sugestão

    Para mais informações sobre as opções que utilizam o Microsoft.DocumentDB/mongoclusters recurso, consulte Microsoft.DocumentDB/mongoclusters a documentação.

Implementar o modelo

Implemente o template criado na etapa anterior usando uma implementação do Azure Resource Manager.

  1. Use o az group create comando para criar um novo grupo de recursos na sua subscrição.

    az group create \
    --name "<resource-group-name>" \
    --location "<location>"

  2. Use az deployment group create para implementar o modelo de bíceps. É então solicitado que introduza um valor para os parâmetros adminUsername e adminPassword.

    az deployment group create \
    --resource-group "<resource-group-name>" \
    --template-file 'main.bicep'

    Sugestão

    Alternativamente, use a opção --parameters para fornecer um ficheiro de parâmetros com valores pré-definidos.

    az deployment group create \
    --resource-group "<resource-group-name>" \
    --template-file 'main.bicep' \
    --parameters @main.parameters.json

    Este ficheiro JSON de exemplo injeta os valores clusteradmin e P@ssw.rd nos parâmetros adminUsername e adminPassword respetivamente.

    {
  "$schema": "https://schema.management.azure.com/schemas/2015-01-01/deploymentParameters.json#",
  "contentVersion": "1.0.0.0",
  "parameters": {
    "adminUsername": {
      "value": "clusteradmin"
    },
    "adminPassword": {
      "value": "P@ssw.rd"
    }
  }
}

  3. Espere que a operação de implantação termine antes de avançar.

Analisar os recursos implementados

Liste os recursos Azure DocumentDB implementados no seu grupo de recursos.

  1. Use az resource list para obter uma lista de recursos no seu grupo de recursos.

    az resource list \
    --resource-group "<resource-group-name>" \
    --namespace "Microsoft.DocumentDB" \
    --resource-type "mongoClusters" \
    --query "[].name" \
    --output json

  2. No exemplo de saída, procure recursos que tenham um tipo de Microsoft.DocumentDB/mongoClusters. Aqui está um exemplo do tipo de saída que pode antecipar:

    [
  "msdocs-documentdb-example-cluster"
]

Limpeza de recursos

Quando terminares o teu cluster do Azure DocumentDB, podes eliminar os recursos Azure que criaste para não incorreres em mais encargos.

  1. Use az group delete para remover o grupo de recursos da sua subscrição.

    az group delete \
    --name "<resource-group-name>" \
    --yes \
    --no-wait

    Importante

    Certifique-se de que já não precisa dos recursos antes de executar este comando, pois ele apaga permanentemente.

Conteúdo relacionado

  • Last updated on