Analisar os registos gerados pelo sistema utilizando o Application Insights

Ligue as suas aplicações de tela a Application Insights, que é uma funcionalidade do Azure Monitor. Application Insights inclui ferramentas de análise que ajudam a diagnosticar problemas e a compreender o comportamento do utilizador nas aplicações. Use as informações recolhidas para tomar melhores decisões de negócios e melhorar a qualidade da aplicação.

Pré-requisitos

• Necessita de acesso ao portal do Azure.
• Necessita de permissão para criar recursos do Azure.

Criar um recurso Application Insights

Envie registos gerados pelo sistema a partir de uma aplicação criando um recurso Application Insights para armazenar eventos.

Saiba como criar um recurso baseado numa área de trabalho para o Application Insights no portal do Azure.

Ligar à sua aplicação para o Application Insights

1. Iniciar sessão no Power Apps.

2. Abra uma aplicação para editá-la.

3. Selecione o objeto Aplicação na vista de árvore de navegação esquerda e cole a Cadeia de ligação do seu recurso do Application Insights.

   

4. Guarde e Publique a sua aplicação.

5. Reproduza a aplicação publicada e navegue pelos diferentes ecrãs.

Quando procura nos ecrãs da aplicação, os eventos são automaticamente registados no Application Insights. Estes incluem detalhes de utilização como:

• A partir de onde os utilizadores acedem à aplicação
• Que dispositivos os utilizadores utilizam
• Os tipos de browsers que os utilizadores utilizam

Ver eventos no Application Insights

1. Inicie sessão no portal do Azure e abra o recurso do Application Insights que criou anteriormente.

2. No painel de navegação esquerdo, selecione Utilizadores na secção Utilização.

   Nota

   A vista Utilizadores mostram os detalhes de utilização da aplicação, tais como:

   • Número de utilizadores que viram a aplicação
   • Número de sessões de utilizador
   • Número de eventos registados
   • Sistemas operativos e detalhes da versão do browser dos utilizadores
   • Região e localização dos utilizadores

   Saiba mais informações sobre utilizadores, sessões e análises de eventos no Application Insights.

3. Selecione uma sessão de utilizador para ver detalhes específicos, como a duração da sessão e os ecrãs visitados.

   

4. No painel de navegação esquerdo, selecione Eventos na secção Utilização. Pode ver um resumo de todos os ecrãs visualizados em todas as sessões da aplicação.

   

Criar eventos de rastreio personalizados

Escreva rastreios personalizados para o Application Insights analisar informações específicas da sua aplicação. A função Rastreio permite-lhe recolher:

• Informações de utilização detalhadas para os controlos nos ecrãs
• Que utilizadores específicos estão a aceder à sua aplicação
• Que erros ocorrem

O rastreio ajuda-o a diagnosticar problemas enviando um registo de informações à medida que os utilizadores navegam na sua aplicação e tomam medidas. As mensagens de rastreio enviadas para o Application Insights têm um de três níveis de gravidade:

• Informações
• Aviso
• Error

Envie uma mensagem de rastreio com a gravidade apropriada com base na situação. Pode consultar os dados e tomar ações específicas com base no nível de gravidade.

Crie um componente na sua aplicação para recolher comentários sobre cada ecrã e registar eventos no Application Insights.

1. Iniciar sessão no Power Apps.

2. Selecione Aplicações no painel de navegação esquerdo. Na lista de aplicações, selecione a aplicação Kudos e, em seguida, selecione Editar.

   Nota

   Pode também criar uma nova aplicação ou editar uma aplicação existente.

3. Selecione Componentes na Vista de árvore:

   

4. Selecione Novo componente e, em seguida, redimensione a largura para 200 e a altura para 75:

   

5. Selecione Inserir no menu e selecione Ícones para adicionar Emoji - Descontente e Emoji - Sorriso:

   

6. Selecione Nova propriedade personalizada para criar uma propriedade personalizada:

   

7. Introduza a propriedade Nome e Nome a apresentar (por exemplo, FeedbackScreen).

8. Introduza uma propriedade Descrição.

9. Selecione Tipo de propriedade como Entrada e Tipo de dados como Ecrã:

   

   Nota

   Uma propriedade de entrada permite-lhe capturar o nome do ecrã e o respetivo componente para registar estas informações no Application Insights.

10. Selecione o componente na Vista de árvore, selecione Mais ações (…) e selecione Mudar o nome para dar ao componente um nome significativo, tal como FeedbackComponent.

    

11. Selecione os ícones, selecione Mais ações (…) e, em seguida, selecione Mudar o nome para mudar o nome dos ícones com nomes significativos, tais como FrownIcon e SmileIcon.

12. Selecione FrownIcon, selecione a propriedade OnSelect e introduza a seguinte expressão na barra de fórmulas:

    Trace(
       "App Feedback",
       TraceSeverity.Information,
           {
             UserName: User().FullName,
             UserEmail: User().Email,
             Screen: FeedbackComponent.FeedbackScreen.Name,
             FeedbackValue: "-1"
           }
         );
    Notify("Thanks for your feedback!");
    

    

    Nota

    A fórmula envia UserName, UserEmail, Screen e Feedback (com o valor -1) para Application Insights.

13. Selecione SmileIcon, selecione a propriedade OnSelect e introduza a seguinte expressão na barra de fórmulas:

    Trace(
       "App Feedback",
       TraceSeverity.Information,
           {
             UserName: User().FullName,
             UserEmail: User().Email,
             Screen: FeedbackComponent.FeedbackScreen.Name,
             FeebackValue: "1"
           }
         );
    Notify("Thanks for your feedback!");
    

14. Adicione o componente a um dos ecrãs na sua aplicação:

    

15. Selecione Guardar e, em seguida, selecione Publicar para guardar e publicar a sua aplicação.

16. Reproduza a aplicação publicada e envie comentários de sorriso e descontente a partir dos respetivos ecrãs.

    Importante

    Tem de reproduzir a aplicação publicada para enviar eventos para o Application Insights. Os eventos não são enviados para o Application Insights quando pré-visualiza a aplicação no Power Apps Studio.

    

Analisar dados personalizados no Application Insights

Pode agora começar a analisar os dados que enviou através da função Rastreio a partir da sua aplicação no Application Insights.

1. Inicie sessão no portal do Azure e abra o recurso de informações da aplicação que criou anteriormente.

   

2. Selecione Registos em Monitorização no painel de navegação esquerdo.

   

3. Introduza a seguinte consulta e selecione Executar para ver os comentários da sua aplicação:

   traces
   | where message == "App Feedback"
   | order by timestamp
   

   

4. Selecione uma linha nos resultados e expanda o campo customDimensions.

   Os valores para Screen, UserName, UserEmail e FeedbackValue para o evento OnSelect do ícone de sorriso e descontente no seu componente são registados. Os valores também são registados para cada evento enviado para o Application Insights, tais como appId, appName e appSessionId.

   

5. Utilize a seguinte consulta de exemplo para expandir as propriedades das dimensões personalizadas JSON e projetar as colunas na vista de resultados.

   traces
       | extend customdims = parse_json(customDimensions)
       | where message == "App Feedback"
       | project timestamp
           , message
           , AppName = customdims.['ms-appName']
           , AppId = customdims.['ms-appId']
           , FeedbackFrom = customdims.UserEmail
           , Screen = customdims.Screen
           , FeedbackValue = customdims.FeedbackValue
       | order by timestamp desc
   

   

   Sugestão

   As consultas de registo são poderosas. Utilize-as para associar várias tabelas, agregar grandes quantidades de dados e executar operações complexas. Saiba mais sobre consultas de registo.

Analisar dados do ciclo de vida da aplicação no Application Insights

O evento de resumo da sessão é registado uma vez por sessão e contém informações sobre o êxito de abertura da aplicação, as sessões ideais de abertura da aplicação vs. sessões não otimizadas e métricas de desempenho de abertura da aplicação.

Limites

Esses eventos são precisos para aplicações de tela executadas num browser da Web. Não estão disponíveis para aplicações executadas no Power Apps para dispositivos móveis e os seus valores nem sempre estão disponíveis ou são precisos para páginas personalizadas.

Aqui está um exemplo de consulta mostrando como aceder ao evento de resumo da sessão e todos os campos disponíveis:

customEvents 
| where name == "PowerAppsClient.PublishedApp.SessionLoadSummary" 
// 
| extend cd = parse_json(customDimensions) 
// 
| extend sessionSummary = parse_json(tostring(cd["ms-sessionSummary"])) 
| extend successfulAppLaunch = tobool(sessionSummary["successfulAppLaunch"]) 
| extend unsuccessfulReason = tostring(sessionSummary["unsuccessfulReason"]) 
| extend appLoadResult = tostring(sessionSummary["appLoadResult"]) 
| extend appLoadNonOptimalReason = 
tostring(sessionSummary["appLoadNonOptimalReason"]) 
// 
| extend timeToAppInteractive = todouble(sessionSummary["timeToAppInteractive"]) 
| extend timeToAppFullLoad = todouble(sessionSummary["timeToAppFullLoad"]) 
// 
| project 
    timestamp, 
    session_Id, 
    successfulAppLaunch, 
    unsuccessfulReason, 
    appLoadResult, 
    appLoadNonOptimalReason, 
    timeToAppInteractive, 
    timeToAppFullLoad 
| limit 5 

Os campos a seguir ajudam a medir o êxito da abertura da aplicação e a latência dos marcadores de desempenho ligados às experiências do utilizador final.

Consultas de amostra

Taxas de êxito de abertura da aplicação

Esta consulta mostrará a taxa de êxito de abertura da aplicação por dia. Isto pode ser usado para avaliar picos ou tendências em problemas que os utilizadores podem estar a enfrentar

customEvents 
| where name == "PowerAppsClient.PublishedApp.SessionLoadSummary" 
| extend cd = parse_json(customDimensions) 
| extend sessionSummary = parse_json(tostring(cd["ms-sessionSummary"])) 
| extend successfulAppLaunch = tobool(sessionSummary["successfulAppLaunch"]) 
| summarize 
sessions_total = dcount(session_Id), 
sessions_success = dcountif(session_Id, successfulAppLaunch == true) 
by bin(timestamp, 1d) 
| extend successRate =  
100.0 * (todouble(sessions_success) / todouble(sessions_total)) 
| project timestamp, successRate 
| render timechart

Contagem de sessões sem êxito por motivo

Esta consulta mostrará contagens de sessões sem êxito por motivo/erro. Isto pode ser usado para depurar falhas ao abrir a aplicação ou para avaliar tendências em problemas que os utilizadores podem estar a enfrentar

customEvents 
| where name == "PowerAppsClient.PublishedApp.SessionLoadSummary" 
| extend cd = parse_json(customDimensions) 
| extend sessionSummary = parse_json(tostring(cd["ms-sessionSummary"])) 
| extend successfulAppLaunch = tobool(sessionSummary["successfulAppLaunch"]) 
| extend unsuccessfulReason = tostring(sessionSummary["unsuccessfulReason"]) 
| where successfulAppLaunch == false 
| summarize 
count() 
by unsuccessfulReason, bin(timestamp, 1d) 
| render timechart

Desempenho de abertura da aplicação

Esta consulta mostrará as métricas de desempenho da abertura da aplicação por dia. Isso pode ser usado para avaliar tendências de desempenho ao longo do tempo ou depois de fazer alterações. Recomendamos:

1. Usando o percentil 75 dos campos timeToAppInteractive e timeToAppFullLoad para evitar ruídos causados por valores atípicos.
2. Filtrando apenas para sessões ideais para evitar ruídos nos dados causados por casos esperados, como sessões com interação do utilizador, sessões em que a aplicação foi carregada num separador em fundo, etc.

customEvents 
| where name == "PowerAppsClient.PublishedApp.SessionLoadSummary" 
| extend cd = parse_json(customDimensions) 
| extend sessionSummary = parse_json(tostring(cd["ms-sessionSummary"])) 
| extend appLoadResult = tostring(sessionSummary["appLoadResult"]) 
| extend timeToAppInteractive = todouble(sessionSummary["timeToAppInteractive"]) 
| extend timeToAppFullLoad = todouble(sessionSummary["timeToAppFullLoad"]) 
| where appLoadResult == "optimal" 
| summarize 
percentile(timeToAppInteractive, 75), 
percentile(timeToAppFullLoad, 75) 
by bin(timestamp, 1d) 
| render timechart

Estado de carregamento da aplicação em chamadas HTTP

Há um novo cabeçalho de pedido x-ms-app-load-state que indica se uma chamada HTTP contribuiu para a inicialização da aplicação. Especificamente, isso pode ser usado para determinar quais chamadas HTTP afetaram o timeToAppFullLoad acima.

O cabeçalho pode ser um de dois valores:

Aqui está uma consulta de exemplo mostrando como aceder ao valor do cabeçalho e projetá-lo na coluna appLoadState:

dependencies 
| extend cd = parse_json(customDimensions) 
| extend requestHeaders = parse_json(tostring(cd["requestHeaders"])) 
| extend appLoadState = tostring(requestHeaders["x-ms-app-load-state"]) 
| project timestamp, session_Id, appLoadState, name, duration 
| limit 5

Contagem de chamadas HTTP que contribuem para a carga total

Esta consulta mostrará a contagem média de chamadas HTTP que estão a contribuir para timeToAppFullLoad por dia. Isso pode ser usado para avaliar o número de chamadas que a aplicação está a fazer na inicialização que podem estar a contribuir para um mau desempenho.

dependencies 
| extend cd = parse_json(customDimensions) 
| extend requestHeaders = parse_json(tostring(cd["requestHeaders"])) 
| extend appLoadState = tostring(requestHeaders["x-ms-app-load-state"]) 
| where appLoadState == "TTFL" 
| summarize httpCalls = count() by session_Id, bin(timestamp, 1d) 
| summarize avg(httpCalls) by timestamp 
| render timechart

Duração de chamadas HTTP que contribuem para a carga total

Esta consulta mostrará a duração total de chamadas HTTP que estão a contribuir para timeToAppFullLoad por dia. Isso pode ser usado para avaliar o impacto geral das chamadas HTTP para o desempenho de inicialização da aplicação.

dependencies 
| extend cd = parse_json(customDimensions) 
| extend requestHeaders = parse_json(tostring(cd["requestHeaders"])) 
| extend appLoadState = tostring(requestHeaders["x-ms-app-load-state"]) 
| where appLoadState == "TTFL" 
| summarize httpCallDuration = sum(duration) by session_Id, bin(timestamp, 1d) 
| summarize percentile(httpCallDuration, 80) by timestamp 
| render timechart

Duração de chamadas HTTP que contribuem para a carga total por URL

Semelhante ao acima, esta consulta mostrará a contagem e a duração de chamadas HTTP que contribuem para timeToAppFulLoad por URL. Isso pode ser usado para identificar chamadas HTTP lentas específicas que estão a afetar o desempenho de inicialização da aplicação.

dependencies 
| extend cd = parse_json(customDimensions) 
| extend requestHeaders = parse_json(tostring(cd["requestHeaders"])) 
| extend appLoadState = tostring(requestHeaders["x-ms-app-load-state"]) 
| where appLoadState == "TTFL" 
| summarize 
count(), percentile(duration, 80) by name

Monitorizar erros não processados (experimental)

[Esta secção contém documentação de pré-lançamento e está sujeita a alterações.]

Nem sempre é possível antecipar ou planear todos os erros que possam ocorrer enquanto a aplicação é executada. Os erros de fórmula do Power Fx não processados são reportados aos utilizadores como mensagens de faixa. Também podem ser reportados para o Application Insights mostrar a sua frequência e gravidade sem depender dos utilizadores da sua aplicação para relatar problemas. Também pode configurar alertas em tempo real quando ocorrerem erros de runtime para adotar uma abordagem mais proativa.

Ativar a transmissão de erros para o Application Insights

Ative a definição que permite ao Power Apps transmitir erros de runtime não processados para o Azure Application Insights.

1. Abra a aplicação de tela para edição.
2. Selecione Definições>Atualizações>Experimentais e ative Transmitir erros para o Azure Application Insights.
3. Guarde e, em seguida, publique a sua aplicação.

Eventos de erro no Application Insights

Os erros do Power Fx não processados que os utilizadores encontram no runtime da aplicação são reportados à tabela de rastreios. Os erros não processados podem ser identificados e distinguidos de outros eventos de erro pela mensagem de evento "Erro não processado". A dimensão "severityLevel" desses eventos é 3 (TraceSeverity.Error).

São fornecidas mensagens de erro detalhadas na dimensão "erros" da propriedade customDimension. Nas situações em que ocorreram vários erros durante a mesma operação, os erros são consolidados na dimensão "erros" de um único evento de rastreio. As mensagens de erro correspondem às relatadas no Monitor durante uma sessão de depuração em direto.

Esta consulta de exemplo identifica erros não processados e expande todas as mensagens de erro no evento de rastreio:

traces
    | where message == "Unhandled error"
    | extend customdims = parse_json(customDimensions)
    | extend errors = parse_json(tostring(customdims.['errors']))
    | mv-expand errors
    | project timestamp
        , itemId //unique identifier for the trace event
        , AppName = customdims.['ms-appName']
        , AppId = customdims.['ms-appId']
        , errors = errors.['Message']
    | order by timestamp desc

Rastreio da correlação (experimental)

[Esta secção contém documentação de pré-lançamento e está sujeita a alterações.]

A ligação a dados e serviços externos é essencial para a maioria das aplicações. O rastreio de correlação gera e propaga informações de contexto para associar registos gerados pelo sistema num aplicação de tela e respetivas ligações, sujeito a certas limitações. Por exemplo, a sua aplicação pode chamar um conector personalizado que, em seguida, chama uma função Azure ou outra API REST. O rastreio de correlação permite-lhe correlacionar ações tomadas na aplicação com as chamadas da API subjacentes entre camadas. Isso é útil para resolver problemas.

O rastreio de correlação de aplicações de tela implementa o rastreio de contexto e segue a especificação W3C.

Ativar o rastreio de correlação

1. Para ativar o rastreio de correlação, abra a sua aplicação de tela para edição.
2. Selecione Definições>Atualizações>Experimental> e ative Ativar rastreio de correlação do Azure Application Insights.
3. Guarde e publique a aplicação.

Limitações

• O rastreio de correlação funciona apenas com conectores personalizados. Os outros tipos de conector não são suportados.
• Os pedidos HTTP só são capturados no Application Insights se o serviço ligado também estiver ligado ao Application Insights.

Utilizar o rastreio de correlação

Quando ativado, o rastreio de correlação adiciona um novo evento de registo gerado pelo sistema na tabela dependências da instância ddo Application Insights da aplicação de tela. Este evento é registado no momento em que uma resposta a uma chamada de rede é recebida. Os eventos de dependência capturam detalhes da chamada de rede, incluindo os cabeçalhos de pedido e de resposta, o código do estado da resposta e a duração da chamada.

Se o serviço ligado também estiver ligado ao Application Insights, é gerado um evento de registo gerado pelo sistema que recolhe o pedido na tabela pedidos da instância do Application Insights do serviço. Alguns serviços do Azure, tais como as Funções do Azure, podem ser ligados sem qualquer codificação a partir do portal do Azure. Tanto a aplicação de tala como várias aplicações e serviços ligados podem ser ligados à mesma instância da Application Insights.

Junte-se a chamadas de rede para conectores suportados com outros registo gerados pelo sistema na dimensão "operation_Id". A consulta a seguir mostra uma chamada de rede ao lado de eventos de rastreio emitidos durante uma sessão da aplicação.

traces | union dependencies | union requests | union pageViews | union customEvents
| project timestamp
    , itemType
    , name
    , operation_Name
    , message
    , severityLevel
    , customDimensions
    , operation_Id
    , operation_ParentId
| where operation_Id == "0a7729e3e83c4e4d93cb4f51149f73b9" //placeholder operation_Id, replace
| order by timestamp asc

Exportar dados para o Power BI

Pode exportar os resultados da consulta e os dados do Application Insights para o Power BI para análise e apresentação de dados.

1. Inicie sessão no portal do Azure e abra o recurso do Application Insights que configurou anteriormente.

2. Selecione Registos em Monitorização no painel de navegação esquerdo.

3. Na janela de consulta da análise de registo, selecione o menu Exportar.

4. Selecione Exportar para Power BI (Consulta M) para transferir um ficheiro de consulta do Power BI.

   

5. Abra o ficheiro transferido num editor de texto e copie a consulta para a área de transferência.

6. Abrir Power BI.

7. Selecione Obter Dados no friso Base e, em seguida, selecione Consulta em branco.

   

8. Na janela de consulta, selecione Editor avançado, cole a consulta na janela, selecione Concluído e, em seguida, selecione Fechar e aplicar.

   

Crie gráficos e visualizações no Power BI para representar os comentários da sua aplicação e tomar decisões orientadas por dados.

Contexto e dimensões do evento de Rastreio Predefinido

Dimensões predefinidas são adicionadas à propriedade customDimensions em cada evento de Rastreio. Estas dimensões podem ser utilizadas para identificar a aplicação e as sessões das aplicações onde os eventos ocorrem. Se registar dados personalizados adicionais através da função de rastreio, também são apresentados nas dimensões personalizadas.

Cenários não suportados

Application Insights não suporta estes cenários.

• Os eventos do jogador offline não são gravados.
• Os eventos de aplicações móveis (iOS e Android) não são registados quando a aplicação é suspensa.