Déployer un compte Azure Batch et deux pools ـ Terraform

Dans ce guide de démarrage rapide, vous créez un compte Azure Batch, un compte stockage Azure et deux pools Batch à l’aide de Terraform. Batch est un service de planification de travaux informatiques qui parallélise et distribue le traitement de grands volumes de données sur de nombreux ordinateurs. Il est généralement utilisé pour les balayages paramétriques, les simulations Monte Carlo, la modélisation des risques financiers et d’autres applications informatiques hautes performances. Un compte Batch est la ressource de niveau supérieur dans le service Batch qui fournit l’accès aux pools, aux travaux et aux tâches. Le compte de stockage est utilisé pour stocker et gérer tous les fichiers utilisés et générés par le service Batch, tandis que les deux pools Batch sont des collections de nœuds de calcul qui exécutent les tâches.

Terraform active la définition, la préversion et le déploiement de l’infrastructure cloud. À l’aide de Terraform, vous créez des fichiers de configuration à l’aide de la syntaxe HCL. La syntaxe HCL vous permet de spécifier un fournisseur de services cloud, tel qu’Azure, et les éléments qui composent votre infrastructure cloud. Après avoir créé vos fichiers de configuration, vous créez un plan d’exécution qui vous permet d’afficher un aperçu des modifications de votre infrastructure avant leur déploiement. Une fois que vous avez vérifié les modifications, vous appliquez le plan d’exécution pour déployer l’infrastructure.

Prérequis

• Créer un compte Azure avec un abonnement actif. Vous pouvez créer gratuitement un compte.
• Installez et configurez Terraform.

Implémenter le code Terraform

1. Créez un répertoire dans lequel tester et exécuter l’exemple de code Terraform, et définissez-le en tant que répertoire actif.

2. Créez un fichier nommé main.tf et insérez le code suivant :

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   resource "random_string" "storage_account_name" {
     length  = 8
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_storage_account" "example" {
     name                     = random_string.storage_account_name.result
     resource_group_name      = azurerm_resource_group.rg.name
     location                 = azurerm_resource_group.rg.location
     account_tier             = "Standard"
     account_replication_type = "LRS"
   }
   
   resource "random_string" "batch_account_name" {
     length  = 8
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_batch_account" "example" {
     name                                = random_string.batch_account_name.result
     resource_group_name                 = azurerm_resource_group.rg.name
     location                            = azurerm_resource_group.rg.location
     storage_account_id                  = azurerm_storage_account.example.id
     storage_account_authentication_mode = "StorageKeys"
   }
   
   resource "random_pet" "azurerm_batch_pool_name" {
     prefix = "pool"
   }
   
   resource "azurerm_batch_pool" "fixed" {
     name                = "${random_pet.azurerm_batch_pool_name.id}-fixed-pool"
     resource_group_name = azurerm_resource_group.rg.name
     account_name        = azurerm_batch_account.example.name
     display_name        = "Fixed Scale Pool"
     vm_size             = "Standard_A1"
     node_agent_sku_id   = "batch.node.ubuntu 22.04"
   
     fixed_scale {
       target_dedicated_nodes = 2
       resize_timeout         = "PT15M"
     }
   
     storage_image_reference {
       publisher = "Canonical"
       offer     = "0001-com-ubuntu-server-jammy"
       sku       = "22_04-lts"
       version   = "latest"
     }
   
     start_task {
       command_line       = "echo 'Hello World from $env'"
       task_retry_maximum = 1
       wait_for_success   = true
   
       common_environment_properties = {
         env = "TEST"
       }
   
       user_identity {
         auto_user {
           elevation_level = "NonAdmin"
           scope           = "Task"
         }
       }
     }
   
     metadata = {
       "tagName" = "Example tag"
     }
   }
   
   resource "azurerm_batch_pool" "autopool" {
     name                = "${random_pet.azurerm_batch_pool_name.id}-autoscale-pool"
     resource_group_name = azurerm_resource_group.rg.name
     account_name        = azurerm_batch_account.example.name
     display_name        = "Auto Scale Pool"
     vm_size             = "Standard_A1"
     node_agent_sku_id   = "batch.node.ubuntu 22.04"
   
     auto_scale {
       evaluation_interval = "PT15M"
   
       formula = <<EOF
         startingNumberOfVMs = 1;
         maxNumberofVMs = 25;
         pendingTaskSamplePercent = $PendingTasks.GetSamplePercent(180 * TimeInterval_Second);
         pendingTaskSamples = pendingTaskSamplePercent < 70 ? startingNumberOfVMs : avg($PendingTasks.GetSample(180 * TimeInterval_Second));
         $TargetDedicatedNodes=min(maxNumberofVMs, pendingTaskSamples);
   EOF
     }
   
     storage_image_reference {
       publisher = "Canonical"
       offer     = "0001-com-ubuntu-server-jammy"
       sku       = "22_04-lts"
       version   = "latest"
     }
   }
   

3. Créez un fichier nommé outputs.tf et insérez le code suivant :

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "storage_account_name" {
     value = azurerm_storage_account.example.name
   }
   
   output "batch_account_name" {
     value = azurerm_batch_account.example.name
   }
   
   output "batch_pool_fixed_name" {
     value = azurerm_batch_pool.fixed.name
   }
   
   output "batch_pool_autopool_name" {
     value = azurerm_batch_pool.autopool.name
   }
   

4. Créez un fichier nommé providers.tf et insérez le code suivant :

   terraform {
     required_version = ">=1.0"
   
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

5. Créez un fichier nommé variables.tf et insérez le code suivant :

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location of the resource group."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   

Initialiser Terraform

Exécutez terraform init pour initialiser le déploiement Terraform. Cette commande télécharge le fournisseur Azure à utiliser pour la gestion de vos ressources Azure.

terraform init -upgrade

Points clés :

• Le paramètre -upgrade met à niveau les plug-ins de fournisseur nécessaires vers la version la plus récente qui est conforme aux contraintes de version de la configuration.

Créer un plan d’exécution Terraform

Exécutez le plan terraform pour créer un plan d’exécution.

terraform plan -out main.tfplan

Points clés :

• La commande terraform plan crée un plan d’exécution, mais ne l’exécute pas. Au lieu de cela, elle détermine les actions nécessaires pour créer la configuration spécifiée dans vos fichiers de configuration. Ce modèle vous permet de vérifier si le plan d’exécution répond à vos attentes avant d’apporter des modifications aux ressources réelles.
• Le paramètre facultatif -out vous permet de spécifier un fichier de sortie pour le plan. L’utilisation du paramètre -out garantit que le plan que vous avez examiné correspond exactement à ce qui est appliqué.

Appliquer un plan d’exécution Terraform

Exécutez terraform pour appliquer le plan d’exécution à votre infrastructure cloud.

terraform apply main.tfplan

Points clés :

• La commande exemple terraform apply part du principe que vous avez préalablement exécuté terraform plan -out main.tfplan.
• Si vous avez spécifié un autre nom de fichier pour le paramètre -out, utilisez ce même nom dans l’appel à terraform apply.
• Si vous n’avez pas utilisé le paramètre -out, appelez terraform apply sans aucun paramètre.

Vérifier les résultats

az batch account show --name <batch_account_name> --resource-group <resource_group_name>

Nettoyer les ressources

Quand vous n’avez plus besoin des ressources créées par le biais de Terraform, effectuez les étapes suivantes :

1. Exécutez terraform plan et spécifiez le drapeau destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Points clés :

   • La commande terraform plan crée un plan d’exécution, mais ne l’exécute pas. Au lieu de cela, elle détermine les actions nécessaires pour créer la configuration spécifiée dans vos fichiers de configuration. Ce modèle vous permet de vérifier si le plan d’exécution répond à vos attentes avant d’apporter des modifications aux ressources réelles.
   • Le paramètre facultatif -out vous permet de spécifier un fichier de sortie pour le plan. L’utilisation du paramètre -out garantit que le plan que vous avez examiné correspond exactement à ce qui est appliqué.

2. Exécutez terraform apply pour appliquer le plan d’exécution.

   terraform apply main.destroy.tfplan
   

Résoudre les problèmes liés à Terraform sur Azure

Résolvez les problèmes courants lors de l’utilisation de Terraform sur Azure.

Étapes suivantes