Propriedade Form.DatasheetFontHeight (Access)

Utilize a propriedade DatasheetFontHeight para especificar o tamanho do ponto de tipo de letra utilizado para apresentar e imprimir nomes de campos e dados na vista Folha de Dados. número inteiro de leitura/gravação.

Sintaxe

expressão. DatasheetFontHeight

expressão Uma variável que representa um objeto Form.

Comentários

Essa propriedade está disponível apenas em um banco de dados do Microsoft Access.

Para a propriedade DatasheetFontHeight , o tamanho do tipo de letra que especificar tem de ser válido para o tipo de letra especificado pela propriedade DatasheetFontName . Por exemplo, o MS Sans Serif está disponível somente em pontos de tamanhos 8, 10, 12, 14, 18 e 24.

A tabela seguinte contém as propriedades que não existem na coleção Propriedades do DAO até as definir através da barra de ferramentas Formatação (Folha de Dados) ou pode adicioná-las numa base de dados do Access (.mdb) através do método CreateProperty e anexá-la à coleção Propriedades do DAO .

Exemplo

O exemplo seguinte define o tipo de letra como MS Serif, o tamanho do tipo de letra como 10 pontos e a espessura do tipo de letra como médio (500) na vista Folha de Dados da tabela Produtos .

Sub SetDatasheetFont 
 
 Dim dbs As Object, objProducts As Object 
 Set dbs = CurrentDb 
 Const DB_Text As Long = 10 
 Const DB_Integer As Long = 3 
 Set objProducts = dbs!Products 
 
 SetTableProperty objProducts, "DatasheetFontName", DB_Text, "MS Serif" 
 SetTableProperty objProducts, "DatasheetFontHeight", DB_Integer, 10 
 SetTableProperty objProducts, "DatasheetFontWeight", DB_Integer, 500 
 
End Sub 

Sub SetTableProperty(objTableObj As Object, strPropertyName As String, _ 
 intPropertyType As Integer, varPropertyValue As Variant) 
 ' Set Microsoft Access-defined table property without causing 
 ' nonrecoverable run-time error. 
 Const conErrPropertyNotFound = 3270 
 Dim prpProperty As Variant 
 On Error Resume Next ' Don't trap errors. 
 objTableObj.Properties(strPropertyName) = varPropertyValue 
 If Err <> 0 Then ' Error occurred when value set. 
 If Err <> conErrPropertyNotFound Then 
 On Error GoTo 0 
 MsgBox "Couldn't set property '" & strPropertyName _ 
 & "' on table '" & objTableObj.Name & "'", 48, "SetTableProperty" 
 Else 
 On Error GoTo 0 
 Set prpProperty = objTableObj.CreateProperty(strPropertyName, _ 
 intPropertyType, varPropertyValue) 
 objTableObj.Properties.Append prpProperty 
 End If 
 End If 
 objTableObj.Properties.Refresh 
End Sub

O exemplo seguinte faz as mesmas alterações que o exemplo anterior na vista Folha de Dados do formulário Produtos aberto.

Forms!Products.DatasheetFontName = "MS Serif" 
Forms!Products.DatasheetFontHeight = 10 
Forms!Products.DatasheetFontWeight = 500

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.