แบบฝึกหัด - สร้างและใช้โมดูล

คุณได้รับมอบหมายให้เพิ่มเครือข่ายจัดส่งเนื้อหาหรือ CDN ไปยังเว็บไซต์ของบริษัทของคุณสําหรับการเปิดตัวของของเล่นวูมแบต อย่างไรก็ตาม ทีมอื่นๆ ในบริษัทของคุณได้บอกคุณว่าพวกเขาไม่ต้องการ CDN ในแบบฝึกหัดนี้ คุณจะสร้างมอดูลสําหรับเว็บไซต์และ CDN และคุณจะเพิ่มมอดูลลงในเทมเพลต

ในระหว่างกระบวนการ คุณจะ:

แบบฝึกหัดนี้ใช้ส่วนขยาย Bicep สําหรับ Visual Studio Code ตรวจสอบให้แน่ใจว่าได้ติดตั้งส่วนขยายนี้ใน Visual Studio Code

สร้างไฟล์ Bicep ที่ว่างเปล่า

1. เปิด Visual Studio Code

2. สร้างไฟล์ใหม่ที่เรียกว่า main.bicep

3. บันทึกไฟล์เปล่าเพื่อให้ Visual Studio Code โหลดเครื่องมือ Bicep

   คุณสามารถเลือกไฟล์ >บันทึกเป็น หรือเลือก Ctrl + S บน Windows (⌘+ S บน macOS) อย่าลืมจดจําตําแหน่งที่คุณบันทึกไฟล์ ตัวอย่างเช่น คุณอาจต้องการสร้างเทมเพลต โฟลเดอร์เพื่อบันทึก

สร้างมอดูลสําหรับแอปพลิเคชันของคุณ

1. สร้างโฟลเดอร์ใหม่ที่เรียกว่า โมดูล ในโฟลเดอร์เดียวกันกับที่คุณสร้างไฟล์ main.bicep ของคุณ ในโฟลเดอร์ โมดูล ให้สร้างไฟล์ที่เรียกว่า app.bicep บันทึกไฟล์

2. เพิ่มเนื้อหาต่อไปนี้ลงในไฟล์ app.bicep:

   @description('The Azure region into which the resources should be deployed.')
   param location string
   
   @description('The name of the App Service app.')
   param appServiceAppName string
   
   @description('The name of the App Service plan.')
   param appServicePlanName string
   
   @description('The name of the App Service plan SKU.')
   param appServicePlanSkuName string
   
   resource appServicePlan 'Microsoft.Web/serverfarms@2024-04-01' = {
     name: appServicePlanName
     location: location
     sku: {
       name: appServicePlanSkuName
     }
   }
   
   resource appServiceApp 'Microsoft.Web/sites@2024-04-01' = {
     name: appServiceAppName
     location: location
     properties: {
       serverFarmId: appServicePlan.id
       httpsOnly: true
     }
   }
   
   @description('The default host name of the App Service app.')
   output appServiceAppHostName string = appServiceApp.properties.defaultHostName
   

   ไฟล์นี้ปรับใช้แผนบริการแอป Azure และแอป โปรดสังเกตว่าโมดูลเป็นแบบทั่วไป ซึ่งไม่รวมถึงสมมติฐานใด ๆ เกี่ยวกับชื่อของทรัพยากร หรือ SKU ของแผนบริการแอป ซึ่งทําให้ง่ายต่อการนําโมดูลกลับมาใช้ใหม่สําหรับการปรับใช้ที่แตกต่างกัน

3. บันทึกการเปลี่ยนแปลงไปยังไฟล์

เพิ่มมอดูลลงในเทมเพลต Bicep ของคุณ

ที่นี่ คุณเพิ่มแอป มอดูลไปยังเทมเพลต Bicep ของคุณเป็นจุดเริ่มต้น

1. เปิดไฟล์ main.bicep

2. เพิ่มพารามิเตอร์และตัวแปรต่อไปนี้ลงในไฟล์:

   @description('The Azure region into which the resources should be deployed.')
   param location string = 'westus3'
   
   @description('The name of the App Service app.')
   param appServiceAppName string = 'toy-${uniqueString(resourceGroup().id)}'
   
   @description('The name of the App Service plan SKU.')
   param appServicePlanSkuName string = 'F1'
   
   var appServicePlanName = 'toy-product-launch-plan'
   

   เนื่องจากเป็นเทมเพลตที่คุณต้องการปรับใช้สําหรับเว็บไซต์ของเล่นของคุณดังนั้นจึงมีความเฉพาะเจาะจงมากขึ้น ชื่อแผนบริการแอปถูกกําหนดเป็นตัวแปร พารามิเตอร์ SKU มีค่าเริ่มต้นที่เหมาะสมกับเว็บไซต์การเปิดใช้งานของเล่น

3. ด้านล่างพารามิเตอร์ สร้างบรรทัดว่าง ตอนนี้ พิมพ์บรรทัดแรกของข้อกําหนดโมดูลแอป:

   module app 'modules/app.bicep' = {
   

   ขณะที่คุณพิมพ์ ให้สังเกตว่าส่วนขยาย Bicep สําหรับ Visual Studio Code ช่วยให้คุณสามารถยกระดับการประกาศโมดูลได้ เมื่อคุณพิมพ์เส้นทางไปยังโมดูลของคุณและพิมพ์อักขระเท่ากับ (=) เมนูป็อปอัพจะปรากฏขึ้นพร้อมตัวเลือกหลายตัว

4. เลือกคุณสมบัติที่จําเป็น จากเมนูป็อปอัพ:

   

5. ทําการรายงานโมดูลให้เสร็จสมบูรณ์:

   module app 'modules/app.bicep' = {
     name: 'toy-launch-app'
     params: {
       appServiceAppName: appServiceAppName
       appServicePlanName: appServicePlanName
       appServicePlanSkuName: appServicePlanSkuName
       location: location
     }
   }
   

6. ที่ด้านล่างของไฟล์ ให้กําหนดเอาต์พุต:

   @description('The host name to use to access the website.')
   output websiteHostName string = app.outputs.appServiceAppHostName
   

7. บันทึกการเปลี่ยนแปลงไปยังไฟล์

สร้างโมดูลสําหรับเครือข่ายการจัดส่งเนื้อหา

1. ในโฟลเดอร์ โมดูล ให้สร้างไฟล์ที่เรียกว่า cdn.bicep บันทึกไฟล์

2. เพิ่มเนื้อหาต่อไปนี้ลงในไฟล์ cdn.bicep:

   @description('The host name (address) of the origin server.')
   param originHostName string
   
   @description('The name of the CDN profile.')
   param profileName string = 'cdn-${uniqueString(resourceGroup().id)}'
   
   @description('The name of the CDN endpoint')
   param endpointName string = 'endpoint-${uniqueString(resourceGroup().id)}'
   
   @description('Indicates whether the CDN endpoint requires HTTPS connections.')
   param httpsOnly bool
   
   var originName = 'my-origin'
   
   resource cdnProfile 'Microsoft.Cdn/profiles@2024-09-01' = {
     name: profileName
     location: 'global'
     sku: {
       name: 'Standard_Microsoft'
     }
   }
   
   resource endpoint 'Microsoft.Cdn/profiles/endpoints@2024-09-01' = {
     parent: cdnProfile
     name: endpointName
     location: 'global'
     properties: {
       originHostHeader: originHostName
       isHttpAllowed: !httpsOnly
       isHttpsAllowed: true
       queryStringCachingBehavior: 'IgnoreQueryString'
       contentTypesToCompress: [
         'text/plain'
         'text/html'
         'text/css'
         'application/x-javascript'
         'text/javascript'
       ]
       isCompressionEnabled: true
       origins: [
         {
           name: originName
           properties: {
             hostName: originHostName
           }
         }
       ]
     }
   }
   
   @description('The host name of the CDN endpoint.')
   output endpointHostName string = endpoint.properties.hostName
   

   ไฟล์นี้ใช้ทรัพยากรสองประเภท: โปรไฟล์ CDN และจุดสิ้นสุด CDN

3. บันทึกการเปลี่ยนแปลงไปยังไฟล์

เพิ่มโมดูลไปยังเทมเพลต Bicep หลัก

1. เปิดไฟล์ main.bicep

2. ใต้พารามิเตอร์ appServicePlanSkuName ให้เพิ่มพารามิเตอร์ต่อไปนี้:

   @description('Indicates whether a CDN should be deployed.')
   param deployCdn bool = true
   

3. ด้านล่างข้อกําหนดโมดูล app ให้กําหนดโมดูล cdn:

   module cdn 'modules/cdn.bicep' = if (deployCdn) {
     name: 'toy-launch-cdn'
     params: {
       httpsOnly: true
       originHostName: app.outputs.appServiceAppHostName
     }
   }
   

   โปรดสังเกตว่าโมดูลมีเงื่อนไขเพื่อให้มีการปรับใช้เฉพาะเมื่อค่าพารามิเตอร์ deployCdn ได้รับการตั้งค่าเป็น true นอกจากนี้ โปรดสังเกตว่าพารามิเตอร์ originHostName ของโมดูลถูกตั้งค่าเป็นค่าของเอาต์พุต appServiceAppHostName จากโมดูล app

4. ปรับปรุงผลลัพธ์ชื่อโฮสต์เพื่อให้เลือกชื่อโฮสต์ที่ถูกต้อง เมื่อมีการปรับใช้ CDN คุณต้องการให้ชื่อโฮสต์อยู่ในตําแหน่งข้อมูล CDN

   output websiteHostName string = deployCdn ? cdn.outputs.endpointHostName : app.outputs.appServiceAppHostName
   

5. บันทึกการเปลี่ยนแปลงไปยังไฟล์

ตรวจสอบไฟล์ Bicep ของคุณ

หลังจากที่คุณทําการเปลี่ยนแปลงก่อนหน้านี้ทั้งหมดเสร็จสิ้นแล้ว ไฟล์ main.bicep ของคุณควรมีลักษณะดังนี้:

@description('The Azure region into which the resources should be deployed.')
param location string = 'westus3'

@description('The name of the App Service app.')
param appServiceAppName string = 'toy-${uniqueString(resourceGroup().id)}'

@description('The name of the App Service plan SKU.')
param appServicePlanSkuName string = 'F1'

@description('Indicates whether a CDN should be deployed.')
param deployCdn bool = true

var appServicePlanName = 'toy-product-launch-plan'

module app 'modules/app.bicep' = {
  name: 'toy-launch-app'
  params: {
    appServiceAppName: appServiceAppName
    appServicePlanName: appServicePlanName
    appServicePlanSkuName: appServicePlanSkuName
    location: location
  }
}

module cdn 'modules/cdn.bicep' = if (deployCdn) {
  name: 'toy-launch-cdn'
  params: {
    httpsOnly: true
    originHostName: app.outputs.appServiceAppHostName
  }
}

@description('The host name to use to access the website.')
output websiteHostName string = deployCdn ? cdn.outputs.endpointHostName : app.outputs.appServiceAppHostName

ถ้าไม่เป็นเช่นนั้น ให้คัดลอกตัวอย่างหรือปรับเทมเพลตของคุณให้ตรงกับตัวอย่าง

ปรับใช้เทมเพลต Bicep กับ Azure

az bicep install && az bicep upgrade

az deployment group create --name main --template-file main.bicep

New-AzResourceGroupDeployment -Name main -TemplateFile main.bicep

ตรวจสอบประวัติการปรับใช้

1. ลงชื่อเข้าใช้ พอร์ทัล Azure และตรวจสอบให้แน่ใจว่าคุณกําลังใช้การสมัครใช้งานที่เหมาะสม:

   1. เลือกอวาตาร์ของคุณที่มุมบนขวาของหน้า
   2. เลือก สลับไดเรกทอรี ในรายการ ให้เลือกไดเรกทอรีที่เหมาะสม

2. บนแผงด้านซ้าย เลือก กลุ่มทรัพยากร

3. เลือก myResourceGroupName

4. บนเมนูทางด้านซ้าย เลือก การปรับใช้ ภายใต้ การตั้งค่า

   

   การปรับใช้สามรายการจะแสดงอยู่

5. เลือกการปรับใช้ หลัก และขยาย รายละเอียดการปรับใช้

   โปรดสังเกตว่าทั้งสองโมดูลอยู่ในรายการ และชนิดของโมดูลดังกล่าวจะแสดงเป็น Microsoft.Resources/deployments โมดูลจะแสดงเป็นสองครั้งเนื่องจากเอาต์พุตจะถูกอ้างอิงภายในเทมเพลต

   

6. เลือก ของเล่น toy-launch-cdn และ ของเล่น การปรับใช้และตรวจทานทรัพยากรที่ปรับใช้ในแต่ละส่วน โปรดสังเกตว่าสอดคล้องกับทรัพยากรที่กําหนดไว้ในโมดูลที่เกี่ยวข้อง

ทดสอบเว็บไซต์

1. เลือก การปรับใช้แอปของเล่น

2. เลือก เอาต์พุต

   

3. เลือกปุ่มคัดลอกสําหรับเอาต์พุต appServiceAppHostName

4. บนแท็บเบราว์เซอร์ใหม่ ลองไปยังที่อยู่ที่คุณคัดลอกในขั้นตอนก่อนหน้า ที่อยู่ควรเริ่มต้นด้วย https://

   

   หน้ายินดีต้อนรับของบริการแอปจะปรากฏขึ้น ซึ่งแสดงว่าคุณได้ปรับใช้แอปเรียบร้อยแล้ว

5. ไปที่การปรับใช้ หลัก และเลือก เอาต์พุต

6. คัดลอกค่าของ websiteHostName เอาต์พุต โปรดสังเกตว่าชื่อโฮสต์นี้แตกต่างกันเนื่องจากเป็นชื่อโฮสต์ Azure Content Delivery Network

7. ในแท็บเบราว์เซอร์ใหม่ ลองไปที่ชื่อโฮสต์ที่คุณคัดลอกในขั้นตอนก่อนหน้า เพิ่ม https:// ลงในจุดเริ่มต้นของที่อยู่

   จุดสิ้นสุด CDN จะใช้เวลาสักครู่เพื่อเปิดใช้งาน ถ้าคุณได้รับเพจ ไม่พบ ข้อผิดพลาด ให้รอสักครู่แล้วลองวางลิงก์อีกครั้ง นอกจากนี้ ตรวจสอบให้แน่ใจว่าคุณได้เพิ่ม https:// ลงในจุดเริ่มต้นของ URL เพื่อให้คุณกําลังใช้ HTTPS

   เมื่อตําแหน่งข้อมูล CDN เปิดใช้งาน คุณจะได้รับหน้ายินดีต้อนรับของบริการแอปเดียวกัน ในครั้งนี้ บริการนี้ให้บริการผ่านบริการ Azure Content Delivery Network ซึ่งจะช่วยปรับปรุงประสิทธิภาพของเว็บไซต์