通过

DBEngine.CreateWorkspace 方法 (DAO)

适用于：Access 2013、Office 2013

创建新的 Workspace 对象。

语法

表达式 。CreateWorkspace (名称、 用户名、 密码、 UseType)

表达式 一个表示 DBEngine 对象的变量。

参数

名称

必需/可选

数据类型

说明

Name

必需

字符串

一个 String，对新的 Workspace 对象进行唯一命名。 有关有效工作区名称的详细信息，请参阅 Name 属性。

UserName

必需

字符串

一个 String 类型的值，用于标识新的 Workspace 对象的所有者。 有关详细信息，请参阅 UserName 属性。

Password

必需

字符串

一个包含新 Workspace 对象密码的字符串。 密码最多可包含 20 个字符，并且可以包含除 ASCII 字符 0 之外的任何字符 (null) 。

注意：使用组合大小写字母、数字和符号的强密码。 弱密码不混合使用这些元素。 例如，强密码：Y6dh!et5。 弱密码：House27。 请使用可以记住的强密码，这样就不必记录密码了。

UseType

可选

Variant

WorkspaceTypeEnum 值之一。

注释：Microsoft Access 2013 中不支持 ODBCDirect 工作区。 如果要在不使用 Microsoft Access 数据库引擎的情况下访问外部数据源，请使用 ADO。

返回值

工作区

备注

一旦使用 CreateWorkspace 方法来创建新的 Workspace 对象，将启动一个 Workspace 会话，并且您可以在应用程序中引用该 Workspace 对象。

Workspace 对象不是永久性的，不能保存到磁盘中。 一旦创建了 Workspace 对象，就不能改动此对象的任何属性设置，但在将 Workspace 对象追加到 Workspaces 集合之前，可以修改 Name 属性。

您不必将新的 Workspace 对象追加到集合就可以使用该对象。 仅当需要通过 Workspaces 集合引用新创建的 Workspace 对象时，才需要追加该对象。

要从 Workspaces 集合中删除 Workspace 对象，请关闭所有打开的数据库和连接，然后对 Workspace 对象使用 Close 方法。

示例

此示例使用 CreateWorkspace 方法创建Microsoft Access 工作区。 然后，它会列出工作区的属性。

Sub CreateWorkspaceX() 
 
   Dim wrkAcc As Workspace 
   Dim wrkLoop As Workspace 
   Dim prpLoop As Property 
 
   DefaultType = dbUseJet 
   ' Create an unnamed Workspace object of the type  
   ' specified by the DefaultType property of DBEngine  
   ' (dbUseJet). 
   Set wrkAcc = CreateWorkspace("", "admin", "") 
 
   ' Enumerate Workspaces collection. 
   Debug.Print "Workspace objects in Workspaces collection:" 
   For Each wrkLoop In Workspaces 
      Debug.Print "  " & wrkLoop.Name 
   Next wrkLoop 
 
   With wrkAcc 
      ' Enumerate Properties collection of Microsoft Access  
      ' workspace. 
      Debug.Print _ 
         "Properties of unnamed Microsoft Access workspace" 
      On Error Resume Next 
      For Each prpLoop In .Properties 
         Debug.Print "  " & prpLoop.Name & " = " & prpLoop 
      Next prpLoop 
      On Error GoTo 0 
   End With 
 
   wrkAcc.Close 
 
End Sub
  • Last updated on