Table.RemoveMatchingRows

ไวยากรณ์

Table.RemoveMatchingRows(
    table as table,
    rows as list,
    optional equationCriteria as any
) as table

เกี่ยวกับ

ลบการปรากฏทั้งหมดของแถวที่ระบุออกจากตาราง

• table: ตารางที่จะค้นหา
• rows: รายการที่มีข้อมูลเกี่ยวกับแถวที่จะเอาออก
• equationCriteria: (ไม่บังคับ) ระบุวิธีการกําหนดความเท่าเทียมกันเมื่อเปรียบเทียบค่า พารามิเตอร์นี้อาจเป็นฟังก์ชันตัวเลือกคีย์ ฟังก์ชันตัวเปรียบเทียบ หรือรายการคอลัมน์ในตารางเพื่อใช้เมื่อเปรียบเทียบแถว

ตัวอย่าง 1

ลบแถวใดๆ ที่มี [a = 1] ออกจากตารางที่ระบุ

การใช้งาน

Table.RemoveMatchingRows(
    Table.FromRecords({
        [a = 1, b = 2],
        [a = 3, b = 4],
        [a = 1, b = 6]
    }),
    {[a = 1]},
    "a"
)

เอาท์พุท

Table.FromRecords({[a = 3, b = 4]})

ตัวอย่าง 2

ลบคําสั่งซื้อที่ยกเลิกโดยไม่สนใจกรณี

การใช้งาน

let
    CurrentOrders = #table(type table[OrderID = number, Product = text, Quantity = number],
    {
        {101, "Widget", 5},
        {102, "Gadget", 3},
        {103, "Widget", 5}
    }),
    CanceledOrders = {
        [OrderID = 103, Product = "widget", Quantity = 5]
    },
    FilteredOrders = Table.RemoveMatchingRows(CurrentOrders, CanceledOrders, Comparer.OrdinalIgnoreCase)
in
    FilteredOrders

เอาท์พุท

#table(type table[OrderID = number, Product = text, Quantity = number],
{
    {101, "Widget", 5},
    {102, "Gadget", 3}
})

ตัวอย่างที่ 3

นํางานบํารุงรักษาที่ตรงกับวันหยุดของสหรัฐฯ ออก

การใช้งาน

let
    MaintenanceSchedule = #table(type table [Task = text, Date = date],
    {
        {"HVAC Check", #date(2025, 7, 10)},             // Not a holiday
        {"Window Washing", #date(2025, 9, 1)},          // Labor Day
        {"Fire Drill", #date(2025, 9, 17)},             // Not a holiday
        {"Light Bulb Replacement", #date(2025, 11, 27)} // Thanksgiving
    }),

    USHolidays = {
        [Date = #date(2025, 1, 1)],   // New Year's Day
        [Date = #date(2025, 7, 4)],   // Independence Day
        [Date = #date(2025, 9, 1)],   // Labor Day
        [Date = #date(2025, 11, 27)], // Thanksgiving
        [Date = #date(2025, 12, 25)]  // Christmas
    },

    FilteredSchedule = Table.RemoveMatchingRows(
        MaintenanceSchedule,
        USHolidays,
        {"Date"}
    )
in
    FilteredSchedule

เอาท์พุท

#table(type table[Task = text, Date = date],
{
    {"HVAC Check", #date(2025, 7, 10)},
    {"Fire Drill", #date(2025, 9, 17)}
})

เนื้อหาที่เกี่ยวข้อง

เกณฑ์สมการ