Freigeben über

DBEngine.CreateWorkspace-Methode (DAO)

Gilt für: Access 2013, Office 2013

Erstellt ein neues Workspace -Objekt.

Syntax

Ausdruck . CreateWorkspace(Name, UserName, Password, UseType)

Ausdruck Eine Variable, die ein DBEngine-Objekt darstellt.

Parameter

Name

Erforderlich/optional

Datentyp

Beschreibung

Name

Erforderlich

String

Ein String-Wert, das das neue Workspace-Objekt eindeutig benennt. Weitere Informationen zu gültigen Arbeitsbereichsnamen finden Sie in der Name-Eigenschaft.

UserName

Erforderlich

String

Ein String -Wert, der den Besitzer des neuen Workspace -Objekts angibt. Weitere Informationen finden Sie im Thema zur UserName -Eigenschaft.

Password

Erforderlich

String

Eine Zeichenfolge, die das Kennwort für das neue Arbeitsbereich -Objekt enthält. Das Kennwort kann bis zu 20 Zeichen lang und alle beliebigen Zeichen außer ASCII-Zeichen 0 (Null) enthalten.

HINWEIS: Verwenden Sie sichere Kennwörter, die Groß- und Kleinbuchstaben, Zahlen und Symbole kombinieren. Unsichere Kennwörter enthalten keine Kombination dieser Elemente. Sicheres Kennwort: Y6dh!et5. Unsicheres Kennwort: Haus27. Use a strong password that you can remember so that you don't have to write it down.

UseType

Optional

Variant

Einer der WorkspaceTypeEnum -Werte.

HINWEIS: ODBCDirect-Arbeitsbereiche werden in Microsoft Access 2013 nicht unterstützt. Verwenden Sie ADO, wenn Sie auf externe Datenquellen zugreifen möchten, ohne das Microsoft Access-Datenbankmodul zu verwenden.

Rückgabewert

Arbeitsbereich

Hinweise

Wenn Sie mithilfe der CreateWorkspace-Methode ein neues Workspace-Objekt erstellen, wird eine Workspace-Sitzung gestartet, und Sie können in der Anwendung auf das Workspace-Objekt verweisen.

Arbeitsbereichsobjekte sind nicht dauerhaft, und Sie können sie nicht auf einem Datenträger speichern. Nachdem Sie ein Workspace-Objekt erstellt haben, können Sie keine seiner Eigenschafteneinstellungen ändern, mit Ausnahme der Name-Eigenschaft , die Sie ändern können, bevor Sie das Workspace-Objekt an die Workspaces-Auflistung anfügen.

Es ist nicht erforderlich, das neue Workspace -Objekt an eine Auflistung anzufügen, um es verwenden zu können. Ein neu erstelltes Workspace -Objekt fügen Sie nur dann an, wenn Sie über die Workspaces -Auflistung darauf verweisen müssen.

Wenn Sie ein Workspace -Objekt aus der Workspaces -Auflistung entfernen möchten, schließen Sie alle geöffneten Datenbanken und Verbindungen. Wenden Sie anschließend die Close -Methode auf das Workspace -Objekt an.

Beispiel

In diesem Beispiel wird die CreateWorkspace-Methode verwendet, um einen Microsoft Access-Arbeitsbereich zu erstellen. Danach werden die Eigenschaften des Arbeitsbereichs aufgelistet.

Sub CreateWorkspaceX() 
 
   Dim wrkAcc As Workspace 
   Dim wrkLoop As Workspace 
   Dim prpLoop As Property 
 
   DefaultType = dbUseJet 
   ' Create an unnamed Workspace object of the type  
   ' specified by the DefaultType property of DBEngine  
   ' (dbUseJet). 
   Set wrkAcc = CreateWorkspace("", "admin", "") 
 
   ' Enumerate Workspaces collection. 
   Debug.Print "Workspace objects in Workspaces collection:" 
   For Each wrkLoop In Workspaces 
      Debug.Print "  " & wrkLoop.Name 
   Next wrkLoop 
 
   With wrkAcc 
      ' Enumerate Properties collection of Microsoft Access  
      ' workspace. 
      Debug.Print _ 
         "Properties of unnamed Microsoft Access workspace" 
      On Error Resume Next 
      For Each prpLoop In .Properties 
         Debug.Print "  " & prpLoop.Name & " = " & prpLoop 
      Next prpLoop 
      On Error GoTo 0 
   End With 
 
   wrkAcc.Close 
 
End Sub
  • Last updated on