Inicio rápido: Creación de una tarea de almacenamiento con Bicep

En este inicio rápido se describe cómo crear una tarea de almacenamiento mediante Bicep.

Bicep es un lenguaje específico de dominio (DSL) que usa una sintaxis declarativa para implementar recursos de Azure. Brinda sintaxis concisa, seguridad de tipos confiable y compatibilidad con la reutilización de código. Bicep ofrece la mejor experiencia de creación para sus soluciones de infraestructura como código en Azure.

Prerrequisitos

Si no tiene una suscripción a Azure, cree una cuenta gratuita antes de empezar.

Revisión del archivo de Bicep

El archivo Bicep utilizado en este inicio rápido proviene de las Plantillas de Inicio Rápido de Azure.

@sys.description('The name of storage task.')
@minLength(3)
@maxLength(18)
param storageTaskName string

@sys.description('A description of the storage task.')
param description string

@sys.description('The region in which to create the storage task.')
param location string = resourceGroup().location

@sys.description('Locks the file for one day.')
param lockedUntilDate string = dateTimeAdd(utcNow(), 'P1D')

resource storageTask 'Microsoft.StorageActions/storageTasks@2023-01-01' = {
  name: storageTaskName
  location: location
  identity: {
    type: 'SystemAssigned'
  }
  properties: {
    action: {
      if: {
        condition: '[[endsWith(Name, \'.docx\')]]'
        operations: [
         {
            name: 'SetBlobImmutabilityPolicy'
            onSuccess: 'continue'
            onFailure: 'break'
            parameters: {
              untilDate: lockedUntilDate
              mode: 'locked'
            }
         }
         {
            name: 'SetBlobTags'
            onSuccess: 'continue'
            onFailure: 'break'
            parameters: {
                tagsetImmutabilityUpdatedBy: 'StorageTaskQuickstart'
            }     
         }
        ]
      }

    }
    description: description
    enabled: true
  }
}

El recurso de Azure Microsoft.StorageActions/storageTasks se define en el archivo Bicep.

Desplegar el archivo Bicep

1. Guarde el archivo de Bicep como main.bicep en el equipo local.

2. Implemente el archivo de Bicep mediante la CLI de Azure o Azure PowerShell.

az group create --name exampleRG --location <region>

az deployment group create --resource-group exampleRG --template-file main.bicep --parameters storageTaskName="<storage-task-name>" description="<description>" 

New-AzResourceGroup -Name exampleRG -Location <region>

New-AzResourceGroupDeployment -ResourceGroupName exampleRG -TemplateFile ./main.bicep -storageTaskName "<storage-task-name>" -description "<description>"

Revisión de los recursos implementados

1. En Azure Portal, busque Tareas de almacenamiento. A continuación, en Servicios, seleccione Tareas de Almacenamiento: Acciones de Azure Storage.

2. En la lista de tareas de almacenamiento, busque el nombre de la tarea de almacenamiento que implementó.

   

Limpieza de recursos

Cuando ya no necesite el grupo de recursos, elimínelo. Se eliminan el grupo de recursos y todos los recursos del grupo de recursos. Use el siguiente comando para eliminar el grupo de recursos y todos sus recursos contenidos.

az group delete --name <resource-group-name>

Remove-AzResourceGroup -Name <resource-group-name>

Reemplace <resource-group-name> por el nombre del grupo de recursos.

Pasos siguientes

Asigne una tarea de almacenamiento a una cuenta de almacenamiento.