儀錶板特定視覺效果

所有在轉譯運算符內容中建立的視覺效果都可在儀錶板視覺效果中使用。 不過，下列視覺效果僅適用於 Azure 數據總管儀錶板、即時儀錶板或 Azure 數據總管 Web UI，而非轉譯運算元。

若要瞭解如何自定義任何儀錶板視覺效果，請參閱 自定義 Azure 數據總管儀錶板視覺效果

如需 Azure 數據總管中儀錶板的一般資訊，請參閱 使用 Azure 數據總管儀錶板將數據可視化。

漏斗圖

漏鬥圖會將具有循序連線階段的線性程式可視化。 漏斗圖的每個階段代表總數中所佔的百分比。 因此，在大部分情況下，漏鬥圖的形狀就像漏鬥圖，第一個階段是最大的，而且每個後續階段都小於其前置階段。

下列範例視覺化伺服器請求的進度，顯示工作階段、請求及其完成狀態的總數。 它著重顯示從會話到請求的減少，以及已完成請求與未完成請求的比例。

範例查詢

let stageOrder = datatable(Stage:string, Order:int)
[
    "session_id", 1,
    "request_id", 2,
    "Completed", 3,
    "Incomplete", 4
];

let base = TransformedServerMetrics
| where MetricType == "sqlserver_requests";

// Build the funnel table dynamically
let funnelData = 
    union 
    (base | where SQLMetrics == "session_id" | summarize Count = count() | extend Stage = "session_id"),
    (base | where SQLMetrics == "request_id" | summarize Count = count() | extend Stage = "request_id"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value == 100) | extend Stage = "Completed"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value < 100) | extend Stage = "Incomplete");

// Join with stage order and order properly
funnelData
| join kind=inner stageOrder on Stage
| order by Order asc
| project Stage, Count

熱度圖

熱度圖會將兩個軸變數中感興趣的主要變數值顯示為彩色方格。

若要轉譯熱度圖，查詢必須產生具有三個數據行的數據表。 用於值欄位的資料必須是數值。 將用於 x 和 y 值的欄位會使用下列規則：

• 如果 x 欄中的值採用格式 string ，則 y 欄中的值也必須採用格式 string 。
• 如果 x 欄中的值採用格式 datetime ，則 y 欄中的值必須是數值。

下列範例顯示五個最常使用 SQL 指標在不同指標類型中的分佈。 它會醒目提示每個 SQL 指標最常見的指標類型，讓您輕鬆識別熱門指標中的活動模式。

範例查詢

let topMetrics = TransformedServerMetrics
| summarize TotalCount = count() by SQLMetrics
| top 5 by TotalCount;  // pick only the 5 most common metrics

TransformedServerMetrics
| where SQLMetrics in (topMetrics | project SQLMetrics)
| summarize Count = count() by SQLMetrics, MetricType
| project X = MetricType, Y = SQLMetrics, Value = Count