Schnellstart: Erstellen einer Speicheraufgabe mit Bicep

In dieser Schnellstartanleitung wird beschrieben, wie Sie mithilfe von Bicep eine Speicheraufgabe erstellen.

Bicep ist eine domänenspezifische Sprache (Domain-Specific Language, DSL), die eine deklarative Syntax zur Bereitstellung von Azure-Ressourcen verwendet. Sie bietet eine präzise Syntax, zuverlässige Typsicherheit und Unterstützung für die Wiederverwendung von Code. Bicep bietet die beste Entwicklungserfahrung für Ihre Infrastructure-as-Code-Lösungen in Azure.

Voraussetzungen

Wenn Sie noch kein Azure-Abonnement haben, erstellen Sie ein kostenloses Konto, bevor Sie beginnen.

Überprüfen der Bicep-Datei

Die in dieser Schnellstartanleitung verwendete Bicep-Datei stammt aus den Azure-Schnellstartvorlagen.

@sys.description('The name of storage task.')
@minLength(3)
@maxLength(18)
param storageTaskName string

@sys.description('A description of the storage task.')
param description string

@sys.description('The region in which to create the storage task.')
param location string = resourceGroup().location

@sys.description('Locks the file for one day.')
param lockedUntilDate string = dateTimeAdd(utcNow(), 'P1D')

resource storageTask 'Microsoft.StorageActions/storageTasks@2023-01-01' = {
  name: storageTaskName
  location: location
  identity: {
    type: 'SystemAssigned'
  }
  properties: {
    action: {
      if: {
        condition: '[[endsWith(Name, \'.docx\')]]'
        operations: [
         {
            name: 'SetBlobImmutabilityPolicy'
            onSuccess: 'continue'
            onFailure: 'break'
            parameters: {
              untilDate: lockedUntilDate
              mode: 'locked'
            }
         }
         {
            name: 'SetBlobTags'
            onSuccess: 'continue'
            onFailure: 'break'
            parameters: {
                tagsetImmutabilityUpdatedBy: 'StorageTaskQuickstart'
            }     
         }
        ]
      }

    }
    description: description
    enabled: true
  }
}

Die Azure-Ressource "Microsoft.StorageActions/storageTasks " wird in der Bicep-Datei definiert.

Bereitstellen der Bicep-Datei

1. Speichern Sie die Bicep-Datei als main.bicep auf Ihrem lokalen Computer.

2. Stellen Sie die Bicep-Datei entweder mit Azure CLI oder mit Azure PowerShell bereit.

az group create --name exampleRG --location <region>

az deployment group create --resource-group exampleRG --template-file main.bicep --parameters storageTaskName="<storage-task-name>" description="<description>" 

New-AzResourceGroup -Name exampleRG -Location <region>

New-AzResourceGroupDeployment -ResourceGroupName exampleRG -TemplateFile ./main.bicep -storageTaskName "<storage-task-name>" -description "<description>"

Überprüfen der bereitgestellten Ressourcen

1. Suchen Sie im Azure-Portal nach Speicheraufgaben. Wählen Sie dann unter Dienste die Option Speicheraufgaben – Azure Speichervorgänge aus.

2. Suchen Sie in der Liste der Speicheraufgaben nach dem Namen der von Ihnen bereitgestellten Speicheraufgabe.

   

Bereinigen von Ressourcen

Wenn sie nicht mehr benötigt wird, löschen Sie die Ressourcengruppe. Die Ressourcengruppe und alle Ressourcen in der Ressourcengruppe werden gelöscht. Verwenden Sie den folgenden Befehl, um die Ressourcengruppe und alle enthaltenen Ressourcen zu löschen.

az group delete --name <resource-group-name>

Remove-AzResourceGroup -Name <resource-group-name>

Ersetzen Sie <resource-group-name> durch den Namen Ihrer Ressourcengruppe.

Nächste Schritte

Weisen Sie einem Speicherkonto eine Speicheraufgabe zu.