List.PositionOfAny

Sintaxe

List.PositionOfAny(
    list as list,
    values as list,
    optional occurrence as nullable number,
    optional equationCriteria as any
) as any

Sobre

Retorna o deslocamento no qual um item da lista especificada de valores aparece em uma lista. Retorna -1 se nenhuma ocorrência for encontrada.

• list: A lista a pesquisar.
• values: A lista de valores a encontrar na lista original.
• occurrence: (Opcional) A ocorrência específica a comunicar. Esse valor pode ser Occurrence.First, Occurrence.Last ou Occurrence.All. Se não occurrence for especificado, Occurrence.First é usado.
• equationCriteria: (Opcional) Especifica como a igualdade é determinada ao comparar valores. Este parâmetro pode ser uma função seletora de chave, uma função de comparação ou uma lista contendo um seletor de teclas e um comparador.

Exemplo 1

Encontre a primeira posição na lista {1, 2, 3} na qual o valor 2 ou 3 aparece.

Utilização

List.PositionOfAny({1, 2, 3}, {2, 3})

Saída

1

Exemplo 2

Encontre a posição na lista de todas as ocorrências de datas dos anos 2022 ou 2023.

Utilização

let
    Source = {
        #date(2021, 5, 10),
        #date(2022, 6, 28),
        #date(2023, 7, 15),
        #date(2025, 12, 31),
        #date(2022, 4, 8),
        #date(2024, 3, 20)
    },
    YearList = List.Transform(Source, each Date.Year(_)),
    TargetYear = {2022, 2023},
    FindPositions = List.PositionOfAny(YearList, TargetYear, Occurrence.All)
in
    FindPositions

Saída

{1, 2, 4}

Exemplo 3

Encontre a posição na lista da última ocorrência da palavra cão ou gato, ignorando caso.

Utilização

let
    Source = List.PositionOfAny(
        {"dog", "cat", "DOG", "pony", "bat", "rabbit", "dOG"}, 
        {"dog", "cat"}, 
        Occurrence.Last, 
        Comparer.OrdinalIgnoreCase
    )
in
    Source

Saída

6

Exemplo 4

Encontre qualquer posição na lista que esteja dentro de duas unidades do número 17 ou 28.

Utilização

let
    Source = { 10, 15, 20, 25, 30 },
    Position = List.PositionOfAny(
        Source, 
        {17, 28},
        Occurrence.All, 
        (x, y) => Number.Abs(x - y) <= 2
    )
in
    Position

Saída

{1, 4}

Conteúdos relacionados

Critérios de equação