共用方式為

對 WVDConnectionNetworkData 資料表的查詢

如需在 Azure 入口網站 中使用這些查詢的詳細資訊，請參閱Log Analytics教學課程。 如需 REST API，請參閱 查詢。

一段時間的平均往返時間

每隔 10 分鐘顯示一個圖表，包括所有連線的往返時間（以毫秒為單位），並顯示第 10、50 和 90 百分位數。

WVDConnectionNetworkData
| summarize percentiles(EstRoundTripTimeInMs, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

所有連線的平均頻寬

顯示所有連線在 10 分鐘間隔內的頻寬圖表（以每秒 KB 為單位），並以第 10、50 和 90 百分位數表示。

WVDConnectionNetworkData
| summarize percentiles(EstAvailableBandwidthKBps, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

最高往返時間的前10位使用者

傳回前 10 位使用者的清單，其中包含最高平均往返時間 （以毫秒為單位）。

WVDConnectionNetworkData
| join kind=leftouter 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=round(avg(EstRoundTripTimeInMs)), RTT_P95=percentile(EstRoundTripTimeInMs, 95) by UserName
| top 10 by AvgRTT desc

帶寬最低的前10位使用者

傳回前10位用戶的清單，其平均頻寬最低（以每秒 KB 為單位）。

WVDConnectionNetworkData
| join kind=inner 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps), BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

來回時間和頻寬的摘要

針對每個連線傳回來回行程時間 (以毫秒為單位) 和頻寬 (以 KB 為單位) 的第 90 個百分位數，以及其他連線詳細資料。

WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90), BWP90=percentile(EstAvailableBandwidthKBps,90), StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=inner
(
    WVDConnections
    | where State == "Connected"
    | extend Protocol = iif(UdpUse in ("0", "<>"), "TCP", "UDP")
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion
  • Last updated on