List.PositionOf

Sintaxe

List.PositionOf(
    list as list,
    value as any,
    optional occurrence as nullable number,
    optional equationCriteria as any
) as any

Sobre

Retorna o deslocamento no qual o valor especificado aparece em uma lista. Retorna -1 se o valor não aparecer.

• list: A lista a ser pesquisada.
• value: O valor a ser encontrado na lista.
• occurrence: (Opcional) A ocorrência específica a comunicar. Esse valor pode ser Occurrence.First, Occurrence.Last ou Occurrence.All. Se não occurrence for especificado, Occurrence.First é usado.
• equationCriteria: (Opcional) Especifica como a igualdade é determinada ao comparar valores. Este parâmetro pode ser uma função seletora de chave, uma função de comparação ou uma lista contendo um seletor de teclas e um comparador.

Exemplo 1

Encontre a posição na lista {1, 2, 3} na qual o valor 3 aparece.

Utilização

List.PositionOf({1, 2, 3}, 3)

Saída

2

Exemplo 2

Encontre a posição na lista de todas as ocorrências de datas de 2022.

Utilização

let
    Source = {
        #date(2021, 5, 10),
        #date(2022, 6, 28),
        #date(2023, 7, 15),
        #date(2022, 12, 31),
        #date(2022, 4, 8),
        #date(2024, 3, 20)
    },
    YearList = List.Transform(Source, each Date.Year(_)),
    TargetYear = 2022,
    FindPositions = List.PositionOf(YearList, TargetYear, Occurrence.All)
in
    FindPositions

Saída

{1, 3, 4}

Exemplo 3

Encontre a posição na lista da última ocorrência da palavra cão, ignorando caso.

Utilização

let
    Source = List.PositionOf(
        {"dog", "cat", "DOG", "pony", "bat", "rabbit", "dOG"}, 
        "dog", 
        Occurrence.Last, 
        Comparer.OrdinalIgnoreCase
    )
in
    Source

Saída

6

Exemplo 4

Encontre a posição na lista que está dentro de duas unidades do número 28.

Utilização

let
    Source = { 10, 15, 20, 25, 30 },
    Position = List.PositionOf(
        Source, 
        28,
        Occurrence.First, 
        (x, y) => Number.Abs(x - y) <= 2
    )
in
    Position

Saída

4

Conteúdos relacionados

Critérios de equação