使用 DAX 时间智能函数

DAX 包含多个时间智能函数，以简化修改日期筛选器上下文的任务。 可以通过使用修改日期筛选器的 CALCULATE 函数编写其中多个智能公式，但这样做会产生更多工作。

日期表要求

若要使用时间智能 DAX 函数，您需要满足在模型中至少具有一个日期表 的先决条件模型要求。 日期表是标记为“Date”表的表。 该表必须具有数据类型为“日期”（或日期/时间）的列，称为日期列。 日期列必须：

• 包含唯一值。
• 跨越全部年份。
• 不包含空值。
• 没有任何缺失的日期。

有关详细信息，请参阅在 Power BI Desktop 中创建日期表。

在一段时间内汇总

一组 DAX 时间智能函数与一段时间内的汇总相关：

• DATESYTD - 返回一个单列表，其中包含当前筛选器上下文中的年初迄今 (YTD) 日期。 此组还包括针对本月至今 (MTD) 和本季度至今 (QTD) 的 DATESMTD 和 DATESQTD 函数。 您可以将这些函数作为筛选器传递到 CALCULATE 函数。
• TOTALYTD - 计算当前筛选器上下文中 YTD 的表达式。 还包括 TOTALQTD 和 TOTALMTD 的等效 QTD 和 MTD DAX 函数。
• DATESBETWEEN - 返回一个表，该表包含由日期构成的一列，这些日期从给定的开始日期开始，并一直持续到给定的结束日期。
• DATESINPERIOD - 返回一个表，该表包含由日期构成的一列，这些日期从给定的开始日期开始，并持续指定数量的间隔时间。

在以下示例中，您将创建第一个使用 TOTALYTD 函数的时间智能计算。 语法如下：

TOTALYTD(<expression>, <dates>, [, <filter>][, <year_end_date>])

函数需要表达式，和所有时间智能函数一样，还需要对标记日期表的日期列的引用。 （可选）可以传入一个筛选表达式或年终结算日期（仅当年份不是在 12 月 31 日结束时才需要）。

下载并打开 Adventure Works DW 2020 M07.pbix 文件。 然后，将以下度量值定义添加到计算 YTD 收入的 Sales 表。 将此度量值的格式设置为带有两个小数位数的货币。

Revenue YTD =
TOTALYTD(
    [Revenue],
    'Date'[Date],
    "6-30"
)

"6-30" 的年终结算日期值表示 6 月 30 日。

在报表的第 1 页上，将 Revenue YTD 度量值添加到矩阵视觉对象。 请注意，它将生成从年初到已筛选月份的收入金额的汇总。

在一段时间内比较

另一组 DAX 时间智能函数与转换时间段相关：

• DATEADD - 返回一个表，该表包含由日期构成的一列，这些日期在时间上从当前筛选器上下文中的日期前移或后移指定数量的时间间隔。
• PARALLELPERIOD - 返回一个表，该表包含由日期构成的一列，这些日期表示与当前筛选器上下文中指定的日期列中的日期并行的期间，该列中具有在时间上前移或后移时间间隔数量的日期。
• SAMEPERIODLASTYEAR - 返回一个表，该表包含由日期构成的一列，这些日期在时间上从当前筛选器上下文中指定的日期列中的日期移回一年。
• 许多 helper DAX 函数用于在特定时间段向后或向前导航，所有这些函数都将返回一个日期表。 这些 helper 函数包括 NEXTDAY、NEXTMONTH、NEXTQUARTER、NEXTYEAR、PREVIOUSDAY、PREVIOUSMONTH、PREVIOUSQUARTER 和 PREVIOUSYEAR。

现在，您将使用 SAMEPERIODLASTYEAR 函数向 Sales 表中添加一个度量值，用于计算上一年的收入。 将此度量值的格式设置为带有两个小数位数的货币。

Revenue PY =
VAR RevenuePriorYear = CALCULATE(
    [Revenue],
    SAMEPERIODLASTYEAR('Date'[Date])
)
RETURN
    RevenuePriorYear

将 Revenue PY 度量值添加到矩阵视觉对象。 请注意，它生成的结果与上一年的收入金额类似。

接下来，您将通过将该度量值重命名为 Revenue YoY % 来修改它，然后更新 RETURN 子句以计算更改率。 请务必将格式更改为带有两个小数位数的百分比。

Revenue YoY % =
VAR RevenuePriorYear = CALCULATE(
    [Revenue],
    SAMEPERIODLASTYEAR('Date'[Date])
)
RETURN
    DIVIDE(
        [Revenue] - RevenuePriorYear,
        RevenuePriorYear
    )

请注意，Revenue YoY % 度量值将产生相对上一年月收入的变化系数的比率。 例如，2018 年 7 月相对上一年月收入增加 了 106.53%，而 2018 年 11 月相对上一年月收入减少 了 24.22%。