Workspaces-Sammlung (DAO)

Gilt für: Access 2013, Office 2013

Eine Workspaces-Auflistung enthält alle aktiven, nicht ausgeblendeten Workspace-Objekte des DBEngine-Objekts. (Ausgeblendete Workspace-Objekte werden nicht an die Auflistung angefügt, und auf sie wird nicht durch die Variable verwiesen, der sie zugeordnet sind.)

Hinweise

Verwenden Sie das Workspace-Objekt, um die aktuelle Sitzung zu verwalten oder eine zusätzliche Sitzung zu starten.

Wenn Sie zunächst auf ein Arbeitsbereichsobjekt verweisen oder es verwenden, erstellen Sie automatisch den Standardarbeitsbereich, DBEngine.Workspaces(0). The settings of the Name and UserName properties of the default workspace are "#Default Workspace#" and "Admin," respectively. If security is enabled, the UserName property setting is the name of the user who logged on.

Sie können mit der CreateWorkspace -Methode neue Workspace-Objekte erstellen. Wenn Sie ein neues Workspace-Objekt erstellt haben, müssen Sie es an die Workspaces-Auflistung anfügen, um von der Workspaces-Auflistung auf dieses Objekt verweisen zu können. Sie können ein neu erstelltes Workspace-Objekt jedoch auch verwenden, ohne es an die Workspaces-Auflistung anzufügen.

Um auf ein Arbeitsbereichsobjekt in einer Auflistung durch die Ordinalzahl oder die Name-Eigenschaftseinstellung zu verweisen, verwenden Sie eine der folgenden Syntaxformen:

DBEngine.Arbeitsbereiche(0)

DBEngine.Arbeitsbereiche(„name“)

DBEngine. Arbeitsbereiche! [Name]

Beispiel

In diesem Beispiel werden ein neues Microsoft Access Workspace-Objekt erstellt und dann an die Workspaces-Auflistung angefügt. Anschließend werden die Arbeitsbereichs auflistungen und die Eigenschafts auflistung des Arbeitsbereichs objekts aufgezählt.

Sub WorkspaceX() 
 
 Dim wrkNewAcc As Workspace 
 Dim wrkLoop As Workspace 
 Dim prpLoop As Property 
 
 ' Create a new Microsoft Access workspace. 
 Set wrkNewAcc = CreateWorkspace("NewAccessWorkspace", _ 
 "admin", "", dbUseJet) 
 Workspaces.Append wrkNewAcc 
 
 ' Enumerate the Workspaces collection. 
 For Each wrkLoop In Workspaces 
 With wrkLoop 
 Debug.Print "Properties of " & .Name 
 ' Enumerate the Properties collection of the new 
 ' Workspace object. 
 For Each prpLoop In .Properties 
 On Error Resume Next 
 If prpLoop <> "" Then Debug.Print " " & _ 
 prpLoop.Name & " = " & prpLoop 
 On Error GoTo 0 
 Next prpLoop 
 End With 
 Next wrkLoop 
 
 wrkNewAcc.Close 
End Sub 

In diesem Beispiel wird die CreateWorkspace -Methode verwendet, um einen Microsoft Access-Arbeitsbereich zu erstellen. Danach werden die Eigenschaften des Arbeitsbereichs aufgelistet.

Sub CreateWorkspaceX() 
 
 Dim wrkAcc As Workspace 
 Dim wrkLoop As Workspace 
 Dim prpLoop As Property 
 
 
 DefaultType = dbUseJet 
 ' Create an unnamed Workspace object of the type 
 ' specified by the DefaultType property of DBEngine 
 ' (dbUseJet). 
 Set wrkAcc = CreateWorkspace("", "admin", "") 
 
 ' Enumerate Workspaces collection. 
 Debug.Print "Workspace objects in Workspaces collection:" 
 For Each wrkLoop In Workspaces 
 Debug.Print " " & wrkLoop.Name 
 Next wrkLoop 
 
 With wrkAcc 
 ' Enumerate Properties collection of Microsoft Access 
 ' workspace. 
 Debug.Print _ 
 "Properties of unnamed Microsoft Access workspace" 
 On Error Resume Next 
 For Each prpLoop In .Properties 
 Debug.Print " " & prpLoop.Name & " = " & prpLoop 
 Next prpLoop 
 On Error GoTo 0 
 End With 
 
 wrkAcc.Close 
 
End Sub