地理空間視覺效果

適用於：✅Microsoft網狀架構✅✅

地理空間數據可以使用 轉譯運算符 作為地圖上的點、餡餅或泡泡，以可視化方式呈現為查詢的一部分。

如需地理空間叢集的詳細資訊，請參閱 地理空間叢集。

範例

下列範例會尋找風暴事件，並將地圖上的 100 可視化。

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

下列範例將多個點數列可視化，其中 [經度，緯度] 配對會定義每個點，而第三個數據行會定義數列。 在這裡範例中，數列是 EventType。

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

下列範例會將地圖上的一系列點可視化。 如果您在結果中有多個數據行，則必須指定要用於 xcolumn （經度）、ycolumn （緯度） 和數列的數據行。

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

下列範例會使用 GeoJSON 動態值在地圖上可視化點，以定義點。

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

下列範例顯示由 S2 單元格匯總的 Storm 事件。 圖表會依單一色彩的位置匯總泡泡中的事件。

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map)

下列範例顯示由 S2 單元格匯總的 Storm 事件。 圖表會依位置依餅圖中的事件類型匯總事件。

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map)

相關內容

• 地理空間叢集
• 轉譯運算符
• 汽車測試車隊 的數據分析（地理空間叢集使用案例）
• 瞭解地理空間數據處理和分析的 Azure 架構