List.Select

Sintaxe

List.Select(list as list, selection as function) as list

Sobre nós

Retorna os valores da lista especificada que correspondem à condição de seleção.

• list: A lista a ser examinada.
• selection: A função que determina os valores a serem selecionados.

Exemplo 1

Localize os valores na lista {1, -3, 4, 9, -2} superiores a 0.

Utilização

List.Select({1, -3, 4, 9, -2}, each _ > 0)

Output

{1, 4, 9}

Exemplo 2

Selecione datas da lista que caem no sábado ou domingo.

Utilização

let
    dates = {
        #date(2025, 10, 20),  // Monday
        #date(2025, 10, 21),  // Tuesday
        #date(2025, 10, 25),  // Saturday
        #date(2025, 10, 26),  // Sunday
        #date(2025, 10, 27)   // Monday
    },
    weekendDates = List.Select(
        dates,
        each Date.DayOfWeek(_, Day.Monday) >= 5
    )
in
    weekendDates

Output

{
    #date(2025, 10, 25),
    #date(2025, 10, 26)
}

Exemplo 3

Exiba uma tabela de clientes ativos com totais de compra acima de US$ 100.

Utilização

let
    customers = {
        [Name = "Alice", Status = "Active", Purchases = 150],
        [Name = "Bob", Status = "Inactive", Purchases = 200],
        [Name = "Carol", Status = "Active", Purchases = 90],
        [Name = "Dave", Status = "Active", Purchases = 120]
    },
    highValueActiveCustomers = List.Select(
        customers,
        each [Status] = "Active" and [Purchases] > 100
    ),
    resultTable = Table.FromRecords(
        highValueActiveCustomers,
        type table [Name = text, Status = text, Purchases = number]
    )
in
    resultTable

Output

#table(type table[Name = text, Status = text, Purchases = number],
{
    {"Alice", "Active", 150},
    {"Dave", "Active", 120}
})