Enumerator.ReadItem-Methode

Ruft ein Element aus der Ressource ab und gibt eine XML-Darstellung des Elements zurück.

Syntax

Enumerator.ReadItem( _
  ByVal resource _
)

Parameter

resource

Der URI des Elements.

Rückgabewert

Die XML-Darstellung des Elements.

Bemerkungen

Legen Sie die Session.BatchItems-Eigenschaft fest, um die Anzahl der gelesenen Elemente zu begrenzen.

Beachten Sie, dass durch die Freigabe des Enumerationsobjekts alle ausstehenden Enumerationsanforderungen bereinigt werden.

Die Session.Enumerate-Methode ruft eine Auflistung nicht auf die gleiche Weise ab, wie eine WMI-Abfrage, z SELECT * from Win32_LogicalDisk. B. , eine Auflistung in einem SWbemObjectSet zurückgibt. Um eine Datei als Textstream zu lesen, erstellen Sie das TextStream-Skriptobjekt und rufen die TextStream.Readline-Methode auf, um jede Zeile der Datei zu lesen. Auf ähnliche Weise rufen Sie die Session.Enumerate-Methode auf, um ein Enumerator-Objekt abzurufen, und rufen dann die Enumerator.ReadItem-Methode auf. Wie beim Lesen aus der Textdatei können Sie die Enumerator.AtEndOfStream-Eigenschaft überprüfen, um zu überprüfen, ob das Ende der Datenelemente erreicht ist.

Beispiele

Im folgenden VBScript-Beispiel wird die Session.Enumerate-Methode aufgerufen, um eine Liste der geplanten Aufträge abzurufen. Die DisplayOutput-Unterroutine verwendet die XML-Transformationsdatei des Winrm-Befehlszeilentools (WsmTxt.xsl), um die Daten in tabellarischer Form auszugeben.

Const RemoteComputer = "servername.domain.com"

Set objWsman = CreateObject( "WSMan.Automation" )
Set objSession = objWsman.CreateSession( "https://" & RemoteComputer )

strResource = "http://schemas.microsoft.com/wbem/wsman/1/" &_
              "wmi/root/cimv2/Win32_ScheduledJob"

Set objResultSet = objSession.Enumerate( strResource )
NumOfJobs = 0

While Not objResultSet.AtEndOfStream
    NumOfJobs = NumOfJobs + 1
    DisplayOutput( objResultSet.ReadItem ) 
Wend

Wscript.Echo "There are " & NumOfJobs & " jobs scheduled."

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

Anforderungen

Siehe auch

Enumerator

Auflisten oder Auflisten aller Instanzen einer Ressource