Conectar uma instância do Banco de Dados do Azure para MySQL ao seu aplicativo no Azure Spring Apps

1. No arquivo pom.xml do seu projeto, adicione a seguinte dependência:

   <dependency>
       <groupId>org.springframework.boot</groupId>
       <artifactId>spring-boot-starter-data-jpa</artifactId>
   </dependency>
   <dependency>
       <groupId>com.azure.spring</groupId>
       <artifactId>spring-cloud-azure-starter-jdbc-mysql</artifactId>
   </dependency>
   

2. No arquivo application.properties, remova quaisquer spring.datasource.* propriedades.

3. Atualize o aplicativo atual executando az spring app deploy, ou crie uma nova implantação para essa alteração executando az spring app deployment create.

Todas as cadeias de conexão e credenciais são injetadas como variáveis de ambiente, que você pode referenciar no código do aplicativo.

Para obter os nomes de variáveis de ambiente padrão, consulte Integrar o Banco de Dados do Azure para MySQL com o Service Connector.

Siga estas etapas para configurar seu aplicativo Spring para se conectar a um Banco de Dados do Azure para Servidor Flexível MySQL com uma identidade gerenciada atribuída pelo sistema.

1. Use o comando a seguir para instalar a extensão sem senha do Service Connector para a CLI do Azure.

   az extension add --name serviceconnector-passwordless --upgrade
   

2. Em seguida, use o seguinte comando para criar uma identidade gerenciada atribuída pelo usuário para autenticação do Microsoft Entra. Certifique-se de substituir as variáveis no exemplo por valores reais. Para obter mais informações, consulte Configurar a autenticação do Microsoft Entra para o Banco de Dados do Azure para MySQL - Servidor Flexível.

   export AZ_IDENTITY_RESOURCE_ID=$(az identity create \
       --name $AZURE_USER_IDENTITY_NAME \
       --resource-group $AZURE_IDENTITY_RESOURCE_GROUP \
       --query id \
       --output tsv)
   

3. Execute o az spring connection create comando, conforme mostrado no exemplo a seguir. Certifique-se de substituir as variáveis no exemplo por valores reais.

   az spring connection create mysql-flexible \
       --resource-group $AZURE_SPRING_APPS_RESOURCE_GROUP \
       --service $AZURE_SPRING_APPS_SERVICE_INSTANCE_NAME \
       --app $APP_NAME \
       --target-resource-group $MYSQL_RESOURCE_GROUP \
       --server $MYSQL_SERVER_NAME \
       --database $DATABASE_NAME \
       --system-identity mysql-identity-id=$AZ_IDENTITY_RESOURCE_ID
   

O script Terraform a seguir mostra como configurar um aplicativo Azure Spring Apps com o Banco de Dados do Azure para MySQL.

provider "azurerm" {
  features {}
}

variable "application_name" {
  type        = string
  description = "The name of your application"
  default     = "demo-abc"
}

variable "administrator_login" {
  type        = string
  description = "The MySQL administrator login"
  default     = "myadmin"
}

resource "azurerm_resource_group" "example" {
  name     = "example-resources"
  location = "West Europe"
}

resource "random_password" "password" {
  length           = 32
  special          = true
  override_special = "_%@"
}

resource "azurerm_mysql_server" "database" {
  name                = "mysql-${var.application_name}-001"
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location

  administrator_login          = var.administrator_login
  administrator_login_password = random_password.password.result

  sku_name                          = "B_Gen5_1"
  storage_mb                        = 5120
  version                           = "5.7"
  auto_grow_enabled                 = true
  backup_retention_days             = 7
  geo_redundant_backup_enabled      = false
  infrastructure_encryption_enabled = false
  public_network_access_enabled     = true
  ssl_enforcement_enabled           = true
  ssl_minimal_tls_version_enforced  = "TLS1_2"
}

resource "azurerm_mysql_database" "database" {
  name                = "mysqldb-${var.application_name}-001"
  resource_group_name = azurerm_resource_group.example.name
  server_name         = azurerm_mysql_server.database.name
  charset             = "utf8"
  collation           = "utf8_unicode_ci"
}

# This rule is to enable the 'Allow access to Azure services' checkbox
resource "azurerm_mysql_firewall_rule" "database" {
  name                = "mysqlfw-${var.application_name}-001"
  resource_group_name = azurerm_resource_group.example.name
  server_name         = azurerm_mysql_server.database.name
  start_ip_address    = "0.0.0.0"
  end_ip_address      = "0.0.0.0"
}

resource "azurerm_spring_cloud_service" "example" {
  name                = "example-springcloud"
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location
}

resource "azurerm_spring_cloud_app" "example" {
  name                = "example-springcloudapp"
  resource_group_name = azurerm_resource_group.example.name
  service_name        = azurerm_spring_cloud_service.example.name
  is_public           = true
  https_only          = true
}

resource "azurerm_spring_cloud_java_deployment" "example" {
  name                = "default"
  spring_cloud_app_id = azurerm_spring_cloud_app.example.id
  quota {
    cpu    = "2"
    memory = "4Gi"
  }
  instance_count      = 2
  jvm_options         = "-XX:+PrintGC"
  runtime_version     = "Java_11"

  environment_variables = {
    "spring.datasource.url" : "jdbc:mysql://${azurerm_mysql_server.database.fqdn}:3306/${azurerm_mysql_database.database.name}?useSSL=true&requireSSL=false&useLegacyDatetimeCode=false&serverTimezone=UTC"
    "spring.datasource.username" : "${var.administrator_login}@${azurerm_mysql_server.database.name}"
    "spring.datasource.password" : random_password.password.result
    "spring.jpa.properties.hibernate.dialect" : "org.hibernate.dialect.MySQL5InnoDBDialect"
  }
}

resource "azurerm_spring_cloud_active_deployment" "example" {
  spring_cloud_app_id = azurerm_spring_cloud_app.example.id
  deployment_name     = azurerm_spring_cloud_java_deployment.example.name
}