如需在 Azure 入口網站中使用這些查詢的詳細資訊，請參閱 Log Analytics 教學課程。 如需 REST API，請參閱 查詢。
呼叫自動化作業
傳回呼叫自動化作業和版本組的所有不同組合。
ACSCallAutomationIncomingOperations
| distinct OperationName, OperationVersion
| limit 100
計算呼叫自動化作業持續時間百分位數
計算每個呼叫自動化作業的執行時間的第 90、第 95 和第 99 百分位數，以毫秒為單位。 您可以針對單一作業或其他百分位數自定義它。
ACSCallAutomationIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100
每個呼叫自動化作業的前 5 個 IP 位址
針對每個呼叫自動化作業，擷取最多呼叫該作業的 5 個 IP 位址。
ACSCallAutomationIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100
呼叫自動化作業錯誤
列出依新近性排序的每個呼叫自動化錯誤。
ACSCallAutomationIncomingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature
| order by TimeGenerated desc
| limit 100
呼叫自動化作業結果計數
針對每個呼叫自動化作業，計算傳回結果的類型。
ACSCallAutomationIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType
| order by OperationName asc, Count desc
| limit 100
呼叫連線識別碼的呼叫自動化記錄
查詢特定通話連線標識碼的呼叫自動化記錄。
ACSCallAutomationIncomingOperations
//| where CallConnectionId == "<callConnectionId>" // This can be uncommented to filter on a specific call connection ID
| limit 100
針對呼叫的呼叫自動化 API 作業
傳回特定呼叫的所有呼叫自動化 API 作業和版本組（相互關聯標識碼）。
ACSCallAutomationIncomingOperations
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| project CorrelationId, OperationName, OperationVersion
| limit 100
CallAutomation API 呼叫的 CallDiagnostics 記錄
查詢診斷記錄，以取得呼叫自動化 API 使用相互關聯識別碼與其互動的呼叫。
ACSCallAutomationIncomingOperations
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| join kind=inner
(ACSCallDiagnostics)
on CorrelationId
| limit 100
CallAutomation API 呼叫的 CallSummary 記錄
查詢摘要記錄，以取得呼叫自動化 API 使用相互關聯識別碼與其互動的呼叫。
ACSCallAutomationIncomingOperations
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
| join kind=inner
(ACSCallSummary)
on CorrelationId
| limit 100
啟用 MediaStreaming 的通話數目
計算有啟動媒體串流的呼叫次數。
ACSCallAutomationStreamingUsage
| where StreamingModality contains "AudioStreaming"
| summarize NumCallsWithMediaStreamingActive = dcount(CallConnectionId)
媒體串流作業成功計數
計算 MediaStreaming 作業的成功次數。
ACSCallAutomationIncomingOperations
// Filter OperationName to view results for each API.
| where OperationName in ("StartMediaStreaming", "StopMediaStreaming")
| where tostring(ResultSignature) matches regex "2.."
| summarize MediaStreamingSuccess=count() by ResultSignature
媒體串流作業失敗計數
計算媒體串流作業的失敗次數。
ACSCallAutomationIncomingOperations
// Filter OperationName to view results for each API.
| where OperationName in ("StartMediaStreaming", "StopMediaStreaming")
| where tostring(ResultSignature) matches regex "5.."
| summarize MediaStreamingFailures=count() by ResultSignature
啟用語音文字轉換的通話數量
計算使用轉譯的呼叫數目。
ACSCallAutomationStreamingUsage
| where StreamingModality == "Transcription"
| summarize NumCallsWithTranscriptionActive = dcount(CallConnectionId)
轉譯作業成功計數
計算轉譯作業的成功次數。
ACSCallAutomationIncomingOperations
// Filter OperationName to view results for each API.
| where OperationName in ("StartTranscription", "StopTranscription", "UpdateTranscription")
| where tostring(ResultSignature) matches regex "2.."
| summarize TranscriptionSuccess=count()
轉譯作業失敗計數
計算轉譯作業的失敗次數。
ACSCallAutomationIncomingOperations
// Filter OperationName to view results for each API.
| where OperationName in ("StartTranscription", "StopTranscription", "UpdateTranscription")
| where tostring(ResultSignature) matches regex "5.."
| summarize TranscriptionFailures=count()