Propriété Shape.RowType (Visio)

Récupère ou définit le type d'une ligne dans une section de feuille ShapeSheet Geometry, Connection Points, Controls ou Tabs. Lecture-écriture.

Syntaxe

expression. RowType (Section, Row)

expression Une variable qui représente uneForme d’objet.

Paramètres

Valeur renvoyée

Entier

Remarques

Après avoir changé le type d'une ligne, le nouveau type de ligne peut avoir ou non les mêmes cellules. Votre programme doit fournir les formules appropriées pour les nouvelles cellules ou les cellules modifiées.

Vous pouvez spécifier le type de ligne souhaité en définissant RowType égal à l'une des constantes suivantes déclarées par la bibliothèque de types de Visio dans le membre VisRowTags.

Si une étiquette de ligne incorrecte est transmise ou si la ligne n'existe pas, aucune modification n'est effectuée et une erreur est renvoyée.

Utilisez la propriété RowName pour transformer les lignes Points de connexion non nommées en lignes nommées.

Consultez VisRowIndices pour obtenir la liste des constantes de ligne valides et VisRowTags pour obtenir la liste des constantes de balise de ligne valides.

Consultez VisSectionIndices pour obtenir la liste des constantes de section valides.

Exemple

Cette macro Microsoft Visual Basic pour Applications (VBA) illustre l'utilisation de la propriété RowType pour modifier le type d'une ligne ShapeSheet. Elle dessine un rectangle sur une page et courbe ses traits jusqu'à ce qu'ils deviennent des arcs. C'est possible en changeant les types de ligne ShapeSheet de chaque côté du rectangle afin qu'elles passent de LineTo à ArcTo et en changeant ensuite les valeurs des cellules X et Y dans chacune de ces cellules.

 
Public Sub RowType_Example() 
 
 Dim vsoPage As Visio.Page 
 Dim vsoShape As Visio.Shape 
 Dim vsoCell As Visio.Cell 
 Dim strBowCell As String 
 Dim strBowFormula As String 
 Dim intCounter As Integer 
 
 'Set the value of the strBowCell string. 
 strBowCell = "Scratch.X1" 
 
 'Set the value of the strBowFormula string. 
 strBowFormula = "=Min(Width, Height) / 5" 
 Set vsoPage = ActivePage 
 
 'If there isn't an active page, set vsoPage 
 'to the first page of the active document. 
 If vsoPage Is Nothing Then 
 
 Set vsoPage = ActiveDocument.Pages(1) 
 
 End If 
 
 'Draw a rectangle on the active page. 
 Set vsoShape = vsoPage.DrawRectangle(1, 5, 5, 1) 
 
 'Add a scratch section and add a row to the scratch section. 
 vsoShape.AddSection visSectionScratch 
 vsoShape.AddRow visSectionScratch, visRowScratch, 0 
 
 'Set vsoCell to the Scratch.X1 cell and set its formula. 
 Set vsoCell = vsoShape.Cells(strBowCell) 
 vsoCell.formula = strBowFormula 
 
 'Bow in or curve the rectangle's lines by changing 
 'each row type from LineTo to ArcTo and entering the bow value. 
 For intCounter = 1 To 4 
 
 vsoShape.RowType(visSectionFirstComponent, visRowVertex + intCounter) = visTagArcTo 
 Set vsoCell = vsoShape.CellsSRC(visSectionFirstComponent, visRowVertex + intCounter, 2) 
 vsoCell.formula = "-" & strBowCell 
 
 Next intCounter 
 
End Sub

Assistance et commentaires

Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.