operador scan

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Examina dados, faz a correspondência e cria sequências com base nos predicados.

Os registros correspondentes são determinados de acordo com os predicados definidos nas etapas do operador. Um predicado pode depender do estado gerado pelas etapas anteriores. A saída para o registro correspondente é determinada pelo registro de entrada e atribuições definidas nas etapas do operador.

Syntax

T| scan [ with_match_id=MatchIdColumnName ] [ declare(ColumnDeclarations) ] with(StepDefinitions)

Sintaxe ColumnDeclarations

Columnname:ColumnType[=DefaultValue ] [, ... ]

Sintaxe StepDefinition

step StepName [ output | lastall | none = ] :Condition [ =>Column=Assignment [, ... ] ];

Saiba mais sobre convenções de sintaxe.

Parameters

Returns

Um registro para cada correspondência de um registro da entrada para uma etapa. O esquema da saída é o esquema da fonte estendida com a coluna na declare cláusula.

Lógica de verificação

scan examina os dados de entrada serializados, registro por registro, comparando cada registro com a condição de cada etapa, levando em consideração o estado atual de cada etapa.

State

O estado subjacente do scan operador pode ser pensado como uma tabela com uma linha para cada step. Cada etapa mantém seu próprio estado com os valores mais recentes das colunas e variáveis declaradas de todas as etapas anteriores e da etapa atual. Se relevante, ele também contém a ID de correspondência para a sequência em andamento.

Se um operador de verificação tiver n etapas denominadas s_1, s_2, ..., s_n então, a etapa s_k teria k registros em seu estado correspondente a s_1, s_2, ..., s_k. O StepName. O formato ColumnName é usado para fazer referência a um valor no estado. Por exemplo, s_2.col1 faria referência à coluna col1 que pertence à etapa s_2 no estado de s_k. Para obter um exemplo detalhado, consulte o passo a passo da lógica de verificação.

O estado começa vazio e é atualizado sempre que um registro de entrada digitalizado corresponde a uma etapa. Quando o estado da etapa atual não está vazio, a etapa é conhecida como tendo uma sequência ativa.

Lógica de correspondência

Cada registro de entrada é avaliado em relação a todas as etapas na ordem inversa, da última etapa à primeira. Quando um registro r é avaliado em relação a alguma etapa s_k, a seguinte lógica é aplicada:

• Verifique 1: Se o estado da etapa anterior (s_k-1) não for inteiro e r atender à Condição de s_k, ocorrerá uma correspondência. A correspondência leva às seguintes ações:

  1. O estado de s_k está limpo.
  2. O estado de s_k-1 é promovido para se tornar o estado de s_k.
  3. As atribuições de s_k são calculadas e estendem r.
  4. O r estendido é adicionado à saída e ao estado de s_k.

  Note

  Se a Verificação 1 resultar em uma correspondência, a Verificação 2 será desconsiderada e r passará a ser avaliado em relação a s_k-1.

• Verifique 2: Se o estado de s_k tiver uma sequência ativa ou s_k for a primeira etapa e r atender à Condição de s_k, ocorrerá uma correspondência. A correspondência leva às seguintes ações:

  1. As atribuições de s_k são calculadas e estendem r.
  2. Os valores que representam s_k no estado de s_k são substituídos pelos valores do r estendido.
  3. Se s_k for definido como output=all, o r estendido será adicionado à saída.
  4. Se s_k for a primeira etapa, uma nova sequência começará e a ID da correspondência aumentará 1. Isso afeta apenas a saída quando with_match_id é usado.

Depois que as verificações de s_k estiverem concluídas, o r passará a ser avaliado em relação a s_k-1.

Para obter um exemplo detalhado dessa lógica, consulte o passo a passo da lógica de verificação.

Examples

O exemplo nesta seção mostra como usar a sintaxe para ajudá-lo a começar.

Soma cumulativa

Calcule a soma cumulativa de uma coluna de entrada. O resultado deste exemplo é equivalente ao uso de row_cumsum().

range x from 1 to 5 step 1 
| scan declare (cumulative_x:long=0) with 
(
    step s1: true => cumulative_x = x + s1.cumulative_x;
)

Output

Soma cumulativa em várias colunas com uma condição de redefinição

Calcule a soma cumulativa para duas colunas de entrada, redefina o valor da soma para o valor do registro atual sempre que a soma cumulativa atingir 10 ou mais.

range x from 1 to 5 step 1
| extend y = 2 * x
| scan declare (cumulative_x:long=0, cumulative_y:long=0) with 
(
    step s1: true => cumulative_x = iff(s1.cumulative_x >= 10, x, x + s1.cumulative_x), 
                     cumulative_y = iff(s1.cumulative_y >= 10, y, y + s1.cumulative_y);
)

Output

Preencher uma coluna

Preencha uma coluna de string. Cada valor vazio recebe o último valor não vazio visto.

let Events = datatable (Ts: timespan, Event: string) [
    0m, "A",
    1m, "",
    2m, "B",
    3m, "",
    4m, "",
    6m, "C",
    8m, "",
    11m, "D",
    12m, ""
]
;
Events
| sort by Ts asc
| scan declare (Event_filled: string="") with 
(
    step s1: true => Event_filled = iff(isempty(Event), s1.Event_filled, Event);
)

Output

Marcação de sessões

Divida a entrada em sessões: uma sessão termina 30 minutos após o primeiro evento da sessão, após o qual uma nova sessão é iniciada. Observe o uso do with_match_id sinalizador, que atribui um valor exclusivo para cada correspondência distinta (sessão) da verificação. Observe também que o uso especial de duas etapas neste exemplo tem inSessiontrue como condição que captura e gera todos os registros da entrada enquanto endSession captura registros que ocorrem a mais de 30m do sessionStart valor da correspondência atual. A endSession etapa significa output=none que não produz registros de saída. A endSession etapa é usada para avançar o estado da correspondência atual de inSession para endSession, permitindo que uma nova correspondência (sessão) seja iniciada, a partir do registro atual.

let Events = datatable (Ts: timespan, Event: string) [
    0m, "A",
    1m, "A",
    2m, "B",
    3m, "D",
    32m, "B",
    36m, "C",
    38m, "D",
    41m, "E",
    75m, "A"
]
;
Events
| sort by Ts asc
| scan with_match_id=session_id declare (sessionStart: timespan) with 
(
    step inSession: true => sessionStart = iff(isnull(inSession.sessionStart), Ts, inSession.sessionStart);
    step endSession output=none: Ts - inSession.sessionStart > 30m;
)

Output

Calculando o comprimento da sessão por usuário

Calcule a hora de início da sessão, a hora de término e a duração da sessão de cada usuário usando o scan operador. Uma sessão é definida como um período entre o logon de um usuário e o logoff subsequente. Combinando partition e scan com output=none e output=all, esse padrão garante que uma única linha seja retornada por sessão (ou seja, por par de logoff/logoff), em vez de uma linha por evento.

A lógica funciona por:

• Na etapa s1: Capturando o carimbo de data/hora de logon usando uma etapa de verificação com output=none
• Na etapa s2: emitindo uma linha somente quando um logoff correspondente é encontrado usando output=all

let LogsEvents = datatable(Timestamp:datetime, userID:int, EventType:string)
[
    datetime(2024-05-28 08:15:23), 1, "login",
    datetime(2024-05-28 08:30:15), 2, "login",
    datetime(2024-05-28 09:10:27), 3, "login",
    datetime(2024-05-28 12:30:45), 1, "logout",
    datetime(2024-05-28 11:45:32), 2, "logout",
    datetime(2024-05-28 13:25:19), 3, "logout"
];
LogsEvents
| sort by userID, Timestamp
| partition hint.strategy=native by userID (
    sort by Timestamp asc 
    | scan declare (start: datetime, end: datetime, sessionDuration: timespan) with (
        step s1 output=none: EventType == "login" => start = Timestamp;
        step s2 output=all: EventType == "logout" => start = s1.start, end = Timestamp, sessionDuration = Timestamp - s1.start;
    )
)
| project start, end, userID, sessionDuration

Output

Eventos entre Início e Parada

Encontre todas as sequências de eventos entre o evento Start e o evento Stop que ocorrem em 5 minutos. Atribua uma ID de correspondência para cada sequência.

let Events = datatable (Ts: timespan, Event: string) [
    0m, "A",
    1m, "Start",
    2m, "B",
    3m, "D",
    4m, "Stop",
    6m, "C",
    8m, "Start",
    11m, "E",
    12m, "Stop"
]
;
Events
| sort by Ts asc
| scan with_match_id=m_id with 
(
    step s1: Event == "Start";
    step s2: Event != "Start" and Event != "Stop" and Ts - s1.Ts <= 5m;
    step s3: Event == "Stop" and Ts - s1.Ts <= 5m;
)

Output

Calcular um funil personalizado de eventos

Calcule uma conclusão de funil da sequência Hail ->Tornado ->Thunderstorm Wind com State limites personalizados nos tempos entre os eventos (Tornado dentro 1h e Thunderstorm Wind dentro 2h). Este exemplo é semelhante ao plug-in funnel_sequence_completion, mas permite maior flexibilidade.

StormEvents
| partition hint.strategy=native by State 
    (
    sort by StartTime asc
    | scan with 
    (
        step hail: EventType == "Hail";
        step tornado: EventType == "Tornado" and StartTime - hail.StartTime <= 1h;
        step thunderstormWind: EventType == "Thunderstorm Wind" and StartTime - tornado.StartTime <= 2h;
    )
    )
| summarize dcount(State) by EventType

Output

Passo a passo da lógica de varredura

Esta seção demonstra a lógica de verificação usando um passo a passo dos Eventos entre o exemplo de início e parada :

let Events = datatable (Ts: timespan, Event: string) [
    0m, "A",
    1m, "Start",
    2m, "B",
    3m, "D",
    4m, "Stop",
    6m, "C",
    8m, "Start",
    11m, "E",
    12m, "Stop"
]
;
Events
| sort by Ts asc
| scan with_match_id=m_id with 
(
    step s1: Event == "Start";
    step s2: Event != "Start" and Event != "Stop" and Ts - s1.Ts <= 5m;
    step s3: Event == "Stop" and Ts - s1.Ts <= 5m;
)

Output

O estado

Pense no estado do scan operador como uma tabela com uma linha para cada etapa, na qual cada etapa tem seu próprio estado. Esse estado contém os valores mais recentes das colunas e variáveis declaradas de todas as etapas anteriores e da etapa atual. Para saber mais, confira Estado.

Para este exemplo, o estado pode ser representado com a seguinte tabela:

O "X" indica que um campo específico é irrelevante para essa etapa.

A lógica de correspondência

Esta seção segue a lógica correspondente por meio de cada registro da Events tabela, explicando a transformação do estado e da saída em cada etapa.

Registro 1

Registre a avaliação em cada etapa:

• s3: a verificação 1 não é passada porque o estado está s2 vazio e a Verificação 2 não é passada porque s3 falta uma sequência ativa.
• s2: a verificação 1 não é passada porque o estado está s1 vazio e a Verificação 2 não é passada porque s2 falta uma sequência ativa.
• s1: a verificação 1 é irrelevante porque não há nenhuma etapa anterior. A verificação 2 não foi passada porque o registro não atende à condição de Event == "Start". O registro 1 é descartado sem afetar o estado ou a saída.

State:

Registro 2

Registre a avaliação em cada etapa:

• s3: a verificação 1 não é passada porque o estado está s2 vazio e a Verificação 2 não é passada porque s3 falta uma sequência ativa.
• s2: a verificação 1 não é passada porque o estado está s1 vazio e a Verificação 2 não é passada porque s2 falta uma sequência ativa.
• s1: a verificação 1 é irrelevante porque não há nenhuma etapa anterior. A verificação 2 é passada porque o registro atende à condição de Event == "Start". Essa correspondência inicia uma nova sequência e é m_id atribuída. O registro 2 e seu m_id (0) são adicionados ao estado e à saída.

State:

Registro 3

Registre a avaliação em cada etapa:

• s3: a verificação 1 não é passada porque o estado está s2 vazio e a Verificação 2 não é passada porque s3 falta uma sequência ativa.
• s2: a verificação 1 é passada porque o estado não s1 está vazio e o registro atende à condição de Ts - s1.Ts < 5m. Essa correspondência faz com que o estado de s1 seja limpo e a sequência em s1 seja promovida para s2. O registro 3 e seu m_id (0) são adicionados ao estado e à saída.
• s1: a verificação 1 é irrelevante porque não há nenhuma etapa anterior e a Verificação 2 não é passada porque o registro não atende à condição de Event == "Start".

State:

Registro 4

Registre a avaliação em cada etapa:

• s3: a verificação 1 não é passada porque o registro não atende à condição de Event == "Stop", e a Verificação 2 não é passada porque s3 não tem uma sequência ativa.
• s2: a verificação 1 não é passada porque o estado está s1 vazio. Ele passa a Verificação 2 porque atende à condição de Ts - s1.Ts < 5m. O registro 4 e seu m_id (0) são adicionados ao estado e à saída. Os valores desse registro substituem os valores de estado anteriores para s2.Ts e s2.Event.
• s1: a verificação 1 é irrelevante porque não há nenhuma etapa anterior e a Verificação 2 não é passada porque o registro não atende à condição de Event == "Start".

State:

Registro 5

Registre a avaliação em cada etapa:

• s3: a verificação 1 é passada porque s2 não está úmida e atende à s3 condição de Event == "Stop". Essa correspondência faz com que o estado de s2 seja limpo e a sequência em s2 seja promovida para s3. O registro 5 e seu m_id (0) são adicionados ao estado e à saída.
• s2: a verificação 1 não é passada porque o estado está s1 vazio e a Verificação 2 não é passada porque s2 falta uma sequência ativa.
• s1: a verificação 1 é irrelevante porque não há nenhuma etapa anterior. A verificação 2 não foi passada porque o registro não atende à condição de Event == "Start".

State:

Registro 6

Registre a avaliação em cada etapa:

• s3: a verificação 1 não é passada porque o estado está s2 vazio e a Verificação 2 não é passada porque s3 não atende à s3 condição de Event == "Stop".
• s2: a verificação 1 não é passada porque o estado está s1 vazio e a Verificação 2 não é passada porque s2 falta uma sequência ativa.
• s1: a verificação 1 não foi passada porque não há nenhuma etapa anterior e a Verificação 2 não é passada porque não atende à condição de Event == "Start". O registro 6 é descartado sem afetar o estado ou a saída.

State:

Registro 7

Registre a avaliação em cada etapa:

• s3: a verificação 1 não é passada porque o estado está s2 vazio e a Verificação 2 não é passada porque não atende à condição de Event == "Stop".
• s2: a verificação 1 não é passada porque o estado está s1 vazio e a Verificação 2 não é passada porque s2 falta uma sequência ativa.
• s1: a verificação 1 não foi passada porque não há nenhuma etapa anterior. Ele passa a Verificação 2 porque atende à condição de Event == "Start". Essa correspondência inicia uma nova sequência com s1 um novo m_id. O registro 7 e seu m_id (1) são adicionados ao estado e à saída.

State:

Registro 8

Registre a avaliação em cada etapa:

• s3: a verificação 1 não é passada porque o estado está s2 vazio e a Verificação 2 não é passada porque não atende à s3 condição de Event == "Stop".
• s2: a verificação 1 é passada porque o estado não s1 está vazio e o registro atende à condição de Ts - s1.Ts < 5m. Essa correspondência faz com que o estado de s1 seja limpo e a sequência em s1 seja promovida para s2. O registro 8 e seu m_id (1) são adicionados ao estado e à saída.
• s1: a verificação 1 é irrelevante porque não há nenhuma etapa anterior e a Verificação 2 não é passada porque o registro não atende à condição de Event == "Start".

State:

Registro 9

Registre a avaliação em cada etapa:

• s3: a verificação 1 é passada porque s2 não está úmida e atende à s3 condição de Event == "Stop". Essa correspondência faz com que o estado de s2 seja limpo e a sequência em s2 seja promovida para s3. O registro 9 e seu m_id (1) são adicionados ao estado e à saída.
• s2: a verificação 1 não é passada porque o estado está s1 vazio e a Verificação 2 não é passada porque s2 falta uma sequência ativa.
• s1: a verificação 1 não foi passada porque não há nenhuma etapa anterior e a Verificação 2 não é passada porque o registro não atende à condição de Evento == "Iniciar".

State:

Saída final