Funções X++ de tempo de execução de conversão

Este artigo descreve as funções de tempo de execução de conversão.

qualquer2Data

Converte um valor anytype em um valor de data .

date any2Date(anytype object)

Parâmetros

Valor de retorno

Um valor de data .

Observações

O parâmetro object pode ser da maioria dos tipos de dados, mas a saída útil é obtida quando é do tipo str ou int . O conteúdo inadequado gera um erro em tempo de execução.

Example

static void any2DateExample(Args _args)
{
    date myDate;
    str s;
    int i;
    s = "2010 6 17"; // A string object, of yyyy mm dd.
    myDate = any2Date(s);
    Global::info(strFmt("%1  is output, from input of "2010 6 17"", myDate));
    i = 40361; // An int object, which represents the number of days from 1900/01/01.
    myDate = any2Date(i);
    Global::info(strFmt("%1  is output, from input of 40361", myDate));
}
/**** Infolog display.
Message (04:44:15 pm)
6/17/2010 is output, from input of "2010 6 17"
7/4/2010 is output, from input of 40361
****/

any2Enum

Converte um valor anytype para o valor da propriedade Name de um elemento no enum de destino.

enum any2Enum(anytype object)

Parâmetros

Valor de retorno

O valor da propriedade Name para qualquer elemento no enum de destino tem uma propriedade Value que corresponde ao parâmetro de entrada.

Observações

O parâmetro object pode ser da maioria dos tipos de dados, mas os dados úteis são obtidos somente quando você usa um parâmetro do tipo str ou int . Este parâmetro de objeto de entrada refere-se à propriedade Value de um elemento individual no enum de destino.

Example

static void any2EnumExample(Args _args)
{
    NoYes myNoYes;  // NoYes is an enum.
    int i;
    str s;
    i = 0;  // An int that will be converted.
    myNoYes = any2Enum(i);
    Global::info(strfmt("'%1' - is the output, from input of the %2 as int.", myNoYes, i));
    s = "1";  // A str that will be converted.
    myNoYes = any2Enum(s);
    Global::info(strfmt("'%1' - is the output, from input of the %2 as str.", myNoYes, s));
    /**** Infolog display.
    Message (01:05:32 pm)
    'No' - is the output, from input of the 0 as int.
    'Yes' - is the output, from input of the 1 as str.
    ****/
}

any2Guid

Converte o objeto anytype especificado em um objeto GUID.

guid any2Guid(anytype object)

Parâmetros

Valor de retorno

Um objeto GUID.

qualquer2Int

Converte um valor anytype em um valor int .

int any2Int(anytype object)

Parâmetros

Valor de retorno

Um valor int .

Observações

O parâmetro object pode ser da maioria dos tipos de dados, mas os dados úteis são obtidos somente quando você usa parâmetros do tipo enum, real ou str .

Example

static void any2IntExample(Args _args)
{
    int myInt;
    str s;
    NoYes a;
    real r;
    s = "31";
    myInt = any2Int(s);
    Global::info(strfmt("%1 is the output, from input of 31 as a str value.", myInt));
    a = NoYes::No;
    myInt = any2Int(a);
    Global::info(strfmt("%1 is the output, from input of NoYes::No as an enum value.", myInt));
    r = 5.34e2;
    myInt = any2Int(r);
    Global::info(strfmt("%1 is the output, from the input of 5.34e2 as a real value.", myInt));
}
/**** Infolog display.
Message (02:23:59 pm)
31 is the output, from input of 31 as a str value.
0 is the output, from input of NoYes::No as an enum value.
534 is the output, from the input of 5.34e2 as a real value.
****/

qualquer2Int64

Converte um objeto anytype em um objeto int64 .

int64 any2Int64(anytype object)

Parâmetros

Valor de retorno

Um objeto int64 .

qualquer2Real

Converte um valor anytype em um valor real .

real any2Real(anytype object)

Parâmetros

Valor de retorno

Um valor real .

Observações

O parâmetro object pode ser da maioria dos tipos de dados, mas a saída útil é obtida para elementos de entrada dos tipos date, int, enum e str .

Example

static void any2RealExample(Args _args)
{
    real myReal;
    str s;
    int i;
    NoYes a;
    s = "5.12";
    myReal = any2Real(s);
    Global::info(strfmt("%1 is the output from the input of 5.12 as a str object", myReal));
    i = 64;
    myReal = any2Real(i);
    Global::info(strfmt("%1 is the output from the input of 64 as an int object", myReal));
    a = NoYes::Yes;
    myReal = any2Real(a);
    Global::info(strfmt("%1 is the output from the input of NoYes::Yes as an enum object", myReal));
}
/****Infolog display.
Message (02:43:57 pm)
5.12 is the output from the input of 5.12 as a str object
64.00 is the output from the input of 64 as an int object
1.00 is the output from the input of NoYes::Yes as an enum object
****/

any2Str

Converte um valor anytype em um valor str .

str any2Str(anytype object)

Parâmetros

Valor de retorno

Um valor str .

Observações

O parâmetro object pode ser da maioria dos tipos de dados, mas a saída útil é obtida a partir de elementos de entrada dos tipos date, int e enum .

Example

static void any2StrExample(Args _args)
{
    str myStr;
    anytype a;
    a = "Any to string";
    myStr = any2Str(a);
    Global::info(strFmt("%1 is output, from input of Any to string as a str value", myStr));
    a = NoYes::Yes;
    myStr = any2Str(a);
    Global::info(strFmt("%1 is output, from input of NoYes::Yes as an enumeration", myStr));
}
/****Infolog Display
Message (09:08:46 am)
Any to string is output, from input of Any to string as a str value
1 is output, from input of NoYes::Yes as an enumeration
****/

anytodate

Veja any2Date.

Anytoenum

Veja any2Enum.

Anytoguid

Veja any2Guid.

anytoint

Veja any2Int.

anytoint64

Ver any2Int64.

Anytoreal

Veja any2Real.

Anytostr

Ver any2Str.

char2Num

Converte um caractere em uma cadeia de caracteres para o valor ASCII do caractere.

int char2Num(str text, int position)

Parâmetros

Valor de retorno

O valor ASCII do caractere como um objeto int .

Observações

char2Num("ABCDEFG",3); //Returns the numeric value of C, which is 67.
char2Num("ABCDEFG",1); //Returns the numeric value of A, which is 65.

data2Num

Converte uma data em um inteiro que corresponde ao número de dias desde 1º de janeiro de 1900.

int date2Num(date _date)

Parâmetros

Valor de retorno

O número de dias entre 1º de janeiro de 1900 e a data especificada.

Example

//Returns the value377.
date2Num(1311901);
static void date2NumExample(Args _arg)
{
    date d = today();
    int i;
    i = date2Num(d);
    print i;
}

data2Str

Converte a data especificada em uma cadeia de caracteres.

str date2Str(date date, int sequence, int day, int separator1, int month, int separator2, int year [, int flags = DateFlags::None])

Parâmetros

Valor de retorno

Uma cadeia de caracteres que representa a data especificada.

Observações

O MorphX aloca valores válidos para os parâmetros de formatação se os valores especificados não forem válidos. Para usar o formato de data especificado pelo usuário em Configurações regionais, use a função strFmt ou date2Str e especifique -1 em todos os parâmetros de formatação. Quando as configurações regionais controlam o formato de data, as configurações podem mudar de usuário para usuário. Se -1 for usado para qualquer parâmetro separador , ambos os separadores usam como padrão Configurações Regionais. Os valores dos parâmetros de sequência devem ser qualquer número de três dígitos que contenha exatamente uma ocorrência de cada um dos dígitos 1, 2 e 3. Os dígitos 1, 2 e 3 representam dia, mês e ano, respectivamente. Por exemplo, 321 produz a sequência ano, mês e dia. Ou o valor pode ser -1 para usar as Configurações Regionais. Nenhum tipo de enumeração deve ser usado para esse parâmetro, porque números como 321 excedem o intervalo de valores válidos para valores de enumeração, que é de 0 a 250, inclusive. O valor padrão do parâmetro flags é o valor de enumeração DateFlags::None , o que significa que nenhum processamento de sequência da esquerda para a direita ou da direita para a esquerda é feito.

Example

O exemplo a seguir exibe a data atual na sequência de ano, mês e dia.

static void Job2(Args _args)
{
    date currentDate = today();
    str s;
    int iEnum;
    s = date2Str
    (currentDate, 
        321,
        DateDay::Digits2,
        DateSeparator::Hyphen, // separator1
        DateMonth::Digits2,
        DateSeparator::Hyphen, // separator2
        DateYear::Digits4
    );
    info("Today is:  " + s);
}
/** Example Infolog output
Message (12:36:21 pm)
Today is:  2009-01-13
**/

datetime2Str

Converte um valor utcdatetime em uma cadeia de caracteres.

str datetime2Str(utcdatetime datetime [, int flags = DateFlags::None])

Parâmetros

Valor de retorno

Uma cadeia de caracteres que representa o valor utcdatetime que foi especificado como o parâmetro datetime .

Observações

Entrada de data-hora nula

Se o valor mínimo utcdatetime for especificado para o parâmetro datetime , a função datetime2Str o tratará como um valor de entrada nulo. Isso faz com que a função retorne uma cadeia de caracteres vazia. A data-hora 1900-01-01T00:00:00 é retornada pelo método DateTimeUtil::minValue . Esse valor mínimo é tratado como nulo.

Configurações locais da direita para a esquerda

O comportamento padrão dessa função é gerar a cadeia de caracteres na sequência da esquerda para a direita, onde a parte do ano é mais à esquerda. No entanto, o valor do parâmetro flags do valor de enumeração DateFlags::FormatAll direciona a função para gerar a cadeia de caracteres na sequência da direita para a esquerda se as configurações locais estiverem definidas para a direita para a esquerda. O formato do método toStr da classe DateTimeUtil não é afetado pelas configurações regionais.

Example

static void jobTestDatetime2str( Args _args )
{
    utcdatetime utc2 = 1959-06-17T15:44:33;
    str s3;
    s3 = datetime2Str( utc2 );
    info( s3 );
}

enum2Str

Converte o texto enumerado especificado em uma representação de caracteres.

str enum2Str(enum enum)

Parâmetros

Valor de retorno

O valor da enumeração como uma cadeia de caracteres.

Example

O exemplo a seguir retorna a cadeia de caracteres "Not included". Este é o rótulo para o valor IncludeNot do tipo de enumeração ListCode .

static void enum2StrExample(Args _arg)
{
    ListCode l;
    l =  ListCode::IncludeNot;
    print enum2Str(l);
}

guid2Str

Converte o objeto GUID especificado na cadeia de caracteres equivalente.

str guid2String(guid _uuid)

Parâmetros

Valor de retorno

O equivalente de cadeia de caracteres do objeto GUID especificado.

Example

static void guid2StrExample()
{
    guid _guid;
    str stringGuid;
    _guid = Global::guidFromString("{12345678-1234-1234-1234-123456789abc}");
    print strfmt("GUID is %1", _guid);
    stringGuid = guid2str(_guid);
    info("String GUID is " + stringGuid);
}
/**** Output to Infolog
String GUID is {12345678-1234-1234-1234-123456789ABC}
****/

int2Str

Converte um inteiro na cadeia de caracteres equivalente.

str int2Str(int integer)

Parâmetros

Valor de retorno

Uma representação de cadeia de caracteres do inteiro.

Example

static void int2StrExample(Args _arg)
{
    print "This is int2Str, value is " + int2Str(intMax());
    print "This is int642Str, value is " + int642Str(int64Max());
}

int642Str

Converte o parâmetro inteiro especificado na cadeia de texto equivalente.

str int642Str(int64 integer)

Parâmetros

Valor de retorno

A cadeia de caracteres de texto equivalente do parâmetro inteiro .

Example

static void example()
{
    print "This is int2Str, value is " + int2Str(intMax());
    print "This is int642Str, value is " + int642Str(int64Max());
}

num2Char

Converte um inteiro para o caractere ASCII correspondente.

str num2Char(int figure)

Parâmetros

Valor de retorno

O caractere representado pelo inteiro especificado.

Example

static void num2CharExample(Args _arg)
{
    str s;
    s = num2Char(42);
    // Prints an asterisk * -the character represented by 42.
    print s;
}

num2Data

Recupera a data que corresponde ao número especificado de dias após 1º de janeiro de 1900.

date num2Date(int _days)

Parâmetros

Valor de retorno

A data que é o número de dias especificado pelo parâmetro _days após 1º de janeiro de 1900.

Observações

num2Date(366); //Returns the date 01/01/1901 (1 January 1901).

num2Str

Converte um número real em uma cadeia de caracteres.

str num2Str(real number, int character, int decimals, int separator1, int separator2)

Parâmetros

Valor de retorno

Uma cadeia de caracteres que representa o número.

Observações

Para o parâmetro decimals , o valor máximo é 16. Se um número maior for usado, esse método obterá um valor para o parâmetro decimals do computador local. Em ambos os casos, ocorre arredondamento. Aqui estão os possíveis valores de enumeração para o parâmetro separator1 :

• 99 – Auto (as configurações de formatação do usuário determinam qual separador decimal é usado), valor de enumeração DecimalSeparator::Auto
• 1 – Dot (.), valor de enumeração DecimalSeparator::D ot
• 2 – Vírgula (,), valor de enumeração DecimalSeparator::Vírgula

Aqui estão os valores possíveis para o parâmetro separator2 :

• 99 – Auto (as configurações de formatação do usuário determinam qual separador de mil é usado)
• 0 – Nenhum (sem separador mil), valor de enumeração ThousandSeparator::Nenhum
• 1 – Dot (.), valor de enumeração ThousandSeparator::D ot
• 2 – Vírgula (,), valor de enumeração ThousandSeparator::Vírgula
• 3 – Apóstrofo ('), valor de enumeração ThousandSeparator::Apostrophe
• 4 – Espaço ( ), valor de enumeração ThousandSeparator::Space

Example

No exemplo de código a seguir, a primeira chamada para o método num2str fornece 16 para o parâmetro decimals e a segunda chamada fornece 17.

static void Job_Num2Str(Args _args)
{
    real realNum = 0.1294567890123456777; // 19 decimals places.
    info(Num2Str(realNum, 0, 16, DecimalSeparator::Dot, ThousandSeparator::Space)); // 16 decimal places
    info(Num2Str(realNum, 0, 17, DecimalSeparator::Dot, ThousandSeparator::Space)); // 17 decimal places
}

Resultado

As mensagens estão na seguinte saída do Infolog. O primeiro número na saída contém 16 dígitos de casa decimal, enquanto o segundo número contém apenas dois dígitos de casa decimal.

Message (10:18:12)
0.1294567890123457
0.13

str2Date

Converte a cadeia de caracteres especificada em um valor de data .

date str2Date(str _text, str _sequence)

Parâmetros

Valor de retorno

Um valor de data .

Observações

Use os seguintes valores para especificar as posições do dia, mês e ano no parâmetro _sequence :

• Dia: 1
• Mês: 2
• Ano: 3

Por exemplo, se a sequência na cadeia de caracteres for mês, ano e, em seguida, dia, o parâmetro _sequence deverá ser 231. Uma data 0 (zero) é retornada se os parâmetros de entrada especificarem uma data inválida. Os dois exemplos a seguir especificam uma data inválida.

str2Date("31/12/44", 123) // Year must be four digits to reach the minimum of January 1 1901.
str2Date("31/12/2044", 213) // 213 means the month occurs first in the string, but 31 cannot be a month.

Example

static void str2DateExample(Args _arg)
{
    date d;
    d = str2Date("22/11/2007", 123);
    print d;
}

str2Data/hora

Gera um valor utcdatetime a partir da cadeia de caracteres especificada de informações de data e hora.

utcdatetime str2datetime( str text, int sequence )

Parâmetros

Valor de retorno

Um valor utcdatetime que representa a data e hora especificadas.

Observações

Os requisitos de sintaxe para a parte de data do parâmetro text são flexíveis. A variedade de formatos válidos é a mesma que na função date2str . Cada uma das chamadas a seguir para str2datetime é válida e todas elas produzem a mesma saída.

utc3 = str2datetime( "1985/02/25 23:04:59" ,321 );
utc3 = str2datetime( "Feb-1985-25 11:04:59 pm" ,231 );
utc3 = str2datetime( "2 25 1985 11:04:59 pm" ,123 );

Cada componente da data e hora é representado por um dígito no parâmetro de sequência :

• 1 – Dia
• 2 – Mês
• 3 – Ano

Por exemplo, a ordem do ano, mês, dia é 321. Todos os valores válidos contêm cada um desses três dígitos exatamente uma vez. Se o valor do parâmetro sequence não for válido, as configurações regionais serão usadas para interpretar o parâmetro de texto de entrada. Se os parâmetros de entrada descreverem uma data e hora inválidas, uma cadeia de caracteres vazia será retornada.

Example

static void JobTestStr2datetime( Args _args )
{
    utcdatetime utc3;
    str sTemp;
    utc3 = str2datetime( "1985/02/25 23:04:59" ,321 );
    sTemp = datetime2str( utc3 );
    print( "sTemp == " + sTemp );
}

str2Enum

Recupera o elemento enum para o qual o valor da propriedade Label localizada corresponde à cadeia de caracteres de entrada.

enum str2Enum(enum _type, str _text)

Parâmetros

Valor de retorno

Um elemento do enum alvo, que também representa um int.

Observações

A função relacionada enum2str retorna o valor de uma propriedade Label de um elemento no enum. O valor que é retornado pela função enum2str pode ser a entrada para o parâmetro _type da função str2enum . Um valor apropriado para o parâmetro _text é enum2Str(BankAccountType::SavingsAccount). Cada elemento de um enum tem uma propriedade Name e uma propriedade Label . Em uma nova instalação, os valores Name são quase sempre palavras em inglês. Na edição em inglês, o valor da propriedade Label é quase sempre o mesmo que o valor Name . No entanto, em edições diferentes do inglês, os valores Label são localizados e, portanto, não correspondem aos valores Name .

Example

Para evitar incompatibilidades de cadeia de caracteres causadas pela localização para outros idiomas falados, recomendamos que você use a função enum2str para gerar a entrada na função str2enum . O exemplo a seguir mostra a maneira apropriada de usar a função str2enum junto com a função enum2str .

static void str2Enum_AcrossLangs(Args _arg)
{
    BankAccountType bat;
    str sEnumValueLabelLocalized;
    int nInt;
    // enum2str.
    sEnumValueLabelLocalized = enum2str(BankAccountType::SavingsAccount);
    info("Localized friendly string: "
        + sEnumValueLabelLocalized);
    // str2enum.
    bat = str2Enum(bat, sEnumValueLabelLocalized);
    nInt = bat;
    info("nInt = " + int2str(nInt));
    /********** Actual output:
    Message (04:32:12 pm)
    Localized friendly string: Savings account
    nInt = 1
    **********/
}

str2Guid

Converte uma cadeia de caracteres em um objeto GUID.

Guid str2Guid(str text)

Parâmetros

Valor de retorno

Um GUID que é representado pela cadeia de caracteres de entrada.

Observações

Por exemplo, um valor válido para o parâmetro guid é {12345678-1234-abCD-3456-123456789012}, com ou sem chaves.

str2Int

Converte uma cadeia de caracteres no inteiro equivalente.

int str2Int(str _text)

Parâmetros

Valor de retorno

O equivalente inteiro da cadeia de caracteres especificada.

Example

static void str2IntExample(Args _arg)
{
    int i;
    i = str2Int("1234567890");
    print "i = " + int2Str(i);
}

str2Int64

Converte uma cadeia de caracteres em um valor Int64 .

int str2Int64(str text)

Parâmetros

Valor de retorno

O valor Int64 da cadeia de caracteres especificada.

Example

static void str2Int64Example(Args _args)
{
    str myStr;
    str tooBig;
    Int64 myInt64;
    myStr = "1234567890";
    tooBig = int642str(int64Max()+1);
    myInt64 = str2Int64(mystr);
    print strfmt ("int64: %1",myInt64);
    myInt64 = str2Int64(tooBig);
    print strfmt ("Too big int64: %1",myInt64);
}

str2Num

Converte uma cadeia de caracteres em um número real.

real str2Num(str _text)

Parâmetros

Valor de retorno

O número real se a cadeia de caracteres especificada contiver um número válido; caso contrário, 0 (zero).

Observações

Os exemplos a seguir mostram como essa função é usada.

str2Num("123.45") returns the value 123.45.
str2Num("a123") returns the value 0.0.
str2Num("123a") returns the value 123.00.

A verificação ocorre da esquerda para a direita e termina quando um caractere não pode ser convertido em parte de um número real.

Example

static void str2NumToReal(Args _arg)
{
    real r;
    str s;
    r = str2Num("3.15");
    s = strFmt("r = %1", r);
    info(s);
}
/*** Infolog output.
Message_@SYS14327 (02:36:12 pm)
r = 3.15
***/

static void str2NumExponentialSyntax(Args _args)
{
    Qty qty1, qty2, qty3;
    qty1 = str2num('1e-3'); // Bad syntax by the user.
    qty2 = str2num('1.e-3');
    qty3 = str2num('1.0e-3');
    info(strfmt('Result: %1; Expected: %2', num2str(qty1, 0,3,2,0), '0.001'));
    info(strfmt('Result: %1; Expected: %2', num2str(qty2, 0,3,2,0), '0.001'));
    info(strfmt('Result: %1; Expected: %2', num2str(qty3, 0,3,2,0), '0.001'));
}
/*** Infolog output. The first result differs from expectations.
Message_@SYS14327 (02:20:55 pm)
Result: 1,000; Expected: 0.001
Result: 0,001; Expected: 0.001
Result: 0,001; Expected: 0.001
***/

str2Time

Converte uma cadeia de caracteres em um valor timeOfDay .

int str2Time(str _text)

Parâmetros

Valor de retorno

O número de segundos entre a meia-noite e o parâmetro _text ; caso contrário, -1.

Observações

str2Time("05:01:37") //Returns the value 18097.
str2Time("7 o'clock") //Returns the value -1.

Example

static void str2TimeExample(Args _arg)
{
    int i;
    i = str2Time("11:30");
    print i;
}

time2Str

Converte um valor timeOfDay em uma cadeia de caracteres que inclui horas, minutos e segundos.

str time2Str(int _time, int _separator, int _timeFormat)

Parâmetros

Valor de retorno

Uma cadeia de caracteres que representa a hora especificada.

Observações

O valor do parâmetro _time é o número de segundos desde a meia-noite.

Example

static void TimeJob4(Args _args)
{
    timeOfDay theTime = timeNow();
    info( time2Str(theTime, TimeSeparator::Colon, TimeFormat::AMPM) );
}
/**
Message (04:33:56 pm)
04:33:56 pm
**/

uint2Str

Converte um inteiro em uma cadeia de caracteres. A suposição é que o inteiro não está assinado.

str uint2Str(int integer)

Parâmetros

Valor de retorno

A cadeia de caracteres equivalente ao inteiro não assinado especificado.

Observações

Use essa função em vez da função int2str para inteiros muito grandes, como IDs de registro.

info(int2str(3123456789)); //returns -1171510507 as a string.
info(uint2str(3123456789)); //returns 3123456789 as a string.