Partilhar via

Bar chart

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

O gráfico de barras visual precisa de um mínimo de duas colunas no resultado da consulta. Por padrão, a primeira coluna é usada como o eixo y. Esta coluna pode conter texto, datetime ou tipos de dados numéricos. As outras colunas são usadas como o eixo x e contêm tipos de dados numéricos a serem exibidos como linhas horizontais. Os gráficos de barras são usados principalmente para comparar valores discretos numéricos e nominais, onde o comprimento de cada linha representa seu valor.

Note

This visualization can only be used in the context of the render operator.

Syntax

T|renderbarchart [with(propertyName=propertyValue [, ...])]

Learn more about syntax conventions.

Parameters

Name Tipo Required Description
T string ✔️ Nome da tabela de entrada.
propertyName, propertyValue string Uma lista separada por vírgulas de pares de propriedades chave-valor. See supported properties.

Supported properties

Todas as propriedades são opcionais.

PropertyName PropertyValue
accumulate Se o valor de cada medida é adicionado a todas as suas antecessoras (true ou false).
kind Elaboração adicional do tipo visualização. Para obter mais informações, consulte kind propriedade.
legend Exibir ou não uma legenda (visible ou hidden).
series Lista delimitada por vírgulas de colunas cujos valores combinados por registro definem a série à qual o registro pertence.
ymin O valor mínimo a ser exibido no eixo Y.
ymax O valor máximo a ser exibido no eixo Y.
title O título da visualização (do tipo string).
xaxis Como dimensionar o eixo x (linear ou log).
xcolumn Qual coluna no resultado é usada para o eixo x.
xtitle O título do eixo x (do tipo string).
yaxis Como dimensionar o eixo y (linear ou log).
ycolumns Lista delimitada por vírgulas de colunas que consistem nos valores fornecidos por valor da coluna x.
ytitle O título do eixo y (do tipo string).
ysplit Como dividir a visualização em vários valores do eixo y. Para obter mais informações, consulte ysplit propriedade.

ysplit propriedade

Esta visualização suporta a divisão em vários valores do eixo y:

ysplit Description
none Um único eixo y é exibido para todos os dados da série. Este é o padrão.
axes Um único gráfico é exibido com vários eixos y (um por série).
panels Um gráfico é renderizado para cada ycolumn valor. Máximo de cinco painéis.

Supported properties

Todas as propriedades são opcionais.

PropertyName PropertyValue
kind Elaboração adicional do tipo visualização. Para obter mais informações, consulte kind propriedade.
series Lista delimitada por vírgulas de colunas cujos valores combinados por registro definem a série à qual o registro pertence.
title O título da visualização (do tipo string).

kind propriedade

Esta visualização pode ser mais elaborada fornecendo a propriedade kind. Os valores suportados desta propriedade são:

Valor kind Description
default Cada "bar" fica por conta própria.
unstacked O mesmo que default.
stacked Stack "bars".
stacked100 Empilhar "barras" e esticar cada uma para a mesma largura que as outras.

Examples

O exemplo nesta seção mostra como usar a sintaxe para ajudá-lo a começar.

The examples in this article use publicly available tables in the help cluster, such as the StormEvents table in the Samples database.

The examples in this article use publicly available tables, such as the Weather table in the Weather analytics sample gallery. Talvez seja necessário modificar o nome da tabela na consulta de exemplo para corresponder à tabela em seu espaço de trabalho.

Renderizar um gráfico de barras

A consulta a seguir cria um gráfico de barras exibindo o número de eventos de tempestade para cada estado, filtrando apenas os estados com mais de 10 eventos. O gráfico fornece uma representação visual da distribuição do evento em diferentes estados.

Executar a consulta

StormEvents
| summarize event_count=count() by State
| project State, event_count
| render barchart
    with (
    title="Storm count by state",
    ytitle="Storm count",
    xtitle="State",
    legend=hidden
    )

Captura de tela de um gráfico de barras rotulado.

Renderizar um gráfico de barras stacked

A consulta a seguir cria um gráfico de barras stacked que mostra a contagem total de eventos de tempestade por tipo para estados selecionados do Texas, Califórnia e Flórida. Cada barra representa um tipo de evento de tempestade e as barras empilhadas mostram a divisão de eventos de tempestade por estado dentro de cada tipo.

Executar a consulta

StormEvents
| where State in ("TEXAS", "CALIFORNIA", "FLORIDA")
| summarize EventCount = count() by EventType, State
| order by EventType asc, State desc
| render barchart with (kind=stacked)

Scrrenshot de uma visualização de gráfico de barras empilhado.

Renderizar um gráfico de barras stacked100

A consulta a seguir cria um gráfico de barras stacked100 que mostra a contagem total de eventos de tempestade por tipo para estados selecionados do Texas, Califórnia e Flórida. O gráfico mostra a distribuição dos eventos de tempestade entre os estados dentro de cada tipo. Embora as pilhas visualmente somem até 100, os valores na verdade representam o número de eventos, não porcentagens. Essa visualização é útil para entender as porcentagens e as contagens reais de eventos.

Executar a consulta

StormEvents
| where State in ("TEXAS", "CALIFORNIA", "FLORIDA")
| summarize EventCount = count() by EventType, State
| order by EventType asc, State desc
| render barchart with (kind=stacked100)

Captura de tela de uma visualização de gráfico de 100 barras empilhadas.

Use a propriedade ysplit

A consulta a seguir fornece um resumo diário de ferimentos e mortes relacionados a tempestades, visualizado como um gráfico de barras com eixos/painéis divididos para melhor comparação.

Executar a consulta

StormEvents
| summarize
    TotalInjuries = sum(InjuriesDirect) + sum(InjuriesIndirect),
    TotalDeaths = sum(DeathsDirect) + sum(DeathsIndirect)
    by bin(StartTime, 1d)
| project StartTime, TotalInjuries, TotalDeaths
| render barchart with (ysplit=axes)

Captura de tela do gráfico de colunas usando a propriedade ysplit axes.

Para dividir a vista em painéis separados, especifique panels em vez de axes:

Executar a consulta

StormEvents
| summarize
    TotalInjuries = sum(InjuriesDirect) + sum(InjuriesIndirect),
    TotalDeaths = sum(DeathsDirect) + sum(DeathsIndirect)
    by bin(StartTime, 1d)
| project StartTime, TotalInjuries, TotalDeaths
| render barchart with (ysplit=panels)

Captura de tela do gráfico de colunas usando a propriedade ysplit panels.

  • Last updated on