Exibição de Nomes e Estados de Tarefas (Script)

Este exemplo de script mostra como enumerar tarefas em uma pasta de tarefas e exibir valores de propriedade de cada tarefa.

O procedimento a seguir descreve como exibir nomes e estados de tarefas para todas as tarefas em uma pasta de tarefas.

Para exibir nomes e estados de tarefas para todas as tarefas em uma pasta de tarefas

1. Crie o objeto TaskService.

   Este objeto permite que você se conecte ao serviço Agendador de Tarefas e acesse uma pasta de tarefas específica.

2. Obtenha uma pasta de tarefas que contenha as tarefas sobre as quais pretende obter informações.

   Use o método TaskService.GetFolder para obter a pasta.

3. Obtenha a coleção de tarefas da pasta.

   Utilize o método TaskFolder.GetTasks para obter a coleção de tarefas (RegisteredTaskCollection).

4. Obtenha o número de tarefas na coleção e enumere cada tarefa na coleção.

   Use a coleção de objetos RegisteredTaskCollection para obter uma instância de objeto RegisteredTask. Cada instância conterá uma tarefa na coleção. Em seguida, você pode exibir as informações (valores de propriedade) de cada tarefa registrada.

O exemplo VBScript a seguir mostra como enumerar através de uma coleção de tarefas registradas na pasta de tarefas raiz e exibir o nome e o estado de cada tarefa.

'---------------------------------------------------------
' This sample enumerates through the tasks on the local computer and
' displays their name and state.
'---------------------------------------------------------


' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

' Get the task folder that contains the tasks. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")
 
Dim taskCollection
Set taskCollection = rootFolder.GetTasks(0)

Dim numberOfTasks
numberOfTasks = taskCollection.Count

If numberOfTasks = 0 Then 
    Wscript.Echo "No tasks are registered."
Else
    WScript.Echo "Number of tasks registered: " & numberOfTasks
    
    Dim registeredTask
    For Each registeredTask In taskCollection
        WScript.Echo "Task Name: " & registeredTask.Name
    
        Dim taskState 
        Select Case registeredTask.State 
            Case "0"
                taskState = "Unknown"
            Case "1"
                taskState = "Disabled"
            Case "2"
                taskState = "Queued"
            Case "3"
                taskState = "Ready"
            Case "4"
                taskState = "Running"
        End Select

        WScript.Echo "    Task State: " & taskState
    Next
End If

Tópicos relacionados

Usando o Agendador de Tarefas