Partilhar via

Acompanhar a jornada de migração usando o painel de migração - SQL Server habilitado pelo Azure Arc

Aplica-se a:SQL Server

O painel de migração é uma exibição conveniente que mostra todas as instâncias do SQL Server habilitadas pelo Azure Arc e sua prontidão para migração. O SQL Server habilitado pelo Azure Arc produz automaticamente uma avaliação para migração para o Azure. Esta avaliação desempenha um papel vital no sucesso do seu percurso de migração e modernização da cloud. Com esse painel, você pode acompanhar a jornada de migração em escala. A prontidão é projetada como propriedades no plano de gerenciamento do Azure, que permite o uso de recursos organizacionais, de marcação e de consulta nativos do Azure.

O painel fornece:

  • Uma visão geral das instâncias e bancos de dados descobertos do SQL Server.
  • Uma visão geral das instâncias do SQL Server com avaliações geradas.
  • Um resumo de preparação para migração para cada oferta SQL do Azure.
  • Recursos avançados de filtragem que você pode usar para personalizar a exibição de acordo com suas necessidades.

Rever a avaliação da migração

Você pode acessar o painel de migração das seguintes maneiras:

  • No portal do Azure, procure Azure Arc e vá para o centro do Azure Arc.
  • No painel esquerdo, expanda Serviços de dados e vá para instâncias do SQL Server.
  • Selecione a guia Painel de migração .

Captura de tela que mostra o painel de migração do SQL Server habilitado pelo Azure Arc.

Resumo de instâncias e bancos de dados do SQL Server descobertos

A primeira seção do painel fornece uma visão geral de todas as instâncias e bancos de dados do SQL Server acessíveis para você. Você também pode ver a distribuição das instâncias por versão e edição.

Captura de tela que mostra o painel de migração mostrando instâncias e bancos de dados do SQL Server e distribuição por versão e edição.

Resumo da avaliação da migração do SQL Server

Esta seção do painel fornece uma visão geral da avaliação da migração e da preparação para a migração das instâncias do SQL Server habilitadas pelo Azure Arc. Você pode ver quantas instâncias têm avaliações disponíveis. A prontidão de migração para cada oferta SQL do Azure é mostrada separadamente.

Captura de tela que mostra o painel de migração com uma visão geral das avaliações de migração e preparação de instâncias e bancos de dados para ofertas SQL do Azure.

Consulta do Azure Resource Graph

O Azure Resource Graph fornece meios eficientes e eficazes para consultar as propriedades de prontidão das instâncias do SQL Server habilitadas pelo Azure Arc. Aqui estão alguns exemplos de consultas.

resources
 | where type == 'microsoft.azurearcdata/sqlserverinstances'
 | where properties.migration.assessment.assessmentUploadTime > ago(14d) and properties.migration.assessment.enabled == true and isnotnull(parse_json(properties.migration.assessment.skuRecommendationResults))
 | extend azureSqlDatabaseRecommendationStatus = tostring(properties.migration.assessment.skuRecommendationResults.azureSqlDatabase.recommendationStatus)
 | extend azureSqlManagedInstanceRecommendationStatus = tostring(properties.migration.assessment.skuRecommendationResults.azureSqlManagedInstance.recommendationStatus)
 | extend azureSqlVirtualMachineRecommendationStatus = tostring(properties.migration.assessment.skuRecommendationResults.azureSqlVirtualMachine.recommendationStatus)
 | extend serverAssessments = tostring(properties.migration.assessment.serverAssessments)
 | extend subscriptionId = extract(@"/subscriptions/([^/]+)", 1, id)
 | extend resourceGroup = extract(@"/resource[g/G]roups/([^/]+)", 1, id)
 | mv-expand platformStatus = pack_array(
     pack("platform", "Azure SQL Database", "status", azureSqlDatabaseRecommendationStatus),
     pack("platform", "Azure SQL Managed Instance", "status", azureSqlManagedInstanceRecommendationStatus),
     pack("platform", "Azure SQL Virtual Machine", "status", azureSqlVirtualMachineRecommendationStatus)
   )
 | extend platformIncludedString = strcat('"AppliesToMigrationTargetPlatform":', strcat('"', replace(" ", "", tolower(tostring(platformStatus["platform"]))), '"'))
 | extend platformHasIssues = tolower(serverAssessments) has tolower(platformIncludedString)
 | project Platform = tostring(platformStatus["platform"]), status = tostring(platformStatus["status"]), tostring(serverAssessments), id, platformHasIssues
 | extend finalStatus = case(
     status == "Ready" and platformHasIssues, "Ready with Conditions",
     status == "Ready", "Ready",
     status == "NotReady", "NotReady",
     isnull(status) or status !in ("Ready", "NotReady", "Ready with Conditions"), "Unknown",
     "Unknown")
 | summarize TotalAssessed = count(), Ready = countif(finalStatus == "Ready"), NotReady = countif(finalStatus == "NotReady"),
     ReadyWithConditions = countif(finalStatus == "Ready with Conditions"), Unknown = countif(finalStatus == "Unknown")
     by Platform

az graph query -q "resources | where type =~ 'microsoft.hybridcompute/machines' | extend machineId = tolower(tostring(id)), datacenter = iif(isnull(tags.Datacenter), '', tags.Datacenter), status = tostring(properties.status) | extend mssqlinstalled = coalesce(tobool(properties.detectedProperties.mssqldiscovered),false) | extend pgsqlinstalled = coalesce(tobool(properties.detectedProperties.pgsqldiscovered),false) | extend mysqlinstalled = coalesce(tobool(properties.detectedProperties.mysqldiscovered),false) | extend osSku = properties.osSku, osName = properties.osName, osVersion = properties.osVersion | extend coreCount = tostring(properties.detectedProperties.logicalCoreCount), totalPhysicalMemoryinGB = tostring(properties.detectedProperties.totalPhysicalMemoryInGigabytes)  | extend operatingSystem = iif(isnotnull(osSku), osSku, osName) | where mssqlinstalled or mysqlinstalled or pgsqlinstalled | project id ,name, type, resourceGroup, subscriptionId, location, kind, osVersion, status, osSku,coreCount,totalPhysicalMemoryinGB,tags, mssqlinstalled, mysqlinstalled, pgsqlinstalled | sort by (tolower(tostring(name))) asc"

Conteúdo relacionado

  • Last updated on