operador make-series

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Crie uma série de valores agregados especificados ao longo de um eixo especificado.

Sintaxe

T| make-series [MakeSeriesParameters] [Coluna=] Agregação [default=DefaultValue] [, ...] onAxisColumn [frominício] [tofim] stepetapa [by [Coluna=] GroupExpression [, ...]]

Saiba mais sobre as convenções de sintaxe.

Parâmetros

Parâmetros de série make com suporte

Sintaxe alternativa

T| make-series [Coluna=] Agregação [default=DefaultValue] [, ...] onAxisColumninrange(início,fim,etapa) [by [Coluna=] GroupExpression [, ...]]

A série gerada com a sintaxe alternativa difere da sintaxe principal em dois aspectos:

• O valor de fim é inclusivo.
• O binning do eixo de índice é gerado com bin() e não bin_at(), o que significa que o início pode não ser incluído na série gerada.

Recomendamos que você use a sintaxe principal da make-series e não a sintaxe alternativa.

Retornos

As linhas de entrada são organizadas em grupos com os mesmos valores que as expressões by e a expressão bin_at(AxisColumn,etapa,início). Em seguida, as funções de agregação especificadas são calculadas sobre cada grupo, produzindo uma linha para cada grupo. O resultado contém as colunas by e AxisColumn e pelo menos uma coluna para cada agregação calculada. (Não há suporte para a agregação de várias colunas ou resultados não numéricos.)

Esse resultado intermediário tem tantas linhas quanto há combinações distintas de by e valores de bin_at(AxisColumn,etapa,início).

Por fim, as linhas do resultado intermediário organizadas em grupos que têm os mesmos valores que as expressões by e todos os valores agregados são organizados em matrizes (valores do tipo dynamic). Para cada agregação, há uma coluna contendo sua matriz com o mesmo nome. A última coluna é uma matriz que contém os valores de AxisColumn compartimentalizados de acordo com a etapaespecificada.

Lista de funções de agregação

Lista de funções de análise de série

Para obter uma lista completa de funções de análise de série, confira: Funções de processamento de série

Lista de funções de interpolação de séries

• Observação: Por padrão, as funções de interpolação pressupõem null como um valor ausente. Portanto, especifique default=double(null) em make-series se você pretende usar funções de interpolação para a série.

Exemplos

Uma tabela que mostra as matrizes dos números e os preços médios de cada fruta de cada fornecedor, ordenados pelo carimbo de data/hora com o intervalo especificado. Há uma linha na saída para cada combinação distinta de frutas e fornecedor. As colunas de saída mostram a fruta, o fornecedor e as matrizes de: contagem, média e a linha do tempo inteira (de 01/01/2016 até 10/01/2016). Todas as matrizes são classificadas pelo respectivo carimbo de data/hora e todas as lacunas são preenchidas com valores padrão (0 neste exemplo). Todas as outras colunas de entrada são ignoradas.

T | make-series PriceAvg=avg(Price) default=0
on Purchase from datetime(2016-09-10) to datetime(2016-09-13) step 1d by Supplier, Fruit

let data=datatable(timestamp:datetime, metric: real)
[
  datetime(2016-12-31T06:00), 50,
  datetime(2017-01-01), 4,
  datetime(2017-01-02), 3,
  datetime(2017-01-03), 4,
  datetime(2017-01-03T03:00), 6,
  datetime(2017-01-05), 8,
  datetime(2017-01-05T13:40), 13,
  datetime(2017-01-06), 4,
  datetime(2017-01-07), 3,
  datetime(2017-01-08), 8,
  datetime(2017-01-08T21:00), 8,
  datetime(2017-01-09), 2,
  datetime(2017-01-09T12:00), 11,
  datetime(2017-01-10T05:00), 5,
];
let interval = 1d;
let stime = datetime(2017-01-01);
let etime = datetime(2017-01-10);
data
| make-series avg(metric) on timestamp from stime to etime step interval 

Quando a entrada de make-series estiver vazia, o comportamento padrão de make-series produzirá um resultado vazio.

let data=datatable(timestamp:datetime, metric: real)
[
  datetime(2016-12-31T06:00), 50,
  datetime(2017-01-01), 4,
  datetime(2017-01-02), 3,
  datetime(2017-01-03), 4,
  datetime(2017-01-03T03:00), 6,
  datetime(2017-01-05), 8,
  datetime(2017-01-05T13:40), 13,
  datetime(2017-01-06), 4,
  datetime(2017-01-07), 3,
  datetime(2017-01-08), 8,
  datetime(2017-01-08T21:00), 8,
  datetime(2017-01-09), 2,
  datetime(2017-01-09T12:00), 11,
  datetime(2017-01-10T05:00), 5,
];
let interval = 1d;
let stime = datetime(2017-01-01);
let etime = datetime(2017-01-10);
data
| take 0
| make-series avg(metric) default=1.0 on timestamp from stime to etime step interval 
| count 

Saída

O uso kind=nonempty no make-series produz um resultado não vazio dos valores padrão:

let data=datatable(timestamp:datetime, metric: real)
[
  datetime(2016-12-31T06:00), 50,
  datetime(2017-01-01), 4,
  datetime(2017-01-02), 3,
  datetime(2017-01-03), 4,
  datetime(2017-01-03T03:00), 6,
  datetime(2017-01-05), 8,
  datetime(2017-01-05T13:40), 13,
  datetime(2017-01-06), 4,
  datetime(2017-01-07), 3,
  datetime(2017-01-08), 8,
  datetime(2017-01-08T21:00), 8,
  datetime(2017-01-09), 2,
  datetime(2017-01-09T12:00), 11,
  datetime(2017-01-10T05:00), 5,
];
let interval = 1d;
let stime = datetime(2017-01-01);
let etime = datetime(2017-01-10);
data
| take 0
| make-series kind=nonempty avg(metric) default=1.0 on timestamp from stime to etime step interval 

Saída

Usando make-series e mv-expand para preencher valores para registros ausentes:

let startDate = datetime(2025-01-06);
let endDate = datetime(2025-02-09);
let data = datatable(Time: datetime, Value: int, other:int)
[
    datetime(2025-01-07), 10, 11,
    datetime(2025-01-16), 20, 21,
    datetime(2025-02-01), 30, 5
];
data
| make-series Value=sum(Value), other=-1 default=-2 on Time from startDate to endDate step 7d
| mv-expand Value, Time, other
| extend Time=todatetime(Time), Value=toint(Value), other=toint(other)
| project-reorder Time, Value, other 

Saída