Guia de início rápido: criar uma tarefa de armazenamento com o Bicep

Este guia de início rápido descreve como criar uma tarefa de armazenamento usando o Bicep.

Bicep é uma linguagem de domínio específico (DSL) que utiliza sintaxe declarativa para implementar recursos do Azure. Fornece uma sintaxe concisa, segurança de tipos confiável e suporte para reutilização de código. O Bicep oferece a melhor experiência de criação para suas soluções de infraestrutura como código no Azure.

Pré-requisitos

Se não tiver uma subscrição do Azure, crie uma conta gratuita antes de começar.

Revise o arquivo Bicep

O arquivo Bicep utilizado neste início rápido é dos Modelos de Início Rápido do Azure.

@sys.description('The name of storage task.')
@minLength(3)
@maxLength(18)
param storageTaskName string

@sys.description('A description of the storage task.')
param description string

@sys.description('The region in which to create the storage task.')
param location string = resourceGroup().location

@sys.description('Locks the file for one day.')
param lockedUntilDate string = dateTimeAdd(utcNow(), 'P1D')

resource storageTask 'Microsoft.StorageActions/storageTasks@2023-01-01' = {
  name: storageTaskName
  location: location
  identity: {
    type: 'SystemAssigned'
  }
  properties: {
    action: {
      if: {
        condition: '[[endsWith(Name, \'.docx\')]]'
        operations: [
         {
            name: 'SetBlobImmutabilityPolicy'
            onSuccess: 'continue'
            onFailure: 'break'
            parameters: {
              untilDate: lockedUntilDate
              mode: 'locked'
            }
         }
         {
            name: 'SetBlobTags'
            onSuccess: 'continue'
            onFailure: 'break'
            parameters: {
                tagsetImmutabilityUpdatedBy: 'StorageTaskQuickstart'
            }     
         }
        ]
      }

    }
    description: description
    enabled: true
  }
}

O recurso do Azure Microsoft.StorageActions/storageTasks é definido no arquivo Bicep.

Desdobrar o arquivo Bicep

1. Salve o arquivo Bicep como main.bicep em seu computador local.

2. Implante o arquivo Bicep usando o Azure CLI ou o Azure PowerShell.

az group create --name exampleRG --location <region>

az deployment group create --resource-group exampleRG --template-file main.bicep --parameters storageTaskName="<storage-task-name>" description="<description>" 

New-AzResourceGroup -Name exampleRG -Location <region>

New-AzResourceGroupDeployment -ResourceGroupName exampleRG -TemplateFile ./main.bicep -storageTaskName "<storage-task-name>" -description "<description>"

Analisar os recursos implementados

1. No portal do Azure, procure Tarefas de Armazenamento. Em seguida, em Serviços, selecione Tarefas de armazenamento - Ações de Armazenamento do Azure.

2. Na lista de tarefas de armazenamento, procure o nome da tarefa de armazenamento que você implantou.

   

Limpeza de recursos

Quando já não for necessário, elimine o grupo de recursos. O grupo de recursos e todos os recursos no grupo de recursos são excluídos. Use o comando a seguir para excluir o grupo de recursos e todos os recursos contidos.

az group delete --name <resource-group-name>

Remove-AzResourceGroup -Name <resource-group-name>

Substitua <resource-group-name> pelo nome do seu grupo de recursos.

Próximos passos

Atribua uma tarefa de armazenamento a uma conta de armazenamento.