Enumerator-Objekt

Stellt einen Datenstrom mit Ergebnissen dar, die von Vorgängen zurückgegeben werden, z. B. einem Pullvorgang. Beispielsweise gibt die Session.Enumerate-Methode mehrere Ergebnisse zurück.

Member

Das Enumerator-Objekt verfügt über folgende Membertypen:

• Methoden
• Eigenschaften

Methoden

Das Enumerator-Objekt verfügt über diese Methoden.

Eigenschaften

Das Enumerator-Objekt verfügt über diese Eigenschaften.

Bemerkungen

Verwenden Sie Session.Enumerate, um eine Enumeration zu starten. Verwenden Sie Enumerator.ReadItem, um einen WS-Enumeration:Pull-Vorgang auszuführen, der das Lesen von Elementen in der Enumeration fortsetzt.

Das Enumerator-Objekt entspricht der IWSManEnumerator-Schnittstelle .

Beispiele

Im folgenden VBScript-Codebeispiel werden alle Datenträger auf einem Remotecomputer aufgelistet, die durch den vollqualifizierten Domänennamen (servername.domain.com) angegeben werden. Die DisplayOutput-Unterroutine formatiert die Datenausgabe auf die gleiche Weise wie das Tool WinRM.cmd.

Option Explicit

Const RemoteComputer = "MIG50-64D.mig.net"

Dim objWsman, objSession, strResource
Dim objResultSet

Set objWsman = CreateObject( "WSMan.Automation" )
Set objSession = objWsman.CreateSession( "https://" _
    & RemoteComputer )
strResource = "http://schemas.microsoft.com/wbem/wsman/1/" _
     & "wmi/root/cimv2/Win32_OperatingSystem"
Dim iFlag
iFlag = objWsman.EnumerationFlagReturnObjectAndEPR or _
    objWsman.EnumerationFlagHierarchyDeep
Set objResultSet = _
    objSession.Enumerate( strResource, "", "",  iFlag)
While Not objResultSet.AtEndOfStream
    DisplayOutput( objResultSet.ReadItem ) 
Wend


'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

Anforderungen

Siehe auch

WinRM-Skript-API

Auflisten oder Auflisten aller Instanzen einer Ressource

Skripterstellung in der Windows-Remoteverwaltung