Report.Page evento (Access)

O evento Page ocorre depois que o Microsoft Access formata uma página de um relatório para impressão, mas antes de a página ser impressa. Utilize este evento para desenhar um limite à volta da página ou adicionar outros elementos gráficos à página.

Sintaxe

expressão. Página

expressão Uma variável que representa um objeto Relatório .

Valor de retorno

Nada

Comentários

Para executar um procedimento de macro ou evento quando este evento ocorre, defina a propriedade OnPage para o nome da macro ou para [Procedimento de Evento].

Este evento ocorre depois de todos os eventos Formatar do relatório e, depois de todos os eventos de Impressão da página, mas antes de a página ser realmente impressa.

Normalmente, utiliza os métodos Linha, Círculo ou PSet no procedimento de evento Página para criar os gráficos pretendidos para a página.

O evento NoData ocorre antes do evento da primeira Página do relatório.

Exemplo

O exemplo a seguir mostra como desenhar um retângulo em torno de uma página de relatório usando o método Line. As propriedades ScaleWidth e ScaleHeight retornam por padrão a largura e altura internas do relatório.

Private Sub Report_Page() 
    Me.Line(0, 0)-(Me.ScaleWidth, Me.ScaleHeight), , B 
End Sub

O exemplo a seguir mostra como usar o evento Page para adicionar uma marca d'água a um relatório antes que ele seja impresso.

Private Sub Report_Page()
    Dim strWatermarkText As String
    Dim sizeHor As Single
    Dim sizeVer As Single

#If RUN_PAGE_EVENT = True Then
    With Me
        '// Print page border
        Me.Line (0, 0)-(.ScaleWidth - 1, .ScaleHeight - 1), vbBlack, B
    
        '// Print watermark
        strWatermarkText = "Confidential"
        
        .ScaleMode = 3
        .FontName = "Segoe UI"
        .FontSize = 48
        .ForeColor = RGB(255, 0, 0)

        '// Calculate text metrics
        sizeHor = .TextWidth(strWatermarkText)
        sizeVer = .TextHeight(strWatermarkText)
        
        '// Set the print location
        .CurrentX = (.ScaleWidth / 2) - (sizeHor / 2)
        .CurrentY = (.ScaleHeight / 2) - (sizeVer / 2)
    
        '// Print the watermark
        .Print strWatermarkText
    End With
#End If

End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.