通过

Form.DatasheetFontWeight 属性 (Access)

使用 DatasheetFontWeight 属性可以指定用于在数据表视图中显示和打印字段名称和数据的字符的字体的行宽。 Integer 型，可读/写。

语法

表达式。DatasheetFontWeight

expression：表示 Form 对象的变量。

备注

DatasheetFontWeight 属性应用于数据表视图中的所有字段和窗体控件窗体位于数据表视图中。

只能在 Microsoft Access 数据库中通过 Visual Basic 使用这些属性。

在 Visual Basic 中的 DatasheetFontWeight 属性设置使用下列 整数 值。

Setting 说明
100 细
200 特细
300 淡
400 （默认）普通
500 中等
600 半粗
700 粗体
800 特粗
900 重负载

下表包含 DAO 属性 集合中不存在的属性，直到使用 格式设置 (数据表) 工具栏，或者可以使用 CreateProperty 方法将它们添加到 Access 数据库中，并将其追加到 DAO 属性 集合。

属性 属性继续
DatasheetFontItalic * DatasheetForeColor *
DatasheetFontHeight * DatasheetBackColor
DatasheetFontName * DatasheetGridlinesColor
DatasheetFontUnderline * DatasheetGridlinesBehavior
DatasheetFontWeight * DatasheetCellsEffect

注意

[!注释] 当您添加或设置任何属性列出带有一个星号时，Microsoft Access 将自动添加带有星号的数据库 属性 集合中列出的所有属性。

示例

以下示例将字体设置为 MS Serif，字体大小设置为 10 磅，在 Products 表的数据表视图中将字体粗细设置为中等 (500) 。

Sub SetDatasheetFont 
 
   Dim dbs As Object, objProducts As Object 
   Set dbs = CurrentDb 
   Const DB_Text As Long = 10 
   Const DB_Integer As Long = 3 
   Set objProducts = dbs!Products 
    
   SetTableProperty objProducts, "DatasheetFontName", DB_Text, "MS Serif" 
   SetTableProperty objProducts, "DatasheetFontHeight", DB_Integer, 10 
   SetTableProperty objProducts, "DatasheetFontWeight", DB_Integer, 500 
 
End Sub 
 
Sub SetTableProperty(objTableObj As Object, strPropertyName As String, _ 
        intPropertyType As Integer, varPropertyValue As Variant) 
    ' Set Microsoft Access-defined table property without causing 
    ' nonrecoverable run-time error. 
    Const conErrPropertyNotFound = 3270 
    Dim prpProperty As Variant 
    On Error Resume Next                ' Don't trap errors. 
    objTableObj.Properties(strPropertyName) = varPropertyValue 
    If Err <> 0 Then                    ' Error occurred when value set. 
        If Err <> conErrPropertyNotFound Then 
            On Error GoTo 0 
            MsgBox "Couldn't set property '" & strPropertyName _ 
                & "' on table '" & objTableObj.Name & "'", 48, "SetTableProperty" 
        Else 
            On Error GoTo 0 
            Set prpProperty = objTableObj.CreateProperty(strPropertyName, _ 
                intPropertyType, varPropertyValue) 
            objTableObj.Properties.Append prpProperty 
        End If 
    End If 
    objTableObj.Properties.Refresh 
End Sub

以下示例与打开的 “产品 ”窗体的“数据表”视图中的前面示例相同的更改。

Forms!Products.DatasheetFontName = "MS Serif" 
Forms!Products.DatasheetFontHeight = 10 
Forms!Products.DatasheetFontWeight = 500

支持和反馈

有关于 Office VBA 或本文档的疑问或反馈？ 请参阅 Office VBA 支持和反馈，获取有关如何接收支持和提供反馈的指南。

  • Last updated on