Método Selection.Item (Outlook)

Devuelve un encabezado de conversación o elemento de Microsoft Outlook de la selección.

Sintaxis

expresión. Elemento (índice)

expresión Variable que representa un objeto 'Selection'.

Parameters

Valor devuelto

Object que representa el encabezado de conversación o elemento especificado.

Observaciones

No hace ninguna suposición sobre el método Item devolver tipo; el código debe ser capaz de controlar varios tipos de elementos o un objeto ConversationHeader. Por ejemplo, el método Item puede devolver un objeto AppointmentItem, MailItem, MeetingItem o TaskItem en la carpeta Bandeja de entrada, según el valor de la propiedad Selection.Location.

La colección Selection contiene objetos ConversationHeader solamente si especifica olConversationHeaders en el método GetSelection del objeto Selection.

Ejemplo

El siguiente ejemplo de Microsoft Visual Basic para aplicaciones (VBA) se muestra el remitente de cada elemento seleccionado en el explorador activo. Utilizan la propiedad Count y el método Item del objeto Selection, devuelto por la propiedad Explorer.Selection, para mostrar los remitentes de todos los mensajes que están seleccionados en el explorador activo.

Sub GetSelectedItems() 
 Dim myOlExp As Outlook.Explorer 
 Dim myOlSel As Outlook.Selection 
 Dim mySender As Outlook.AddressEntry 
 Dim oMail As Outlook.MailItem 
 Dim oAppt As Outlook.AppointmentItem 
 Dim oPA As Outlook.PropertyAccessor 
 Dim strSenderID As String 
 Const PR_SENT_REPRESENTING_ENTRYID As String = _ 
 "http://schemas.microsoft.com/mapi/proptag/0x00410102" 
 Dim MsgTxt As String 
 Dim x As Long 
 
 MsgTxt = "Senders of selected items:" 
 Set myOlExp = Application.ActiveExplorer 
 Set myOlSel = myOlExp.Selection 
 For x = 1 To myOlSel.Count 
 If myOlSel.Item(x).Class = OlObjectClass.olMail Then 
 ' For mail item, use the SenderName property. 
 Set oMail = myOlSel.Item(x) 
 MsgTxt = MsgTxt & oMail.SenderName & ";" 
 ElseIf myOlSel.Item(x).Class = OlObjectClass.olAppointment Then 
 ' For appointment item, use the Organizer property. 
 Set oAppt = myOlSel.Item(x) 
 MsgTxt = MsgTxt & oAppt.Organizer & ";" 
 Else 
 ' For other items, use the property accessor to get sender ID, 
 ' then get the address entry to display the sender name. 
 Set oPA = myOlSel.Item(x).PropertyAccessor 
 strSenderID = oPA.GetProperty(PR_SENT_REPRESENTING_ENTRYID) 
 Set mySender = Application.Session.GetAddressEntryFromID(strSenderID) 
 MsgTxt = MsgTxt & mySender.Name & ";" 
 End If 
 Next x 
 Debug.Print MsgTxt 
End Sub

Vea también

Objeto Selection

Soporte técnico y comentarios

¿Tiene preguntas o comentarios sobre VBA para Office o esta documentación? Vea Soporte técnico y comentarios sobre VBA para Office para obtener ayuda sobre las formas en las que puede recibir soporte técnico y enviar comentarios.