共用方式為

WMI 工作：作業系統

作業系統的 WMI 工作會取得有關作業系統的資訊，例如版本、是否已啟用或安裝哪些 Hotfix。

本主題中顯示的腳本範例只會從本機計算機取得數據。 如需有關如何使用腳本從遠端電腦取得資料的詳細資訊，請參閱 在遠端電腦連線到 WMI。

下列程式描述如何執行腳本。

執行腳本

  1. 複製程序代碼，並將它儲存在擴展名為 .vbs 的檔案中，例如 filename.vbs。 請確定文字編輯器不會將 .txt 擴展名新增至檔案。
  2. 開啟命令提示字元視窗，並導航至您儲存檔案的目錄。
  3. 在命令提示字元中輸入 CScript filename.vbs。
  4. 如果您無法存取事件記錄檔，請檢查您是否正在從提高許可權的命令提示字元執行。 某些事件記錄檔，例如安全性事件記錄檔，可能會受到使用者訪問控制 （UAC） 的保護。

注意

根據預設，CScript 會在命令提示字元視窗中顯示文稿的輸出。 由於 WMI 命令稿可能會產生大量的輸出，因此您可能會想要將輸出重新導向至檔案。 在命令提示字元中輸入 cscript filename.vbs > outfile.txt，將 filename.vbs 腳本的輸出重新導向至 outfile.txt。

下表列出可用來從本機計算機取得各種數據類型的腳本範例。

如何... WMI 類別或方法
...判斷是否已在電腦上安裝服務包？ 使用 Win32_OperatingSystem 類別，並檢查 ServicePackMajorVersion 和 ServicePackMinorVersion 屬性的值。
VB 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colOperatingSystems = objWMIService.ExecQuery ("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colOperatingSystems
    Wscript.Echo objOperatingSystem.ServicePackMajorVersion & "." & objOperatingSystem.ServicePackMinorVersion
Next
PowerShell 
Get-WmiObject -Class Win32_OperatingSystem -Namespace "root\cimv2" | `
   format-list ServicePackMajorVersion, ServicePackMinorVersion
如何判斷電腦上安裝作業系統的時間？

使用 Win32_OperatingSystem 類別和 InstallDate 屬性。

VB 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colOperatingSystems = objWMIService.ExecQuery ("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colOperatingSystems
    Wscript.Echo "Install Date: " & objOperatingSystem.InstallDate 
Next
PowerShell 
Get-WmiObject -Class Win32_OperatingSystem -Namespace "root\cimv2" | format-list InstallDate
...判斷電腦上安裝哪個版本的 Windows作系統？

使用 Win32_OperatingSystem 類別，並擷取 Name 和 Version 屬性。

VB 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colOperatingSystems = objWMIService.ExecQuery ("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colOperatingSystems
    Wscript.Echo objOperatingSystem.Caption & "  " & objOperatingSystem.Version
Next
PowerShell 
Get-WmiObject -Class Win32_OperatingSystem -Namespace "root\cimv2" | format-list Caption, Version
...判斷電腦上的哪一個是 Windows 資料夾（%Windir%）？

使用 Win32_OperatingSystem 類別，並檢查 WindowsDirectory 屬性的值。

VB 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colOperatingSystems = objWMIService.ExecQuery ("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colOperatingSystems
    Wscript.Echo "Windows Folder: " & objOperatingSystem.WindowsDirectory
Next
PowerShell 
Get-WmiObject -Class Win32_OperatingSystem -Namespace "root\cimv2" | format-list WindowsDirectory
...判斷電腦上已安裝哪些 Hotfix？

使用 Win32_QuickFixEngineering 類別。

VB 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colQuickFixes = objWMIService.ExecQuery ("Select * from Win32_QuickFixEngineering")
For Each objQuickFix in colQuickFixes
    Wscript.Echo "Description: " & objQuickFix.Description
    Wscript.Echo "Hotfix ID: " & objQuickFix.HotFixID
Next
PowerShell 
Get-WmiObject -Class Win32_QuickFixEngineering -Namespace "root\cimv2" | format-list Description, HotFixIDs
...判斷是否需要在電腦上啟用作業系統？

使用 Win32_WindowsProductActivation 類別，並檢查 ActivationRequired 屬性的值。

VB 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colWPA = objWMIService.ExecQuery ("Select * from Win32_WindowsProductActivation")
For Each objWPA in colWPA
    Wscript.Echo "Activation Required: " & objWPA.ActivationRequired
    Wscript.Echo "Remaining Evaluation Period: " & objWPA.RemainingEvaluationPeriod
    Wscript.Echo "Remaining Grace Period: " & objWPA.RemainingGracePeriod
Next
PowerShell 
Get-WmiObject -Class Win32_WindowsProductActivation -computer "." -Namespace "root\cimv2" | `
     format-list ActivationRequired, RemainingEvaluationPeriod, RemainingGracePeriod

文稿和應用程式的 WMI 工作

WMI C++應用程式範例

TechNet ScriptCenter

  • Last updated on