Wizualizacje specyficzne dla pulpitu nawigacyjnego

Wszystkie wizualizacje utworzone w kontekście operatora renderowania są dostępne w wizualizacjach pulpitu nawigacyjnego. Jednak poniższe wizualizacje są dostępne tylko w pulpitach nawigacyjnych usługi Azure Data Explorer, pulpitach nawigacyjnych w czasie rzeczywistym lub internetowym interfejsie użytkownika usługi Azure Data Explorer, a nie w przypadku operatora renderowania.

Aby dowiedzieć się, jak dostosować dowolne wizualizacje pulpitu nawigacyjnego, zobacz Dostosowywanie wizualizacji pulpitu nawigacyjnego usługi Azure Data Explorer

Aby uzyskać ogólne informacje na temat pulpitów nawigacyjnych w usłudze Azure Data Explorer, zobacz Wizualizowanie danych za pomocą pulpitów nawigacyjnych usługi Azure Data Explorer.

Wykres lejkowy

Wykres lejkowy wizualizuje proces liniowy, który ma sekwencyjne, połączone etapy. Każdy etap lejka reprezentuje procent sumy. W większości przypadków wykres lejkowy ma kształt lejka, a pierwszy etap jest największy, a każdy kolejny etap jest mniejszy niż jego poprzednik.

Poniższy przykład wizualizuje postęp żądań serwera, pokazując całkowitą liczbę sesji, żądań i ich stanu ukończenia. Podkreśla spadek liczby od sesji do żądań oraz proporcję ukończonych i niekompletnych żądań.

Przykład kwerendy

let stageOrder = datatable(Stage:string, Order:int)
[
    "session_id", 1,
    "request_id", 2,
    "Completed", 3,
    "Incomplete", 4
];

let base = TransformedServerMetrics
| where MetricType == "sqlserver_requests";

// Build the funnel table dynamically
let funnelData = 
    union 
    (base | where SQLMetrics == "session_id" | summarize Count = count() | extend Stage = "session_id"),
    (base | where SQLMetrics == "request_id" | summarize Count = count() | extend Stage = "request_id"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value == 100) | extend Stage = "Completed"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value < 100) | extend Stage = "Incomplete");

// Join with stage order and order properly
funnelData
| join kind=inner stageOrder on Stage
| order by Order asc
| project Stage, Count

Mapa cieplna

Mapa cieplna przedstawia wartości głównej zmiennej zainteresowania między dwiema zmiennymi osi jako siatką kolorowych kwadratów.

Aby renderować mapę cieplną, zapytanie musi wygenerować tabelę z trzema kolumnami. Dane używane dla pola wartości muszą być liczbowe. Kolumny, które będą używane dla wartości x i y, używają następujących reguł:

• Jeśli wartości w kolumnie x są w string formacie, wartości w kolumnie y również muszą być w string formacie.
• Jeśli wartości w kolumnie x są w datetime formacie, wartości w kolumnie y muszą być liczbowe.

Poniższy przykład przedstawia rozkład pięciu najczęściej występujących metryk SQL w różnych typach metryk. Wyróżnia on, które typy metryk są najbardziej typowe dla każdej metryki SQL, co ułatwia identyfikowanie wzorców aktywności w najważniejszych metrykach.

Przykład kwerendy

let topMetrics = TransformedServerMetrics
| summarize TotalCount = count() by SQLMetrics
| top 5 by TotalCount;  // pick only the 5 most common metrics

TransformedServerMetrics
| where SQLMetrics in (topMetrics | project SQLMetrics)
| summarize Count = count() by SQLMetrics, MetricType
| project X = MetricType, Y = SQLMetrics, Value = Count