Partilhar via

Tarefas WMI: Tarefas agendadas

As tarefas agendadas do WMI criam e obtêm informações sobre tarefas agendadas. Para obter outros exemplos, consulte o TechNet ScriptCenter em https://www.microsoft.com/technet.

Os exemplos de script mostrados neste tópico obtêm dados somente do computador local. Para obter mais informações sobre como usar o script para obter dados de computadores remotos, consulte Conectando-se ao WMI em um computador remoto.

O procedimento a seguir descreve como executar um script.

Para executar um script

  1. Copie o código e salve-o em um arquivo com uma extensão .vbs, como filename.vbs. Certifique-se de que o editor de texto não adiciona uma extensão .txt ao arquivo.
  2. Abra uma janela de prompt de comando e navegue até o diretório onde você salvou o arquivo.
  3. Digite cscript filename.vbs no prompt de comando.
  4. Se não conseguir aceder a um registo de eventos, verifique se está a executar a partir de uma linha de comandos Elevados. Alguns Logs de Eventos, como o Log de Eventos de Segurança, podem estar protegidos por Controles de Acesso de Usuário (UAC).

Observação

Por padrão, o cscript exibe a saída de um script na janela do prompt de comando. Como os scripts WMI podem produzir grandes quantidades de saída, convém redirecionar a saída para um arquivo. Digite cscript filename.vbs > outfile.txt no prompt de comando para redirecionar a saída do script filename.vbs para outfile.txt.

A tabela a seguir lista exemplos de script que podem ser usados para obter vários tipos de dados do computador local.

Como faço para... Classes ou métodos WMI
... Criar tarefas agendadas usando scripts? Use a classe Win32_ScheduledJob e o método Create. Se estiver a ter dificuldade em fazer esta tarefa funcionar no Windows 7 ou posterior, consulte a secção Win32_ScheduledJob Comentários; provavelmente suas configurações estão impedindo que você use a classe.
VB 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 
JobID = "Test"
Set objNewJob = objWMIService.Get("Win32_ScheduledJob")
errJobCreate = objNewJob.Create _
    ("Notepad.exe", "********143000.000000-420", True , 1 OR 4 OR 16, ,True, JobId) 
If errJobCreate = 0 Then
    WScript.Echo "Job created successfully: " & VBNewLine _
        & "Notepad.exe scheduled to run repeately at 14.30 (2:30 P.M.) PST" & VBNewLine _
        & "on Mon, Wed, and Fri."
Else
    WScript.Echo "Job not created. Error code = " & errJobCreate
End If

Na cadeia de caracteres "********143000.000000-420" (usada no StartTime valor do parâmetro do método Create), "********143000.000000" especifica que a tarefa começa às 14h30 (14h30) e "-420" especifica o fuso horário. O número de fuso horário é o viés atual da tradução da hora local. O viés é a diferença entre a hora UTC e a hora local. Para calcular o enviesamento para o seu fuso horário, multiplique o número de horas em que o seu fuso horário está à frente ou atrás do horário de Greenwich (GMT) por 60 (use um número positivo para o número de horas se o seu fuso horário estiver à frente do GMT e um número negativo se o seu fuso horário estiver atrás do GMT). Adicione mais 60 ao seu cálculo se o seu fuso horário estiver usando o horário de verão. Por exemplo, o fuso horário padrão do Pacífico está oito horas atrás do GMT, portanto, o viés é igual a -420 (-8 * 60 + 60) quando o horário de verão está em uso e -480 (-8 * 60) quando o horário de verão não está em uso. Você também pode determinar o valor do viés consultando a propriedade bias da classe Win32_TimeZone.
... Retornar uma lista de todas as tarefas agendadas em um computador?

Use a classe Win32_ScheduledJob. Observe que essa classe só pode retornar trabalhos que são criados usando um script ou AT.exe. Ele não pode retornar informações sobre trabalhos criados ou modificados pelo assistente de Tarefa Agendada.

VB 
strComputer = "."
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colScheduledJobs = objWMIService.ExecQuery ("Select * from Win32_ScheduledJob")
For Each objJob in colScheduledJobs
    Wscript.Echo "Command: " & objJob.Command & VBNewLine _
    & "Days Of Month: " & objJob.DaysOfMonth & VBNewLine _
    & "Days Of Week: " & objJob.DaysOfWeek & VBNewLine _
    & "Description: " & objJob.Description & VBNewLine _
    & "Elapsed Time: " & objJob.ElapsedTime & VBNewLine _
    & "Install Date: " & objJob.InstallDate & VBNewLine _
    & "Interact with Desktop: " & objJob.InteractWithDesktop & VBNewLine _
    & "Job ID: " & objJob.JobId & VBNewLine _
    & "Job Status: " & objJob.JobStatus & VBNewLine _
    & "Name: " & objJob.Name & VBNewLine _
    & "Notify: " & objJob.Notify & VBNewLine _
    & "Owner: " & objJob.Owner & VBNewLine _
    & "Priority: " & objJob.Priority & VBNewLine _
    & "Run Repeatedly: " & objJob.RunRepeatedly & VBNewLine _
    & "Start Time: " & objJob.StartTime & VBNewLine _
    & "Status: " & objJob.Status & VBNewLine _
    & "Time Submitted: " & objJob.TimeSubmitted & VBNewLine _
    & "Until Time: " & objJob.UntilTime
Next

tarefas WMI para scripts e aplicativos

Exemplos de aplicativos WMI C++

TechNet ScriptCenter

  • Last updated on