List.PositionOf

语法

List.PositionOf(
    list as list,
    value as any,
    optional occurrence as nullable number,
    optional equationCriteria as any
) as any

关于

返回指定值出现在列表中的偏移量。 如果值未出现，则返回 -1。

• list：要搜索的列表。
• value：要在列表中查找的值。
• occurrence：（可选） 要报告的特定事件。 此值可以是 Occurrence.First、 Occurrence.Last 或 Occurrence.All。 occurrence如果未指定，Occurrence.First则使用。
• equationCriteria：（可选） 指定比较值时如何确定相等性。 此参数可以是键选择器函数、比较器函数或包含键选择器和比较器的列表。

示例 1

查找列表 {1, 2, 3} 中出现值 3 的位置。

使用情况

List.PositionOf({1, 2, 3}, 3)

输出

2

示例 2

在 2022 年的所有日期实例列表中查找位置。

使用情况

let
    Source = {
        #date(2021, 5, 10),
        #date(2022, 6, 28),
        #date(2023, 7, 15),
        #date(2022, 12, 31),
        #date(2022, 4, 8),
        #date(2024, 3, 20)
    },
    YearList = List.Transform(Source, each Date.Year(_)),
    TargetYear = 2022,
    FindPositions = List.PositionOf(YearList, TargetYear, Occurrence.All)
in
    FindPositions

输出

{1, 3, 4}

示例 3

在词狗的最后一个匹配项列表中查找位置，忽略大小写。

使用情况

let
    Source = List.PositionOf(
        {"dog", "cat", "DOG", "pony", "bat", "rabbit", "dOG"}, 
        "dog", 
        Occurrence.Last, 
        Comparer.OrdinalIgnoreCase
    )
in
    Source

输出

6

示例 4

查找列表中位于数字 28 的两个单位内的位置。

使用情况

let
    Source = { 10, 15, 20, 25, 30 },
    Position = List.PositionOf(
        Source, 
        28,
        Occurrence.First, 
        (x, y) => Number.Abs(x - y) <= 2
    )
in
    Position

输出

4

相关内容

公式条件